unit uRecibosClienteReportController;

interface

uses
  Classes, SysUtils, uDADataTable, uControllerBase, uIDataModuleRecibosClienteReport,
  uBizRecibosCliente;

type
  IRecibosClienteReportController = interface
  ['{3837DFA3-0A38-4BB2-B0DB-D0615249EA49}']
    procedure Preview(const ID : String);
    function Print(const ID : String): Boolean;
    function ExportToPDF(const AID: Integer; const AFileName : String = ''): Boolean;    
  end;

  TRecibosClienteReportController = class(TInterfacedObject, IRecibosClienteReportController)
  private
    FDataModule : IDataModuleRecibosClienteReport;
    function CreateEditor(const AName: String; const IID: TGUID; out Intf): Boolean;
  public
    constructor Create;
    destructor Destroy; override;

    procedure Preview(const ID : String);
    function Print(const ID : String): Boolean;
    function ExportToPDF(const AID: Integer; const AFileName : String = ''): Boolean;
  end;


implementation

uses
  uROTypes, uEditorRegistryUtils, uIEditorRecibosClientePreview,
  uEditorPreview, uDataModuleRecibosCliente, uEditorBase, cxControls,
  schRecibosClienteClient_Intf, uStringsUtils;

{ TRecibosClienteReportController }

constructor TRecibosClienteReportController.Create;
begin
  FDataModule := TDataModuleRecibosCliente.Create(Nil);
end;

function TRecibosClienteReportController.CreateEditor(const AName: String;
  const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;


destructor TRecibosClienteReportController.Destroy;
begin
  FDataModule := NIL;
  inherited;
end;

function TRecibosClienteReportController.ExportToPDF(const AID: Integer; const AFileName: String): Boolean;
var
  AStream: Binary;
begin
  Result := False;
  if EsCadenaVacia(AFileName) then
    Exit;

  ShowHourglassCursor;
  try
    AStream := FDataModule.GetRptPDF(AID, True);
    try
      AStream.SaveToFile(AFileName);
      Result := True;
    finally
      FreeAndNil(AStream);
    end;
  finally
    HideHourglassCursor;
  end;
end;

procedure TRecibosClienteReportController.Preview(const ID : String);
var
  AStream: Binary;
  AEditor : IEditorRecibosClientePreview;
begin
  AEditor := NIL;

  ShowHourglassCursor;
  try
    AStream := FDataModule.GetReport(ID);
    try
      CreateEditor('EditorRecibosClientePreview', IEditorRecibosClientePreview, AEditor);
      AEditor.LoadFromStream(AStream);
    finally
      AStream.Free;
    end;
  finally
    HideHourglassCursor;
  end;

  if Assigned(AEditor) then
    AEditor.Preview;
end;

function TRecibosClienteReportController.Print(const ID : String): Boolean;
var
  AStream: Binary;
  AEditor : IEditorRecibosClientePreview;
begin
  Result := False;
  AEditor := NIL;

  ShowHourglassCursor;
  try
  AStream := FDataModule.GetReport(ID);
    try
      CreateEditor('EditorRecibosClientePreview', IEditorRecibosClientePreview, AEditor);
      AEditor.LoadFromStream(AStream);
    finally
      AStream.Free;
    end;
  finally
    HideHourglassCursor;
  end;

  if Assigned(AEditor) then
  begin
    AEditor.TablaImpresion := nme_RecibosCliente;
    AEditor.IdTablaImpresion := ID;
    Result := AEditor.Print;
  end;
end;

end.