FactuGES2/Source/Modulos/Contabilidad/Controller/uEpigrafesController.pas

unit uEpigrafesController;

interface


uses
  Classes, SysUtils, uDADataTable, uControllerBase,
   uBizEpigrafes, uIDataModuleContabilidad;
type
  IEpigrafesController = interface(IObservador)
  ['{94E5F2B6-64C8-4331-B9CB-3ED730478529}']
    function BuscarTodos: IBizEpigrafe;
    function Buscar(ID: Integer): IBizEpigrafe;
    procedure VerTodos(AEpigrafes: IBizEpigrafe);
    procedure Ver(AEpigrafe: IBizEpigrafe);
    procedure Anadir(AEpigrafe : IBizEpigrafe);
    function Eliminar(AEpigrafe : IBizEpigrafe): Boolean; 
    function Guardar(AEpigrafe : IBizEpigrafe): Boolean;
    procedure DescartarCambios(AEpigrafe : IBizEpigrafe);
    function Localizar(AEpigrafes: IBizEpigrafe; ADescripcion:String): Boolean;
    function DarListaEpigrafes: TStringList;
  end;

  TEpigrafesController = class(TObservador, IEpigrafesController)
  protected
    FDataModule : IDataModuleContabilidad;

    procedure RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable); override;
    function CreateEditor(const AName : String; const IID: TGUID; out Intf): Boolean;

    function ValidarEpigrafe(AEpigrafe: IBizEpigrafe): Boolean;
    procedure AsignarDataModule;

  public
    constructor Create; override;
    destructor Destroy; override;

    function Eliminar(AEpigrafe : IBizEpigrafe): Boolean;
    function Guardar(AEpigrafe : IBizEpigrafe): Boolean; virtual;
    procedure DescartarCambios(AEpigrafe : IBizEpigrafe); virtual;
    procedure Anadir(AEpigrafe : IBizEpigrafe);
    function BuscarTodos: IBizEpigrafe;
    function Buscar(ID: Integer): IBizEpigrafe;
    procedure VerTodos(AEpigrafes: IBizEpigrafe);
    procedure Ver(AEpigrafe: IBizEpigrafe);
    function Localizar(AEpigrafes: IBizEpigrafe; ADescripcion:String): Boolean;
    function DarListaEpigrafes: TStringList;
  end;

implementation

uses
  cxControls, DB, uEditorRegistryUtils, schContabilidadClient_Intf,
  uIEditorEpigrafes, uIEditorEpigrafe, uDataModuleContabilidad,
  uDAInterfaces, uDataTableUtils, uDialogUtils,
  uDateUtils, uROTypes, DateUtils, Controls, Windows;

{ TEpigrafesController }

procedure TEpigrafesController.Anadir(AEpigrafe: IBizEpigrafe);
begin
  AEpigrafe.Insert;
end;

procedure TEpigrafesController.AsignarDataModule;
begin
  FDataModule := TDataModuleContabilidad.Create(Nil);
end;

