unit uPedidosClienteController;

interface


uses
  SysUtils, uDADataTable, uEditorDBItem,
  uControllerBase, uIDataModulePedidosCliente, uClientesController,
  uDetallesPedidoClienteController, uBizPedidosCliente;

type
  IPedidosClienteController = interface(IObservador)
  ['{E758001D-FFAF-4142-BFCA-F50AED742F0E}']
    function GetClienteController: IClientesController;
    procedure SetClienteController(const Value: IClientesController);
    property ClienteController: IClientesController read GetClienteController write SetClienteController;

    function GetDetallesController: IDetallesPedidoClienteController;
    procedure SetDetallesController(const Value: IDetallesPedidoClienteController);
    property DetallesController: IDetallesPedidoClienteController read GetDetallesController write SetDetallesController;

    function Buscar(const ID: Integer): IBizPedidoCliente;
    function BuscarTodos: IBizPedidoCliente;
    procedure Ver(APedido : IBizPedidoCliente);
    procedure VerTodos(APedidos: IBizPedidoCliente);
    function Nuevo : IBizPedidoCliente;
    procedure Anadir(APedido : IBizPedidoCliente);
    procedure Eliminar(const ID : Integer); overload;
    procedure Eliminar(APedido : IBizPedidoCliente); overload;
    procedure Guardar(APedido : IBizPedidoCliente);
    procedure DescartarCambios(APedido : IBizPedidoCliente);
    function Existe(const ID: Integer) : Boolean;
    function Duplicar(APedido: IBizPedidoCliente): IBizPedidoCliente;
//    procedure Preview(APedido : IBizPedidoCliente);
//    procedure Print(APedido : IBizPedidoCliente);
  end;

  TPedidosClienteController = class(TObservador, IPedidosClienteController)
  protected
    FDataModule : IDataModulePedidosCliente;
    FClienteController : IClientesController;
    FDetallesController : IDetallesPedidoClienteController;

    function GetClienteController: IClientesController;
    procedure SetClienteController(const Value: IClientesController);
    procedure RecuperarCliente(APedido : IBizPedidoCliente);
    function GetDetallesController: IDetallesPedidoClienteController;
    procedure SetDetallesController(const Value: IDetallesPedidoClienteController);

    //Estos son los tres métodos a sobre escribir si se desea heredar toda la logica de
    //este controller
    procedure AsignarDataModule; virtual;
    procedure RecuperarObjetos(APedido: IBizPedidoCliente); virtual;
    procedure AsignarEditor(out AEditor: IEditorDBItem); virtual;

    procedure RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable); override;
    procedure AssignarID(APedido: IBizPedidoCliente; ADataModule : IDataModulePedidosCliente);
    function CreateEditor(const AName : String; const IID: TGUID; out Intf): Boolean;
    procedure FiltrarEmpresa(APedido: IBizPedidoCliente);
    function _Vacio : IBizPedidoCliente;
    function ValidarPedido(APedido: IBizPedidoCliente): Boolean;
  public
    property ClienteController: IClientesController read GetClienteController write SetClienteController;
    property DetallesController: IDetallesPedidoClienteController read GetDetallesController write SetDetallesController;

    constructor Create;
    destructor Destroy; override;

    procedure Eliminar(const ID : Integer); overload;
    procedure Eliminar(APedido : IBizPedidoCliente); overload;
    procedure Guardar(APedido : IBizPedidoCliente);
    procedure DescartarCambios(APedido : IBizPedidoCliente); virtual;
    function Existe(const ID: Integer) : Boolean; virtual;
    procedure Anadir(APedido : IBizPedidoCliente);
    function Buscar(const ID: Integer): IBizPedidoCliente;
    function BuscarTodos: IBizPedidoCliente;
    function Nuevo : IBizPedidoCliente;
    procedure Ver(APedido : IBizPedidoCliente);
    procedure VerTodos(APedidos: IBizPedidoCliente);
    function Duplicar(APedido: IBizPedidoCliente): IBizPedidoCliente;
//    procedure Preview(APedido : IBizPedidoCliente);
//    procedure Print(APedido : IBizPedidoCliente);
  end;

implementation

uses
  uROTypes, cxControls, DB, uEditorRegistryUtils, uEditorPreview, DateUtils,
  uIEditorPedidosCliente, uDataModulePedidosCliente,
  uBizDetallesPedidoCliente, uBizContactos, uDataTableUtils, uDataModuleUsuarios,
  schPedidosClienteClient_Intf, uDAInterfaces, uDateUtils, uIEditorPedidoCliente;

{ TPedidosClienteController }

procedure TPedidosClienteController.Anadir(APedido: IBizPedidoCliente);
begin
  APedido.Insert;
end;

procedure TPedidosClienteController.AsignarDataModule;
begin
  FDataModule := TDataModulePedidosCliente.Create(Nil);
end;

procedure TPedidosClienteController.AsignarEditor(out AEditor: IEditorDBItem);
begin
  CreateEditor('EditorPedidoCliente', IEditorPedidoCliente, AEditor);
end;

