unit uBizPedidosCliente;

interface

uses
  Classes, uDADataTable, schPedidosClienteClient_Intf,
  uBizContactos, uBizDetallesPedidoCliente;

const
  BIZ_CLIENT_PEDIDO_CLIENTE = 'Client.PedidoCliente';

  SITUACION_PEDIDO_PENDIENTE = 'Pendiente';
  SITUACION_PEDIDO_ENVIADO = 'Enviado';

type
  IBizPedidoCliente = interface(IPedidosCliente)
  ['{86A2FAD7-D125-47C2-B0BA-52A42FDFA6F6}']

    procedure SetCliente(AValue : IBizCliente);
    function GetCliente : IBizCliente;
    property Cliente : IBizCliente read GetCliente write SetCliente;

    function GetDetalles: IBizDetallesPedidoCliente;
    procedure SetDetalles(Value: IBizDetallesPedidoCliente);
    property Detalles: IBizDetallesPedidoCliente read GetDetalles write SetDetalles;

    function EsNuevo : Boolean;
    function DarListaSituaciones: TStringList;
  end;

  TBizPedidoCliente = class(TPedidosClienteDataTableRules, IBizPedidoCliente)
  protected
    FCliente : IBizCliente;
    FDetalles : IBizDetallesPedidoCliente;
    FDetallesLink : TDADataSource;

    procedure SetCliente(AValue : IBizCliente);
    function GetCliente : IBizCliente;

    function GetDetalles: IBizDetallesPedidoCliente;
    procedure SetDetalles(Value: IBizDetallesPedidoCliente);

    procedure SetFECHA_CONFIRMACIONValue(const aValue: TDateTime); override;
    procedure SetFECHA_ENTREGAValue(const aValue: TDateTime); override;
    procedure SetFECHA_PEDIDOValue(const aValue: TDateTime); override;

    procedure OnNewRecord(Sender: TDADataTable); override;
    procedure SetIDValue(const aValue: Integer); override;
    procedure IniciarValoresPedidoNuevo;
  public
    function DarListaSituaciones: TStringList;
    function EsNuevo : Boolean;
    property Cliente : IBizCliente read GetCliente write SetCliente;
    property Detalles: IBizDetallesPedidoCliente read GetDetalles write SetDetalles;

    constructor Create(aDataTable: TDADataTable); override;
    destructor Destroy; override;
  end;

implementation

uses
  SysUtils, Variants, uDataModuleConfiguracion, uDataModuleUsuarios,
  uDataTableUtils, DateUtils, uDateUtils;

{ TBizPedidoCliente }

constructor TBizPedidoCliente.Create(aDataTable: TDADataTable);
var
  Ruta: Variant;

begin
  inherited;
  FCliente := Nil;
  FDetallesLink := TDADataSource.Create(NIL);
  FDetallesLink.DataTable := aDataTable;
end;

function TBizPedidoCliente.DarListaSituaciones: TStringList;
begin
  Result := TStringList.Create;
  with Result do
  begin
    Add(SITUACION_PEDIDO_PENDIENTE);
    Add(SITUACION_PEDIDO_ENVIADO);
  end;
end;

destructor TBizPedidoCliente.Destroy;
begin
  FCliente := NIL;
  FDetalles := NIL;
  FDetallesLink.Free;
  inherited;
end;

function TBizPedidoCliente.EsNuevo: Boolean;
begin
  Result := (ID < 0);
end;

function TBizPedidoCliente.GetCliente: IBizCliente;
begin
  Result := FCliente;
end;

procedure TBizPedidoCliente.IniciarValoresPedidoNuevo;
begin
  ID_EMPRESA := dmUsuarios.IDEmpresaActual;
  USUARIO := dmUsuarios.LoginInfo.Usuario;
  FECHA_PEDIDO := DateOf(Date);
  SITUACION := SITUACION_PEDIDO_PENDIENTE;
  INCIDENCIAS_ACTIVAS := 0;
end;

function TBizPedidoCliente.GetDetalles: IBizDetallesPedidoCliente;
begin
  Result := FDetalles;
end;

procedure TBizPedidoCliente.OnNewRecord(Sender: TDADataTable);
begin
  inherited;
  ID := GetRecNo; // -1, -2, -3...
  IniciarValoresPedidoNuevo;
end;

procedure TBizPedidoCliente.SetCliente(AValue: IBizCliente);
begin
  FCliente := AValue;

  if Assigned(FCliente) then
  begin
    if not FCliente.DataTable.Active then
      FCliente.DataTable.Active := True;

    if ID_Cliente <> FCliente.ID then
    begin
      DataTable.Edit;
      ID_CLIENTE := FCliente.ID;
    end;
  end;
end;

procedure TBizPedidoCliente.SetDetalles(Value: IBizDetallesPedidoCliente);
begin
  FDetalles := Value;
  EnlazarMaestroDetalle(FDetallesLink, FDetalles);
end;

procedure TBizPedidoCliente.SetFECHA_CONFIRMACIONValue(const aValue: TDateTime);
begin
  inherited;
  if EsFechaVacia(aValue) then
    DataTable.Fields[idx_PedidosClienteFECHA_CONFIRMACION].AsVariant := Null
  else
    inherited;
end;

procedure TBizPedidoCliente.SetFECHA_ENTREGAValue(const aValue: TDateTime);
begin
  inherited;
  if EsFechaVacia(aValue) then
    DataTable.Fields[idx_PedidosClienteFECHA_ENTREGA].AsVariant := Null
  else
    inherited;
end;

procedure TBizPedidoCliente.SetFECHA_PEDIDOValue(const aValue: TDateTime);
begin
  inherited;
  if EsFechaVacia(aValue) then
    DataTable.Fields[idx_PedidosClienteFECHA_PEDIDO].AsVariant := Null
  else
    inherited;
end;

procedure TBizPedidoCliente.SetIDValue(const aValue: Integer);
begin
  inherited;
end;

initialization
  RegisterDataTableRules(BIZ_CLIENT_PEDIDO_CLIENTE, TBizPedidoCliente);

finalization

end.