FactuGES2/Source/Modulos/Almacenes/Views/uEditorUbicacionesAlmacen.pas

{
===============================================================================
  Copyright (©) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 22-05-2006
  Versión actual: 1.0.0
  Fecha versión actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorUbicacionesAlmacen;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorUbicacionesAlmacen, uEditorBasico, uGUIBase, ExtCtrls,
  ComCtrls, uBizUbicacionesAlmacen, uUbicacionesAlmacenController, uDAInterfaces,
  uEditorBase;

type
  TfEditorUbicacionesAlmacen = class(TfEditorBasico, IEditorUbicacionesAlmacen)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaUbicacionesAlmacen: TDBLookupListBox;
    editUbicacionAlmacen: TEdit;
    bAnadir: TButton;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    GroupBox1: TGroupBox;
    Label1: TLabel;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FUbicacionesAlmacen: IBizUbicacionAlmacen;
    FController: IUbicacionesAlmacenController;
    function GetUbicacionesAlmacen: IBizUbicacionAlmacen;
    procedure SetUbicacionesAlmacen(const Value: IBizUbicacionAlmacen);
    function GetController : IUbicacionesAlmacenController;
    procedure SetController (const Value : IUbicacionesAlmacenController);
  public
    property UbicacionesAlmacen: IBizUbicacionAlmacen read GetUbicacionesAlmacen write SetUbicacionesAlmacen;
    property Controller : IUbicacionesAlmacenController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorUbicacionesAlmacen }

uses
  uDialogUtils;


function TfEditorUbicacionesAlmacen.GetController: IUbicacionesAlmacenController;
begin
  Result := FController;
end;

function TfEditorUbicacionesAlmacen.GetUbicacionesAlmacen: IBizUbicacionAlmacen;
begin
  Result := FUbicacionesAlmacen;
end;

procedure TfEditorUbicacionesAlmacen.SetController(const Value: IUbicacionesAlmacenController);
begin
  FController := Value;
end;

procedure TfEditorUbicacionesAlmacen.SetUbicacionesAlmacen(const Value: IBizUbicacionAlmacen);
begin
  FUbicacionesAlmacen := Value;
  DADataSource.DataTable := (FUbicacionesAlmacen as IBizUbicacionAlmacen).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorUbicacionesAlmacen.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(UbicacionesAlmacen, editUbicacionAlmacen.Text) then
  begin
    UbicacionesAlmacen.Append;
    UbicacionesAlmacen.DESCRIPCION := editUbicacionAlmacen.Text;
    UbicacionesAlmacen.Post;
    editUbicacionAlmacen.Clear;
    ListaUbicacionesAlmacen.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe la ubicación ' + editUbicacionAlmacen.Text,
      'Ya existe la ubicación ''' + editUbicacionAlmacen.Text + ''' en la lista de ubicaciones.');
end;

procedure TfEditorUbicacionesAlmacen.actEliminarExecute(Sender: TObject);
begin
  UbicacionesAlmacen.Delete;
  ListaUbicacionesAlmacen.SetFocus;
end;

procedure TfEditorUbicacionesAlmacen.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FUbicacionesAlmacen.DataTable.RecordCount > 0) and
                                  (Length(ListaUbicacionesAlmacen.SelectedItem) > 0);

end;

procedure TfEditorUbicacionesAlmacen.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FUbicacionesAlmacen := Nil;
  FController := Nil;
end;

procedure TfEditorUbicacionesAlmacen.actAceptarExecute(Sender: TObject);
begin
  try
    UbicacionesAlmacen.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      UbicacionesAlmacen.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorUbicacionesAlmacen.actCancelarExecute(Sender: TObject);
begin
  UbicacionesAlmacen.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorUbicacionesAlmacen.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorUbicacionesAlmacen.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editUbicacionAlmacen.Text) > 0)
end;

procedure TfEditorUbicacionesAlmacen.FormShow(Sender: TObject);
begin
  if not FUbicacionesAlmacen.DataTable.Active then
     FUbicacionesAlmacen.DataTable.Active := true;

  editUbicacionAlmacen.SetFocus;
end;

end.