procedure TPedidosClienteController.AssignarID(APedido: IBizPedidoCliente; ADataModule : IDataModulePedidosCliente);
var
  NuevoIDCabecera : Integer;
begin
  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignada');

  if not Assigned(FDetallesController) then
    raise Exception.Create ('Controller detalles no asignado');

  { ¡¡¡ OJO !!!
    Primero cambiamos el ID de las tablas detalles
    porque si cambiamos antes el ID de la cabecera
    deja de funcionar la relacion M/D y no
    encontraríamos las filas detalle.

      -->  MASTER.ID = DETAIL.ID_FACTURA <--
  }

  NuevoIDCabecera := ADataModule.GetNextID(APedido.DataTable.LogicalName);
  FDetallesController.AssignarIDDetalles(False, APedido.Detalles, NuevoIDCabecera, ADataModule);

  APedido.Edit;
  APedido.ID := NuevoIDCabecera;
  APedido.Post;
end;

function TPedidosClienteController.Buscar(const ID: Integer): IBizPedidoCliente;
begin
  Result := FDataModule.GetItem(ID);
  FiltrarEmpresa(Result);
end;

function TPedidosClienteController.BuscarTodos: IBizPedidoCliente;
begin
  Result := FDataModule.GetItems;
  FiltrarEmpresa(Result);
end;

constructor TPedidosClienteController.Create;
begin
  AsignarDataModule;
  
  FClienteController := TClientesController.Create;
  FDetallesController := TDetallesPedidoClienteController.Create;
  FDetallesController.addObservador(Self);
end;

function TPedidosClienteController.CreateEditor(const AName: String;
  const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;

procedure TPedidosClienteController.DescartarCambios(APedido: IBizPedidoCliente);
begin
  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignada');

  ShowHourglassCursor;
  try
    if (APedido.State in dsEditModes) then
      APedido.Cancel;

    APedido.DataTable.CancelUpdates;
  finally
    HideHourglassCursor;
  end;
end;

destructor TPedidosClienteController.Destroy;
begin
  FDataModule := Nil;
  FClienteController := Nil;
  FDetallesController := Nil;
  inherited;
end;

function TPedidosClienteController.Duplicar(
  APedido: IBizPedidoCliente): IBizPedidoCliente;
begin
  Result := Self._Vacio;
  ShowHourglassCursor;
  try
    DuplicarRegistros(APedido.DataTable, Result.DataTable, mdrActual);
    DuplicarRegistros(APedido.Detalles.DataTable, Result.Detalles.DataTable, mdrTodos);

    // Hay que dejar algunos campos como si fuera un presupuesto nuevo
    Result.Edit;
    with Result do
    begin
      ID_EMPRESA := dmUsuarios.IDEmpresaActual;
      USUARIO := dmUsuarios.LoginInfo.Usuario;
      FECHA_PEDIDO := DateOf(Now);
      SITUACION := SITUACION_PEDIDO_PENDIENTE;
      FECHA_CONFIRMACION := 0;
      FECHA_ENTREGA := 0;
      INCIDENCIAS_ACTIVAS := 0;      
    end;
    Result.Post;
  finally
    HideHourglassCursor;
  end;
end;

function TPedidosClienteController.ValidarPedido(
  APedido: IBizPedidoCliente): Boolean;
var
  AFechaPagado : TDateTime;
begin
  Result := False;
  if (APedido.ID_Cliente < 0) or
     (not Assigned(APedido.Cliente)) or
     (APedido.Cliente.IsEmpty) then
    raise Exception.Create('Debe indicar el Cliente de esta pedido');

  if (EsFechaVacia(APedido.FECHA_PEDIDO)) then
    raise Exception.Create('Debe indicar la fecha de este pedido');

  if Length(APedido.REFERENCIA) = 0 then
    raise Exception.Create('Debe indicar una referencia para este pedido');

  // Asegurarse de valores en campos "automáticos"
  APedido.Edit;
  try
    APedido.USUARIO := dmUsuarios.LoginInfo.Usuario;

    if Assigned(APedido.Cliente) then
      APedido.ID_Cliente := APedido.Cliente.ID;

    Result := True;      
  finally
    APedido.Post;
  end;
end;

procedure TPedidosClienteController.Ver(APedido: IBizPedidoCliente);
var
  AEditor : IEditorDBItem;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    RecuperarObjetos(APedido);
    AsignarEditor(AEditor);

    with (AEditor as IEditorPedidoCliente) do
    begin
      Controller := Self; //OJO ORDEN MUY IMPORTANTE
      Pedido := APedido;
    end;
  finally
    HideHourglassCursor;
  end;

  if Assigned(AEditor) then
    try
      AEditor.ShowModal;
    finally
      AEditor := NIL;
    end;
end;

procedure TPedidosClienteController.VerTodos(APedidos: IBizPedidoCliente);
var
  AEditor : IEditorPedidosCliente;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    CreateEditor('EditorPedidosCliente', IEditorPedidosCliente, AEditor);
    with AEditor do
    begin
      Controller := Self; //OJO ORDEN MUY IMPORTANTE
      Pedidos := APedidos;
    end;
  finally
    HideHourglassCursor;
  end;

  if Assigned(AEditor) then
    try
      AEditor.ShowEmbedded;
    finally
      AEditor := NIL;
    end;
end;

function TPedidosClienteController._Vacio: IBizPedidoCliente;
begin
  Result := Buscar(ID_NULO);
end;

procedure TPedidosClienteController.Eliminar(const ID: Integer);
var
  APedido : IBizPedidoCliente;
begin
  APedido := Buscar(ID);

  if not Assigned(APedido) then
    raise Exception.Create(Format('No se ha encontrado el pedido con ID = %d', [ID]));

  Eliminar(APedido);
  APedido := NIL;
end;

procedure TPedidosClienteController.Eliminar(APedido: IBizPedidoCliente);
begin
  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignada');

  ShowHourglassCursor;
  try
    if (APedido.State in dsEditModes) then
      APedido.Cancel;

    APedido.Delete;
    APedido.DataTable.ApplyUpdates;
  finally
    HideHourglassCursor;
  end;
end;
procedure TPedidosClienteController.RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable);
var
  APedido : IBizPedidoCliente;
  ADetalles : IBizDetallesPedidoCliente;
