unit uDetallesMedicacionController;

interface

uses
  uDADataTable, uBizDetallesMedicacion, uIDataModuleMedicaciones, uControllerDetallesArticulos,
  uBizArticulos, uBizContactos, Classes;

const
  TIPO_DETALLE_ENBLISTER = 'En blister';
  TIPO_DETALLE_NOBLISTER = 'Fuera del blister';

type
  IDetallesMedicacionController = interface(IControllerDetallesArticulos)
  ['{38B4EE57-A247-4A41-A62C-CC18B8793FB3}']
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable); overload;
  end;

  TDetallesMedicacionController = class(TControllerDetallesArticulos, IDetallesMedicacionController)
  private
    FDataModule : IDataModuleMedicaciones;
  protected
    procedure AsignarController; override;
    //Si sobreescribimos este método podremos tener en cuenta otras columnas para el calculo del importe total de un concepto
    function CalcularImporteTotalConcepto(DataTable: TDADataTable): Double; override;
    procedure ValidarCampos(DataTable: TDADataTable); override;
    function CalcularTotales(Modificar: boolean; DataTable: TDADataTable): Double; override;
    procedure Add(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo; const ACantidad: Float = 1); overload;
    function DarListaTiposDetalle: TStringList; overload;            
  public
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable); overload;
    constructor Create; override;
    destructor Destroy; override;
  end;

implementation

uses
  Dialogs, uDialogUtils, Variants, uControllerDetallesBase, cxControls,
  uCalculosUtils, uDataModuleMedicaciones, uArticulosMedicacionController;

{ TDetallesMedicacionController }

procedure TDetallesMedicacionController.ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable);
var
  AArticulos : IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos as IBizArticulo);
      ActualizarDetalles(ADetalles, AArticulos);
    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesMedicacionController.Add(
  ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo;
  const ACantidad: Float);
begin
  // inherited; <- no utilizar la herencia
  if Assigned(ADetalles) and Assigned(AArticulos) then
  begin
    try
      ShowHourglassCursor;
      BeginUpdate(ADetalles);

      if not ADetalles.DataTable.Active then
         ADetalles.DataTable.Active := True;

      if not AArticulos.DataTable.Active then
         AArticulos.DataTable.Active := True;

      with AArticulos.DataTable do
      begin
        First;
        while not EOF do
        begin
          Self.Add(ADetalles, TIPO_DETALLE_ENBLISTER);
          RellenarDetalle(ADetalles, AArticulos, ACantidad);
          Next;
        end;
      end;
    finally
      EndUpdate(ADetalles);
      HideHourglassCursor;
    end;
  end;
end;

procedure TDetallesMedicacionController.AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; const ANuevaFila :Boolean; const ACantidad: Integer);
var
  AArticulos: IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos as IBizArticulo);

      //Si nueva fila es false, quiere decir que se sustituye un determinado artículo, por ello la lista a seleccionar no debe ser multiselect
      if ANuevaFila then
      begin
        AArticulos := (FArticulosController as IArticulosMedicacionController).ElegirArticulos(AArticulos, 'Elija los artículos que desea añadir', True);
        Add(ADetalles, AArticulos, ACantidad)
      end
      else
      begin
        AArticulos := (FArticulosController as IArticulosMedicacionController).ElegirArticulos(AArticulos, 'Elija el artículo que desea añadir', False);
        RellenarDetalle(ADetalles, AArticulos, ACantidad);
      end;

    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesMedicacionController.AsignarController;
begin
  FArticulosController := TArticulosMedicacionController.Create;
end;

function TDetallesMedicacionController.CalcularImporteTotalConcepto(DataTable: TDADataTable): Double;
begin
  Result := CalcularLineaConcepto(DataTable);
end;

function TDetallesMedicacionController.CalcularTotales(Modificar: boolean;
  DataTable: TDADataTable): Double;
begin
  Result := 0;
end;

constructor TDetallesMedicacionController.Create;
begin
  inherited;
  FDataModule := TDataModuleMedicacion.Create(Nil);
end;

function TDetallesMedicacionController.DarListaTiposDetalle: TStringList;
begin
  // inherited; <- No utilizar la herencia

  Result := TStringList.Create;
  Result.Values[TIPO_DETALLE_ENBLISTER] := TIPO_DETALLE_ENBLISTER;
  Result.Values[TIPO_DETALLE_NOBLISTER] := TIPO_DETALLE_NOBLISTER;
end;

destructor TDetallesMedicacionController.Destroy;
begin
  FDataModule := Nil;
  inherited;
end;

procedure TDetallesMedicacionController.ValidarCampos(DataTable: TDADataTable);
begin
  // No utilizar herencia para validar los campos.
  //inherited;
  //ValidarCamposLineaConcepto(DataTable);
end;

end.
