LuisLeon_FactuGES/Source/Modulos/Pedidos de cliente/Data/uDataModulePedidosCliente.pas

unit uDataModulePedidosCliente;

interface

uses
  DB, Classes, SysUtils, uDADesigntimeCall, uROServiceComponent,
  uRORemoteService, uROClient, uROBinMessage, uDAScriptingProvider,
  uDACDSDataTable, uROWinInetHttpChannel, uDADataTable, uDABINAdapter,

  uDAClientDataModule, uROTypes,
  uIDataModulePedidosCliente, uBizPedidosCliente, uBizDetallesPedidoCliente,
  uIDataModulePedidosClienteReport;

type
  TDataModulePedidosCliente = class(TDAClientDataModule, IDataModulePedidosCliente, IDataModulePedidosClienteReport)
    ROChannel: TROWinInetHTTPChannel;
    ROMessage: TROBinMessage;
    RORemoteService: TRORemoteService;
    DABinAdapter: TDABINAdapter;
    DADesigntimeCall1: TDADesigntimeCall;
    LoginRemoteService: TRORemoteService;
    tbl_PedidosCliente: TDACDSDataTable;
    ds_PedidosCliente: TDADataSource;
    tbl_PedidosCliente_Detalles: TDACDSDataTable;
    ds_PedidosCliente_Detalles: TDADataSource;
    tbl_PedidoCliente_Articulos_Pendientes: TDACDSDataTable;
    ds_PedidoCliente_Articulos_Pendientes: TDADataSource;
    tbl_PedidoCliente_ArticulosPendientesPedirAProv: TDACDSDataTable;
    ds_PedidoCliente_ArticulosPendientesPedirAProv: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);

  private
    function _CloneDataTable (const ADataTable : TDACDSDataTable): TDACDSDataTable; overload;
    function _GetDetalles : IBizDetallesPedidoCliente;

  protected
    procedure AsignarClaseNegocio(var APedido: TDACDSDataTable); virtual;

  public
    function GetArticulosPendientesPedirAProv(const IDPedido: Integer): IBizPedidoClienteArticulosPendientesPedirAProv;
    function GetArticulosPendientes(const IDPedido: Integer): IBizPedidoClienteArticulosPend;
    function GetItems : IBizPedidoCliente; virtual;
    function GetItem(const ID : Integer) : IBizPedidoCliente;
    function GetNextID(const DataSetName : String) : Integer;
    function NewItem : IBizPedidoCliente;

    // Report
    function GetReport(const AID: String; const ShowLogotipo: Boolean = False): Binary;
    function GetRptPDF(const AID: Integer; const ShowLogotipo: Boolean = False): Binary;
  end;

implementation

{$R *.DFM}

uses
  cxControls, FactuGES_Intf, uDAInterfaces, uDataModuleConexion,
  uDataTableUtils, schPedidosClienteClient_Intf, uBizContactos;

{ TdmPedidosCliente }

procedure TDataModulePedidosCliente.AsignarClaseNegocio(var APedido: TDACDSDataTable);
begin
  APedido.BusinessRulesID := BIZ_CLIENT_PEDIDO_CLIENTE;
end;

procedure TDataModulePedidosCliente.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModulePedidosCliente.GetNextID(const DataSetName: String): Integer;
var
  aGeneratorName : String;
begin
  if DataSetName = nme_PedidosCliente then
    aGeneratorName := 'GEN_PEDIDOS_CLI_ID';

  if DataSetName = nme_PedidosCliente_Detalles then
    aGeneratorName := 'GEN_PEDIDOS_CLI_DETALLES_ID';

  Result := (RORemoteService as IsrvPedidosCliente).GetNextAutoInc(aGeneratorName)
end;

function TDataModulePedidosCliente.GetReport(const AID: String; const ShowLogotipo: Boolean = False): Binary;
begin
  Result := (RORemoteService as IsrvPedidosCliente).GenerateReport(AID, ShowLogotipo)
end;

function TDataModulePedidosCliente.GetRptPDF(const AID: Integer;
  const ShowLogotipo: Boolean): Binary;
var
  AParam : TIntegerArray;
begin
  AParam := TIntegerArray.Create;
  try
    AParam.Add(AID);
    Result := (RORemoteService as IsrvPedidosCliente).GenerarReportPDF(AParam, ShowLogotipo)
  finally
    FreeANDNIL(AParam)
  end;
end;

function TDataModulePedidosCliente.NewItem: IBizPedidoCliente;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModulePedidosCliente._CloneDataTable(const ADataTable : TDACDSDataTable): TDACDSDataTable;
begin
  Result := NIL;

  if not Assigned(ADataTable) then
    raise Exception.Create ('No se ha asignado la tabla de origen (CloneDataTable)');

  Result := TDACDSDataTable.Create(NIL);
  CloneDataTable(ADataTable, Result);
end;

function TDataModulePedidosCliente._GetDetalles: IBizDetallesPedidoCliente;
var
  ADetalles : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    ADetalles := _CloneDataTable(tbl_PedidosCliente_Detalles);
    with ADetalles do
    begin
      BusinessRulesID := BIZ_CLIENT_DETALLES_PEDIDO_CLIENTE;
      DetailOptions := DetailOptions -
        [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (ADetalles as IBizDetallesPedidoCliente);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetArticulosPendientes(
  const IDPedido: Integer): IBizPedidoClienteArticulosPend;
var
  AArticulos : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    AArticulos := _CloneDataTable(tbl_PedidoCliente_Articulos_Pendientes);
    AArticulos.BusinessRulesID := BIZ_CLIENT_ARTICULOS_PEND_PEDIDO_CLIENTE;
    AArticulos.ParamByName('ID_PEDIDO').AsInteger := IDPedido;
    Result := (AArticulos as IBizPedidoClienteArticulosPend);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetArticulosPendientesPedirAProv(
  const IDPedido: Integer): IBizPedidoClienteArticulosPendientesPedirAProv;
var
  AArticulos : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    AArticulos := _CloneDataTable(tbl_PedidoCliente_ArticulosPendientesPedirAProv);
    AArticulos.BusinessRulesID := BIZ_CLIENT_PEDIDO_CLIENTE_ARTICULOS_PENDIENTES_PEDIR_A_PROV;
    AArticulos.ParamByName('ID_PEDIDO').AsInteger := IDPedido;
    Result := (AArticulos as IBizPedidoClienteArticulosPendientesPedirAProv);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetItem(const ID: Integer): IBizPedidoCliente;
begin
  ShowHourglassCursor;
  try
    Result := Self.GetItems;
    with Result.DataTable.Where do
    begin
      if NotEmpty then
         AddOperator(opAND);
      OpenBraket;
      AddText(fld_PedidosClienteID + ' = ' + IntToStr(ID));
      CloseBraket;
    end;
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetItems: IBizPedidoCliente;
var
  APedido : TDACDSDataTable;
begin
  ShowHourglassCursor;
  try
    APedido := _CloneDataTable(tbl_PedidosCliente);

    // EL CAMPO REFERENCIA Y SITUACI<43>N TIENEN QUE SER AUTOREFRESH!!!!!
    APedido.FieldByName(fld_PedidosClienteREFERENCIA).ServerAutoRefresh := TRUE;
    APedido.FieldByName(fld_PedidosClienteSITUACION).ServerAutoRefresh := TRUE;

    AsignarClaseNegocio(APedido);

    with TBizPedidoCliente(APedido.BusinessEventsObj) do
    begin
      Detalles := _GetDetalles;
    end;

    Result := (APedido as IBizPedidoCliente);
  finally
    HideHourglassCursor;
  end;
end;

end.