function TEpigrafesController.Buscar(ID: Integer): IBizEpigrafe;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := BuscarTodos;

    with Result.DataTable.DynamicWhere do
    begin
      // (ID = :ID)
      Condicion := NewBinaryExpression(NewField('', fld_EpigrafesID), NewConstant(ID, datInteger), dboEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

function TEpigrafesController.BuscarTodos: IBizEpigrafe;
begin
  Result := FDataModule.GetEpigrafeItems;
end;

constructor TEpigrafesController.Create;
begin
  inherited;
  AsignarDataModule;
end;

function TEpigrafesController.CreateEditor(const AName: String; const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;

function TEpigrafesController.DarListaEpigrafes: TStringList;
var
  AEpigrafes: IBizEpigrafe;
begin
  AEpigrafes := BuscarTodos;
  AEpigrafes.DataTable.Active := True;
  Result := TStringList.Create;
  try
    with Result do
    begin
      AEpigrafes.DataTable.First;
      while not AEpigrafes.DataTable.EOF do
      begin
        Add(AEpigrafes.DESCRIPCION);
        AEpigrafes.DataTable.Next;
      end;
    end;
  finally
    AEpigrafes := NIL;
  end;
end;

procedure TEpigrafesController.DescartarCambios(AEpigrafe: IBizEpigrafe);
begin
  if not Assigned(AEpigrafe) then
    raise Exception.Create ('Epigrafe no asignado');

  ShowHourglassCursor;
  try
    if (AEpigrafe.State in dsEditModes) then
      AEpigrafe.Cancel;

    AEpigrafe.DataTable.CancelUpdates;
  finally
    HideHourglassCursor;
  end;
end;

destructor TEpigrafesController.Destroy;
begin
  FDataModule:= NIL;
  inherited;
end;

function TEpigrafesController.ValidarEpigrafe(AEpigrafe: IBizEpigrafe): Boolean;
begin
  Result := False;

  if not Assigned(AEpigrafe) then
    raise Exception.Create ('Epigrafe no asignado');

  if (AEpigrafe.DataTable.State in dsEditModes) then
    AEpigrafe.DataTable.Post;

  if Length(AEpigrafe.DESCRIPCION) = 0 then
    raise Exception.Create('Debe indicar un nombre para este Epigrafe.');

  Result := True;
end;

procedure TEpigrafesController.Ver(AEpigrafe: IBizEpigrafe);
var
  AEditor : IEditorEpigrafe;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    CreateEditor('EditorEpigrafe', IEditorEpigrafe, AEditor);
    if Assigned(AEditor) then
       with AEditor do
       begin
         Controller := Self; //OJO ORDEN MUY IMPORTANTE
         Epigrafe := AEpigrafe;
         ShowModal;
         Release;
       end;
  finally
    AEditor := NIL;
    HideHourglassCursor;
  end;
end;

procedure TEpigrafesController.VerTodos(AEpigrafes: IBizEpigrafe);
var
  AEditor : IEditorEpigrafes;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    CreateEditor('EditorEpigrafes', IEditorEpigrafes, AEditor);
    if Assigned(AEditor) then
       with AEditor do
       begin
         Controller := Self; //OJO ORDEN MUY IMPORTANTE
         Epigrafes := AEpigrafes;
         ShowEmbedded;
       end;
  finally
    AEditor := NIL;
    HideHourglassCursor;
  end;
end;

function TEpigrafesController.Eliminar(AEpigrafe: IBizEpigrafe): Boolean;
begin
  Result := False;

  if not Assigned(AEpigrafe) then
    raise Exception.Create ('Epigrafe no asignado');

  ShowHourglassCursor;
  try
    if (AEpigrafe.State in dsEditModes) then
      AEpigrafe.Cancel;

    AEpigrafe.Delete;
    AEpigrafe.DataTable.ApplyUpdates;
    HideHourglassCursor;
    Result := True;
  finally
    HideHourglassCursor;
  end;
end;

procedure TEpigrafesController.RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable);
begin
  inherited;
//
end;

function TEpigrafesController.Guardar(AEpigrafe: IBizEpigrafe): Boolean;
begin
  Result := False;

  if ValidarEpigrafe(AEpigrafe) then
  begin
    ShowHourglassCursor;
    try
      AEpigrafe.DataTable.ApplyUpdates;
      Result := True;
    finally
      HideHourglassCursor;
    end;
  end;
end;

function TEpigrafesController.Localizar(AEpigrafes: IBizEpigrafe; ADescripcion: String): Boolean;
begin
  Result := True;
  ShowHourglassCursor;
  try
    with AEpigrafes.DataTable do
    begin
      DisableControls;
      First;
      if not Locate(fld_EpigrafesDESCRIPCION, ADescripcion, []) then
         Result := False;
      EnableControls;   
    end;
  finally
    HideHourglassCursor;
  end;
end;

end.