{
===============================================================================
  Copyright (©) 2007. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 
  Versión actual: 1.0.0
  Fecha versión actual: 
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uDataModuleRecibosCliente;

interface

uses
  SysUtils, Classes, DB, uDAClientDataModule, uDADataTable, uDABINAdapter,
  uDAScriptingProvider, uDACDSDataTable, uROWinInetHttpChannel, uROTypes,
  uROServiceComponent, uRORemoteService, uROClient, uROBinMessage,
  uDADesigntimeCall,

  uIDataModuleRecibosCliente, uIDataModuleRecibosClienteReport,
  uBizRecibosCliente, uBizPagosCliente;

type
  TDataModuleRecibosCliente = class(TDAClientDataModule, IDataModuleRecibosCliente, IDataModuleRecibosClienteReport)
    RORemoteService: TRORemoteService;
    DABinAdapter: TDABINAdapter;
    DADesigntimeCall1: TDADesigntimeCall;
    LoginRemoteService: TRORemoteService;
    ROWinInetHTTPChannel1: TROWinInetHTTPChannel;
    ROBinMessage1: TROBinMessage;
    tbl_RecibosCliente: TDACDSDataTable;
    ds_RecibosCliente: TDADataSource;
    tbl_PagosCliente: TDACDSDataTable;
    ds_PagosCliente: TDADataSource;
    tbl_RecibosCompensadosCli: TDACDSDataTable;
    ds_RecibosCompensadosCli: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);
  protected
    function DarNombreGenerador(DataSetName: String): String; virtual;
    function _CloneDataTable (const ADataTable : TDACDSDataTable): TDACDSDataTable; overload;
    function _GetPagos: IBizPagosCliente;
    function _GetRecibosCompensados : IBizRecibosCompensadosCli;
  public
    function GetNextID(const DataSetName : String) : Integer;
    function GetItems: IBizRecibosCliente;
    function GetItem(const ID : Integer) : IBizRecibosCliente;
    function NewItem : IBizRecibosCliente;
    function GetReport(const ID: String): Binary;
    
  end;

implementation

{$R *.DFM}

uses
  FactuGES_Intf, uDataModuleConexion, uDataTableUtils, cxControls, uDAInterfaces,
  schRecibosClienteClient_Intf;

{ TDataModuleRecibosCliente }


function TDataModuleRecibosCliente.GetReport(const ID: String): Binary;
begin
  Result := (RORemoteService as IsrvRecibosCliente).GenerateReport(ID);
end;

procedure TDataModuleRecibosCliente.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModuleRecibosCliente.DarNombreGenerador(DataSetName: String): String;
begin
  Result := '';
  if DataSetName = nme_RecibosCliente then
    Result := 'GEN_RECIBOS_CLIENTE_ID';
  if DataSetName = nme_PagosCliente then
    Result := 'GEN_PAGOS_CLIENTE_ID'
end;

function TDataModuleRecibosCliente.GetNextID(const DataSetName: String): Integer;
var
  aGeneratorName : String;
begin
  aGeneratorName := DarNombreGenerador(DataSetName);
  Result := (RORemoteService as IsrvRecibosCliente).GetNextAutoInc(aGeneratorName)
end;

function TDataModuleRecibosCliente._CloneDataTable(const ADataTable : TDACDSDataTable): TDACDSDataTable;
begin
  Result := NIL;

  if not Assigned(ADataTable) then
    raise Exception.Create ('No se ha asignado la tabla de origen (CloneDataTable)');

  Result := TDACDSDataTable.Create(NIL);
  CloneDataTable(ADataTable, Result);
end;

function TDataModuleRecibosCliente._GetPagos: IBizPagosCliente;
var
   APagos : TDACDSDataTable;
begin
   ShowHourglassCursor;
   try
     APagos := _CloneDataTable(tbl_PagosCliente);
     with APagos do
     begin
       BusinessRulesID := BIZ_CLIENT_IBIZPAGOSCLIENTE;
       DetailOptions := DetailOptions -
         [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
     end;
     Result := (APagos as IBizPagosCliente);
   finally
     HideHourglassCursor;
   end;
end;

function TDataModuleRecibosCliente._GetRecibosCompensados: IBizRecibosCompensadosCli;
var
  ARecibosCompensados : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    ARecibosCompensados := _CloneDataTable(tbl_RecibosCompensadosCli);
    with ARecibosCompensados do
    begin
      BusinessRulesID := BIZ_CLIENT_RECIBOS_COMPENSADOSCLI;
      DetailOptions := DetailOptions -
        [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (ARecibosCompensados as IBizRecibosCompensadosCli);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleRecibosCliente.GetItems: IBizRecibosCliente;
var
  AIBizRecibosCliente : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    AIBizRecibosCliente := _CloneDataTable(tbl_RecibosCliente);
    AIBizRecibosCliente.BusinessRulesID := BIZ_CLIENT_IBizRecibosCliente;

    with TBizRecibosCliente(AIBizRecibosCliente.BusinessEventsObj) do
         Pagos := _GetPagos;

    with TBizRecibosCliente(AIBizRecibosCliente.BusinessEventsObj) do
         RecibosCompensados := _GetRecibosCompensados;

    Result := (AIBizRecibosCliente as IBizRecibosCliente);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleRecibosCliente.NewItem: IBizRecibosCliente;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModuleRecibosCliente.GetItem(const ID: Integer): IBizRecibosCliente;
begin
  ShowHourglassCursor;
  try
    Result := Self.GetItems;
    with Result.DataTable.Where do
    begin
      if NotEmpty then
        AddOperator(opAND);
      OpenBraket;
      AddText(fld_RecibosClienteID + ' = ' + IntToStr(ID));
      CloseBraket;
    end;
  finally
    HideHourglassCursor;
  end;
end;

end.