begin
  inherited;

  if Supports(ADataTable, IBizDetallesPedidoCliente, ADetalles) and
     Supports(ADetalles.DataTable.MasterSource.DataTable, IBizPedidoCliente, APedido) then
  begin
    APedido.Edit;
    try
      APedido.IMPORTE_TOTAL := FDetallesController.DarTotalImporteTotal(ADetalles);
    finally
      APedido.Post;
    end;
  end;
end;

procedure TPedidosClienteController.RecuperarObjetos(APedido: IBizPedidoCliente);
begin
  RecuperarCliente(APedido);
end;

procedure TPedidosClienteController.RecuperarCliente(
  APedido: IBizPedidoCliente);
begin
  APedido.Cliente := (FClienteController.Buscar(APedido.ID_Cliente)  as IBizCliente);
end;

function TPedidosClienteController.Existe(const ID: Integer): Boolean;
var
  APedido : IBizPedidoCliente;
begin
  try
    APedido := Buscar(ID);
    Result := Assigned(APedido) and (APedido.ID = ID);
  finally
    APedido := NIL;
  end;
end;

procedure TPedidosClienteController.FiltrarEmpresa(
  APedido: IBizPedidoCliente);
begin
  if APedido.DataTable.Active then
    APedido.DataTable.Active := False;

  // Filtrar los presupuestos actuales por empresa
  with APedido.DataTable.Where do
  begin
    if NotEmpty then
      AddOperator(opAND);
    AddCondition(fld_PedidosClienteID_EMPRESA, cEqual, dmUsuarios.IDEmpresaActual);
  end;
end;

procedure TPedidosClienteController.SetClienteController(const Value: IClientesController);
begin
  FClienteController := Value;
end;

procedure TPedidosClienteController.SetDetallesController(const Value: IDetallesPedidoClienteController);
begin
  FDetallesController := Value;
end;

procedure TPedidosClienteController.Guardar(APedido: IBizPedidoCliente);
begin
  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignada');

  if not Assigned(FDetallesController) then
    raise Exception.Create ('Controller detalles no asignado');

  if ValidarPedido(APedido) then
  begin
    ShowHourglassCursor;
    try
      if (APedido.DataTable.State in dsEditModes) then
          APedido.DataTable.Post;

      //Tambien hacemos post de sus tablas hija
      if (APedido.Detalles.DataTable.State in dsEditModes) then
          APedido.Detalles.DataTable.Post;

      if (APedido.ID < 0) then
        AssignarID(APedido, (FDataModule as IDataModulePedidosCliente))
      else
        FDetallesController.AssignarIDDetalles(True, APedido.Detalles, APedido.ID, (FDataModule as IDataModulePedidosCliente));

      APedido.DataTable.ApplyUpdates;
    finally
      HideHourglassCursor;
    end;
  end;
end;

function TPedidosClienteController.Nuevo: IBizPedidoCliente;
var
  APedido : IBizPedidoCliente;
begin
  APedido := FDataModule.NewItem;
  FiltrarEmpresa(APedido);
  APedido.DataTable.Active := True;
  APedido.Insert;
  Result := APedido;
end;

{procedure TPedidosClienteController.Preview(APedido: IBizPedidoCliente);
var
  AReportController : IPedidosClienteReportController;
begin
  AReportController := TPedidosClienteReportController.Create;
  try
    AReportController.Preview(APedido.ID);
  finally
    AReportController := NIL;
  end;
end;}

{procedure TPedidosClienteController.Print(APedido: IBizPedidoCliente);
var
  AReportController : IPedidosClienteReportController;
begin
  AReportController := TPedidosClienteReportController.Create;
  try
    AReportController.Print(APedido.ID);
  finally
    AReportController := NIL;
  end;
end;}

function TPedidosClienteController.GetClienteController: IClientesController;
begin
  Result := FClienteController;
end;

function TPedidosClienteController.GetDetallesController: IDetallesPedidoClienteController;
begin
  Result := FDetallesController;
end;

end.