AlonsoYSal_FactuGES2/Source/Modulos/Facturas de cliente/Controller/uFacturasClienteReportController.pas

unit uFacturasClienteReportController;

interface

uses
  Classes, SysUtils, uDADataTable, uControllerBase, uIDataModuleFacturasClienteReport,
  uClientesController, uDetallesFacturaClienteController, uIntegerListUtils,
  uBizFacturasCliente;

type
  IFacturasClienteReportController = interface(IControllerBase)
  ['{A0F41767-4FF6-4BAE-9FC9-894DD721D756}']
    procedure Preview(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
    procedure Print(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
    function ExportToPDF(const AID: Integer; const AFileName : String = ''): Boolean;
  end;

  TFacturasClienteReportController = class(TControllerBase, IFacturasClienteReportController)
  private
    FDataModule : IDataModuleFacturasClienteReport;
    function CreateEditor(const AName: String; const IID: TGUID; out Intf): Boolean;
  public
    constructor Create; override;
    destructor Destroy; override;

    procedure Preview(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
    procedure Print(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
    function ExportToPDF(const AID: Integer; const AFileName : String = ''): Boolean;    
  end;


implementation

uses
  uROTypes, uEditorRegistryUtils, uIEditorFacturasClientePreview,
  uEditorPreview, uDataModuleFacturasCliente, uEditorBase, cxControls,
  uStringsUtils;

{ TFacturasClienteReportController }

constructor TFacturasClienteReportController.Create;
begin
  inherited;
  FDataModule := TDataModuleFacturasCliente.Create(Nil);
end;

function TFacturasClienteReportController.CreateEditor(const AName: String;
  const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;


destructor TFacturasClienteReportController.Destroy;
begin
  FDataModule := NIL;
  inherited;
end;

function TFacturasClienteReportController.ExportToPDF(const AID: Integer;
  const AFileName: String): Boolean;
var
  AStream: Binary;
begin
  Result := False;
  if EsCadenaVacia(AFileName) then
    Exit;

  ShowHourglassCursor;
  try
    AStream := FDataModule.GetRptPDFFactura(AID);
    try
      AStream.SaveToFile(AFileName);
      Result := True;
    finally
      FreeAndNil(AStream);
    end;
  finally
    HideHourglassCursor;
  end;
end;

procedure TFacturasClienteReportController.Preview(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
var
  AStream: Binary;
  AEditor : IEditorFacturasClientePreview;
begin
  AEditor := NIL;

  AStream := FDataModule.GetReport(AListaID, AVerDatosCliente);
  try
    CreateEditor('EditorFacturasClientePreview', IEditorFacturasClientePreview, AEditor);
    if Assigned(AEditor) then
      try
        AEditor.Controller := Self;
        AEditor.ListaID := AListaID;
        AEditor.LoadFromStream(AStream);
        AEditor.Preview;
      finally
        AEditor.Release;
      end;
  finally
    FreeAndNil(AStream);
    AEditor := Nil;
  end;
end;

procedure TFacturasClienteReportController.Print(const AListaID : TIntegerList; AVerDatosCliente: Boolean = true);
var
  AStream: Binary;
  AEditor : IEditorFacturasClientePreview;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    AStream := FDataModule.GetReport(AListaID, AVerDatosCliente);
    try
      CreateEditor('EditorFacturasClientePreview', IEditorFacturasClientePreview, AEditor);
      if Assigned(AEditor) then
        try
          AEditor.Controller := Self;
          AEditor.LoadFromStream(AStream);
          AEditor.Print;
        finally
          AEditor.Release;
        end;
    finally
      FreeAndNil(AStream);
      AEditor := Nil;
    end;
  finally
    HideHourglassCursor;
  end;
end;

end.