{
===============================================================================
  Copyright (©) 2007. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión:
  Versión actual: 1.0.0
  Fecha versión actual:
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uDataModuleRecibosProveedor;

interface

uses
  SysUtils, Classes, DB, uDAClientDataModule, uDADataTable, uDABINAdapter,
  uDAScriptingProvider, uDACDSDataTable, uROWinInetHttpChannel, uROTypes,
  uROServiceComponent, uRORemoteService, uROClient, uROBinMessage,
  uDADesigntimeCall,

  uIDataModuleRecibosProveedor, uIDataModuleRecibosProveedorReport,
  uBizRecibosProveedor, uBizPagosProveedor;

type
  TDataModuleRecibosProveedor = class(TDAClientDataModule, IDataModuleRecibosProveedor, IDataModuleRecibosProveedorReport)
    RORemoteService: TRORemoteService;
    DABinAdapter: TDABINAdapter;
    DADesigntimeCall1: TDADesigntimeCall;
    LoginRemoteService: TRORemoteService;
    ROWinInetHTTPChannel1: TROWinInetHTTPChannel;
    ROBinMessage1: TROBinMessage;
    tbl_PagosProveedor: TDACDSDataTable;
    ds_PagosProveedor: TDADataSource;
    tbl_RecibosProveedor: TDACDSDataTable;
    ds_RecibosProveedor: TDADataSource;
    tbl_RecibosCompensadosProv: TDACDSDataTable;
    ds_RecibosCompensadosProv: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);
  protected
    function DarNombreGenerador(DataSetName: String): String; virtual;
    function _CloneDataTable (const ADataTable : TDACDSDataTable): TDACDSDataTable; overload;
    function _GetPagos: IBizPagosProveedor;
    function _GetRecibosCompensados : IBizRecibosCompensadosProv;    
  public
    function GetNextID(const DataSetName : String) : Integer;
    function GetItems: IBizRecibosProveedor;
    function GetItem(const ID : Integer) : IBizRecibosProveedor;
    function NewItem : IBizRecibosProveedor;
    function GetReport(const ID: Integer): Binary;

  end;

implementation

{$R *.DFM}

uses
  FactuGES_Intf, uDataModuleConexion, uDataTableUtils, cxControls, uDAInterfaces,
  schRecibosProveedorClient_Intf;

{ TDataModuleRecibosProveedor }


function TDataModuleRecibosProveedor.GetReport(const ID: Integer): Binary;
begin
  Result := (RORemoteService as IsrvRecibosProveedor).GenerateReport(ID);
end;

procedure TDataModuleRecibosProveedor.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModuleRecibosProveedor.DarNombreGenerador(DataSetName: String): String;
begin
  Result := '';
  if DataSetName = nme_RecibosProveedor then
    Result := 'GEN_RECIBOS_PROVEEDOR_ID';
  if DataSetName = nme_PagosProveedor then
    Result := 'GEN_PAGOS_PROVEEDOR_ID'
end;

function TDataModuleRecibosProveedor.GetNextID(const DataSetName: String): Integer;
var
  aGeneratorName : String;
begin
  aGeneratorName := DarNombreGenerador(DataSetName);
  Result := (RORemoteService as IsrvRecibosProveedor).GetNextAutoInc(aGeneratorName)
end;

function TDataModuleRecibosProveedor._CloneDataTable(const ADataTable : TDACDSDataTable): TDACDSDataTable;
begin
  Result := NIL;

  if not Assigned(ADataTable) then
    raise Exception.Create ('No se ha asignado la tabla de origen (CloneDataTable)');

  Result := TDACDSDataTable.Create(NIL);
  CloneDataTable(ADataTable, Result);
end;

function TDataModuleRecibosProveedor._GetPagos: IBizPagosProveedor;
var
   APagos : TDACDSDataTable;
begin
   ShowHourglassCursor;
   try
     APagos := _CloneDataTable(tbl_PagosProveedor);
     with APagos do
     begin
       BusinessRulesID := BIZ_CLIENT_IBIZPAGOSPROVEEDOR;
       DetailOptions := DetailOptions -
         [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
     end;
     Result := (APagos as IBizPagosProveedor);
   finally
     HideHourglassCursor;
   end;
end;

function TDataModuleRecibosProveedor._GetRecibosCompensados: IBizRecibosCompensadosProv;
var
  ARecibosCompensados : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    ARecibosCompensados := _CloneDataTable(tbl_RecibosCompensadosProv);
    with ARecibosCompensados do
    begin
      BusinessRulesID := BIZ_CLIENT_RECIBOS_COMPENSADOSPROV;
      DetailOptions := DetailOptions -
        [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (ARecibosCompensados as IBizRecibosCompensadosProv);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleRecibosProveedor.GetItems: IBizRecibosProveedor;
var
  AIBizRecibosProveedor : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    AIBizRecibosProveedor := _CloneDataTable(tbl_RecibosProveedor);
    AIBizRecibosProveedor.BusinessRulesID := BIZ_CLIENT_IBizRecibosProveedor;

    with TBizRecibosProveedor(AIBizRecibosProveedor.BusinessEventsObj) do
         Pagos := _GetPagos;

    with TBizRecibosProveedor(AIBizRecibosProveedor.BusinessEventsObj) do
         RecibosCompensados := _GetRecibosCompensados;

    Result := (AIBizRecibosProveedor as IBizRecibosProveedor);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleRecibosProveedor.NewItem: IBizRecibosProveedor;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModuleRecibosProveedor.GetItem(const ID: Integer): IBizRecibosProveedor;
begin
  ShowHourglassCursor;
  try
    Result := Self.GetItems;
    with Result.DataTable.Where do
    begin
      if NotEmpty then
        AddOperator(opAND);
      OpenBraket;
      AddText(fld_RecibosProveedorID + ' = ' + IntToStr(ID));
      CloseBraket;
    end;
  finally
    HideHourglassCursor;
  end;
end;

end.
