unit uFacturasProveedorController;

interface


uses
  Classes, SysUtils, uDADataTable, uControllerBase, uIDataModuleFacturasProveedor,
  uProveedoresController, uDetallesFacturaProveedorController, uBizFacturasProveedor,
  uBizAlbaranesProveedor, uViewGridBase;

type
  IFacturasProveedorController = interface(IObservador)
  ['{3868267C-E61A-4B79-AF61-648B2D627F56}']
    function GetProveedorController: IProveedoresController;
    procedure SetProveedorController(const Value: IProveedoresController);
    property ProveedorController: IProveedoresController read GetProveedorController write SetProveedorController;

    function GetDetallesController: IDetallesFacturaProveedorController;
    procedure SetDetallesController(const Value: IDetallesFacturaProveedorController);
    property DetallesController: IDetallesFacturaProveedorController read GetDetallesController write SetDetallesController;

    function Buscar(const ID: Integer): IBizFacturaProveedor;
    function BuscarTodos: IBizFacturaProveedor;
    procedure Ver(AFactura : IBizFacturaProveedor);
    procedure VerTodos(AFacturas: IBizFacturaProveedor);
    function Nuevo : IBizFacturaProveedor;
    function Anadir(AFactura : IBizFacturaProveedor) : Boolean; overload;
    function AnadirAbono(AFactura : IBizFacturaProveedor) : Boolean;
    function Anadir(AFacturas : IBizFacturaProveedor; AListaAlbaranes : IBizAlbaranProveedor): Boolean; overload;
    function Anadir(AFactura : IBizFacturaProveedor; const IDPedido : Integer): Boolean; overload;

    function Eliminar(const ID : Integer): Boolean; overload;
    function Eliminar(AFactura : IBizFacturaProveedor; AllItems: Boolean = false): Boolean; overload;
    function Guardar(AFactura : IBizFacturaProveedor): Boolean;
    procedure DescartarCambios(AFactura : IBizFacturaProveedor);
    function Existe(const ID: Integer) : Boolean;
    procedure RecuperarProveedor(AFactura : IBizFacturaProveedor);
    function Duplicar(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;
    function GenerarAbono(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;

    procedure Preview(AFactura : IBizFacturaProveedor; AllItems: Boolean = false);
    function Print(AFactura : IBizFacturaProveedor; AllItems: Boolean = false): Boolean;

    procedure RecalcularImportes(FFactura: IBizFacturaProveedor);
    function EsModificable(AFactura: IBizFacturaProveedor): Boolean;
    function EsEliminable(AFactura: IBizFacturaProveedor): Boolean;

    function ElegirFacturas(AFacturas : IBizFacturaProveedor; AMensaje: String; AMultiSelect: Boolean): IBizFacturaProveedor;
    function ExtraerSeleccionados(ARecibosProveedor: IBizFacturaProveedor; Const ViewGrid: IViewGridBase = Nil) : IBizFacturaProveedor;

    function EnviarEmailFacturas(AFacturas : IBizFacturaProveedor): Boolean;
    function GenerarEmailFactura(AFactura : IBizFacturaProveedor): Boolean;
    function EnviarFacturaPorEMail(AFactura: IBizFacturaProveedor;
      const AEnviarDirectamente: Boolean = True;
      const ADireccionEMail: String = ''; const AAsuntoEMail: String = '';
      const ATextoEMail: String = ''): Boolean;

    function DarListaAnosFacturas: TStringList;
    procedure FiltrarAno(AFactura: IBizFacturaProveedor; AWhereDataTable: String; const Ano: String);
  end;

  TFacturasProveedorController = class(TObservador, IFacturasProveedorController)
  private
    FDataModule : IDataModuleFacturasProveedor;
    FProveedorController : IProveedoresController;
    FDetallesController : IDetallesFacturaProveedorController;

    function GetProveedorController: IProveedoresController;
    procedure SetProveedorController(const Value: IProveedoresController);

    function GetDetallesController: IDetallesFacturaProveedorController;
    procedure SetDetallesController(const Value: IDetallesFacturaProveedorController);

    procedure AsignarID(AFactura: IBizFacturaProveedor; const IDNuevo : Integer);
    function CreateEditor(const AName : String; const IID: TGUID; out Intf): Boolean;
    function _Vacio : IBizFacturaProveedor;

    procedure FiltrarEmpresa(AFactura: IBizFacturaProveedor);

    function ValidarFactura(AFactura: IBizFacturaProveedor): Boolean;
    procedure GenerarRecibos(AFactura: IBizFacturaProveedor);
    procedure _AnadirMarcaEnvioCorreo(AFactura: IBizFacturaProveedor);

  protected
    procedure RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable); override;

  public
    property ProveedorController: IProveedoresController read GetProveedorController write SetProveedorController;
    property DetallesController: IDetallesFacturaProveedorController read GetDetallesController write SetDetallesController;

    constructor Create; virtual;
    destructor Destroy; override;

    function Eliminar(const ID : Integer): Boolean; overload;
    function Eliminar(AFactura : IBizFacturaProveedor; AllItems: Boolean = false): Boolean; overload;
    function Guardar(AFactura : IBizFacturaProveedor): Boolean;
    procedure DescartarCambios(AFactura : IBizFacturaProveedor); virtual;
    function Existe(const ID: Integer) : Boolean; virtual;
    function Anadir(AFactura : IBizFacturaProveedor) : Boolean; overload;
    function AnadirAbono(AFactura : IBizFacturaProveedor) : Boolean;
    function Anadir(AFacturas : IBizFacturaProveedor; AListaAlbaranes : IBizAlbaranProveedor): Boolean; overload;
    function Anadir(AFactura : IBizFacturaProveedor; const IDPedido : Integer): Boolean; overload;
    function Buscar(const ID: Integer): IBizFacturaProveedor;
    function BuscarTodos: IBizFacturaProveedor;
//    function BuscarTodasPendientesComision(IdAgente: Integer; IdComision: Integer; IdFacturasAsociadas: String): IBizFacturaProveedor;
    function Nuevo : IBizFacturaProveedor;
    procedure Ver(AFactura : IBizFacturaProveedor);
    procedure VerTodos(AFacturas: IBizFacturaProveedor);
    function Duplicar(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;
    function GenerarAbono(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;
    procedure RecuperarProveedor(AFactura : IBizFacturaProveedor);

    procedure Preview(AFactura : IBizFacturaProveedor; AllItems: Boolean = false);
    function Print(AFactura : IBizFacturaProveedor; AllItems: Boolean = false): Boolean;

    procedure RecalcularImportes(FFactura: IBizFacturaProveedor);
    function EsModificable(AFactura: IBizFacturaProveedor): Boolean;
    function EsEliminable(AFactura: IBizFacturaProveedor): Boolean;

    function ElegirFacturas(AFacturas : IBizFacturaProveedor; AMensaje: String; AMultiSelect: Boolean): IBizFacturaProveedor;
    function ExtraerSeleccionados(AFacturasProveedor: IBizFacturaProveedor; Const ViewGrid: IViewGridBase = Nil) : IBizFacturaProveedor;

    function EnviarEmailFacturas(AFacturas : IBizFacturaProveedor): Boolean;
    function GenerarEmailFactura(AFactura : IBizFacturaProveedor): Boolean;
    function EnviarFacturaPorEMail(AFactura: IBizFacturaProveedor;
      const AEnviarDirectamente: Boolean = True;
      const ADireccionEMail: String = ''; const AAsuntoEMail: String = '';
      const ATextoEMail: String = ''): Boolean;

    function DarListaAnosFacturas: TStringList;
    procedure FiltrarAno(AFactura: IBizFacturaProveedor; AWhereDataTable: String; const Ano: String);
  end;

implementation

uses
  Windows, Controls, cxControls, DB, uEditorRegistryUtils, schFacturasProveedorClient_Intf,
  uBizContactos, uIEditorFacturasProveedor, uIEditorFacturaProveedor,
  uDataModuleFacturasProveedor, uBizDetallesFacturaProveedor, uControllerDetallesBase,
  uDataModuleUsuarios, uDAInterfaces, uDataTableUtils, uDateUtils, uROTypes,
  uAlbaranesProveedorController, schAlbaranesProveedorClient_Intf, uDetallesAlbaranProveedorController,
  uBizDetallesAlbaranProveedor,
  uBizPedidosProveedor, uPedidosProveedorController, uBizDetallesPedidoProveedor,
  uRecibosProveedorController, uBizRecibosProveedor,
  uFacturasProveedorReportController, DateUtils, Forms, Dialogs,
  uFormasPagoController, uBizFormasPago, uSistemaFunc,
  uDialogElegirEMail, uEMailUtils, uStringsUtils,
  uIDialogListaFacturasProvEnvioEMail, uDataModuleRegistroCorreos;

procedure CopiarArticulosPedido(AOrigen: IBizDetallesPedidoProveedor;
  ADestino : IBizDetallesFacturaProveedor);
var
  i : integer;
  ADetallesController : IDetallesFacturaProveedorController;
begin
  if not Assigned(AOrigen) then
    raise Exception.Create ('Origen no asignado (CopiarArticulosPedido)');

  if not Assigned(ADestino) then
    raise Exception.Create ('Destino no asignado (CopiarArticulosPedido)');

  if not AOrigen.DataTable.Active then
    AOrigen.DataTable.Active := True;

  if not ADestino.DataTable.Active then
    ADestino.DataTable.Active := True;

  ADetallesController := TDetallesFacturaProveedorController.Create;
  try
    //OJO IMPORTANTE
    //Siempre que vayamos a trabajar con los detalles debemos hacer un beginupdate de los mismos y un endupdate para
    //obligarle siempre a recalcular los detalles una sola vez
    ADetallesController.BeginUpdate(ADestino);

    AOrigen.DataTable.First;
    for i := 0 to AOrigen.DataTable.RecordCount - 1 do
    begin
      ADetallesController.Add(ADestino, TIPO_DETALLE_CONCEPTO);
      ADestino.Edit;
      ADestino.REFERENCIA := AOrigen.REFERENCIA;
      if AOrigen.ID_ARTICULO > 0 then
         ADestino.ID_ARTICULO := AOrigen.ID_ARTICULO;
      ADestino.CONCEPTO := AOrigen.CONCEPTO;
      ADestino.CANTIDAD := AOrigen.CANTIDAD;
      ADestino.IMPORTE_UNIDAD := AOrigen.IMPORTE_UNIDAD;
      ADestino.IMPORTE_TOTAL := AOrigen.IMPORTE_TOTAL;
      ADestino.DESCUENTO := AOrigen.DESCUENTO;
      ADestino.IMPORTE_PORTE := AOrigen.IMPORTE_PORTE;
      ADestino.VISIBLE := AOrigen.VISIBLE;
      ADestino.REFERENCIA_PROVEEDOR := AOrigen.REFERENCIA_PROVEEDOR;
      ADestino.Post;
      AOrigen.Next;
    end;
  finally
    ADetallesController.EndUpdate(ADestino);
    ADetallesController := NIL;
  end;
end;

procedure CopiarArticulosAlbaran(AOrigen: IBizDetallesAlbaranProveedor;
  ADestino : IBizDetallesFacturaProveedor);
var
  i : integer;
  ADetallesController : IDetallesFacturaProveedorController;
begin
  if not Assigned(AOrigen) then
    raise Exception.Create ('Origen no asignado (CopiarArticulosAlbaran)');

  if not Assigned(ADestino) then
    raise Exception.Create ('Destino no asignado (CopiarArticulosAlbaran)');

  if not AOrigen.DataTable.Active then
    AOrigen.DataTable.Active := True;

  if not ADestino.DataTable.Active then
    ADestino.DataTable.Active := True;

  ADetallesController := TDetallesFacturaProveedorController.Create;
  try
    //OJO IMPORTANTE
    //Siempre que vayamos a trabajar con los detalles debemos hacer un beginupdate de los mismos y un endupdate para
    //obligarle siempre a recalcular los detalles una sola vez
    ADetallesController.BeginUpdate(ADestino);

    AOrigen.DataTable.First;
    for i := 0 to AOrigen.DataTable.RecordCount - 1 do
    begin
      ADetallesController.Add(ADestino, TIPO_DETALLE_CONCEPTO);
      ADestino.Edit;
      ADestino.REFERENCIA := AOrigen.REFERENCIA;
      if AOrigen.ID_ARTICULO > 0 then
         ADestino.ID_ARTICULO := AOrigen.ID_ARTICULO;
      ADestino.CONCEPTO := AOrigen.CONCEPTO;
      ADestino.CANTIDAD := AOrigen.CANTIDAD;
      ADestino.IMPORTE_UNIDAD := AOrigen.IMPORTE_UNIDAD;
      ADestino.IMPORTE_TOTAL := AOrigen.IMPORTE_TOTAL;
      ADestino.DESCUENTO := AOrigen.DESCUENTO;
      ADestino.IMPORTE_PORTE := AOrigen.IMPORTE_PORTE;
      ADestino.VISIBLE := AOrigen.VISIBLE;
      ADestino.REFERENCIA_PROVEEDOR := AOrigen.REFERENCIA_PROVEEDOR;
      ADestino.Post;
      AOrigen.Next;
    end;
  finally
    ADetallesController.EndUpdate(ADestino);
    ADetallesController := NIL;
  end;
end;

{ TFacturasProveedorController }

function TFacturasProveedorController.Anadir(AFactura: IBizFacturaProveedor) : Boolean;
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada (Anadir)');
  AFactura.Insert;
  Result := True;
end;

function TFacturasProveedorController.Anadir(AFacturas: IBizFacturaProveedor;
  AListaAlbaranes: IBizAlbaranProveedor): Boolean;
var
  AFacturaActual : IBizFacturaProveedor;
  AAlbaranesController : IAlbaranesProveedorController;
  I: Integer;
  bEnEdicion : Boolean;
begin
  Result := False;

  // ATENCIÓN!!! AFacturas tiene que estar vacio para no pisar facturas
  // ya generadas.
  if not Assigned(AFacturas) then
    raise Exception.Create ('Factura no asignada (Anadir)');

  if not Assigned(AListaAlbaranes) then
    raise Exception.Create ('Albaranes no asignados (Anadir)');

  if not AFacturas.DataTable.Active then
    AFacturas.DataTable.Active := True;

  if not AListaAlbaranes.DataTable.Active then
    AListaAlbaranes.DataTable.Active := True;

  ShowHourglassCursor;
  Application.ProcessMessages;

  AAlbaranesController := TAlbaranesProveedorController.Create;
  try
    // Ordenar por fecha de albaran
    AListaAlbaranes.DataTable.Sort([fld_AlbaranesProveedorFECHA_ALBARAN], [uDADataTable.sdAscending]);
    AListaAlbaranes.First;
    for I := 0 to AListaAlbaranes.DataTable.RecordCount - 1 do
    begin
      AListaAlbaranes._Proveedor := NIL;
      AFacturaActual := NIL;

      // Busco si hay alguna factura ya hecha de ese Proveedor
      AFacturas.DataTable.First;
      if AFacturas.DataTable.Locate(fld_FacturasProveedorID_Proveedor, AListaAlbaranes.ID_Proveedor, []) then
      begin
        AFacturaActual := AFacturas;
        RecuperarProveedor(AFacturaActual);
        AFacturaActual.Proveedor.DataTable.Active := True;
      end
      else begin
        // No hay factura de ese Proveedor. Creo una nueva
        Anadir(AFacturas);
        AAlbaranesController.RecuperarProveedor(AListaAlbaranes);
        AFacturas.Proveedor := AListaAlbaranes.Proveedor;

        //Siempre asignaremos por defecto la referencia de factura de proveedor que tenga el primer albaran del proveedor
        bEnEdicion := (AFacturas.DataTable.State in dsEditModes);
        if not bEnEdicion then
           AFacturas.Edit;
        AFacturas.REFERENCIA_PROVEEDOR := AListaAlbaranes.REF_FACTURA_PROV;
        AFacturas.Post;
        if bEnEdicion then
           AFacturas.Edit;

        //Si el albaran es de tipo devolución hacemos la factura de tipo abono
        if (AListaAlbaranes.TIPO = CTE_TIPO_ALBARAN_DEV) then
        begin
          bEnEdicion := (AFacturas.DataTable.State in dsEditModes);
          if not bEnEdicion then
             AFacturas.Edit;
          AFacturas.TIPO := CTE_TIPO_ABONO;
          AFacturas.Post;
          if bEnEdicion then
             AFacturas.Edit;
        end;

        AFacturaActual := AFacturas;
      end;

      // Ya tengo la factura. Le añado los conceptos del albarán
      AFacturaActual.Detalles.DataTable.Last;
      //Aqui no hace falta BeginUpdate y EndUpdate de los detalles, porque siempre se
      //añade una linea en blanco al final que hace que nos recalcule todo
      // Añado el título
      Self.DetallesController.Add(AFacturaActual.Detalles, TIPO_DETALLE_TITULO);
      with AFacturaActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Albarán ' + AListaAlbaranes.REFERENCIA + ' del ' + DateToStr(AListaAlbaranes.FECHA_ALBARAN);
        Post;
      end;
      // Añado el contenido del albarán
      CopiarArticulosAlbaran(AListaAlbaranes.Detalles, AFacturaActual.Detalles);

{En los albaranes a proveedor el porte es a nivel del artículo
      Self.DetallesController.Add(AFacturaActual.Detalles, TIPO_DETALLE_CONCEPTO);
      with AFacturaActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Porte del albarán';
        CANTIDAD := 1;
        IMPORTE_UNIDAD := AListaAlbaranes.IMPORTE_PORTE;
        Post;
      end;
}

      // Añado el resumen
      Self.DetallesController.Add(AFacturaActual.Detalles, TIPO_DETALLE_SUBTOTAL);
      with AFacturaActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Total del albarán ' + AListaAlbaranes.REFERENCIA;
        Post;
      end;

      // Añado una línea en blanco
      Self.DetallesController.Add(AFacturaActual.Detalles, TIPO_DETALLE_CONCEPTO);
      with AFacturaActual.Detalles do
      begin
        Edit;
        CONCEPTO := '';
        Post;
      end;

      // Guardo la factura que acabo de generar o editar
      AFacturaActual.CalcularImporteTotal;
      Self.Guardar(AFacturaActual);
      // Asocio la factura con el albarán
      AListaAlbaranes.Edit;
      AListaAlbaranes.ID_FACTURA := AFacturaActual.ID;
      AListaAlbaranes.Post;
      AAlbaranesController.Guardar(AListaAlbaranes);

      AListaAlbaranes.Next;
    end;
    Result := True;
  finally
    AAlbaranesController := NIL;
    HideHourglassCursor
  end;
end;

function TFacturasProveedorController.Anadir(AFactura: IBizFacturaProveedor;
  const IDPedido: Integer): Boolean;
var
  APedidosController : IPedidosProveedorController;
  APedido : IBizPedidoProveedor;
begin
  Result := False;
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada (Anadir)');

  if (IDPedido < 0) or (IDPedido = 0) then
    raise Exception.Create (Format('ID de pedido (%d) incorrecto (Anadir)', [IDPedido]));

  if not AFactura.DataTable.Active then
    AFactura.DataTable.Active := True;

  ShowHourglassCursor;
  Application.ProcessMessages;

  APedido := NIL;
  APedidosController := TPedidosProveedorController.Create;
  try
    APedido := APedidosController.Buscar(IDPedido);

    if not Assigned(APedido) then
      raise Exception.Create (Format('No se ha encontrado un pedido de Proveedor con ID %d (Anadir)', [IDPedido]));

    APedido.DataTable.Active := True;
    APedidosController.RecuperarProveedor(APedido);

    Self.Anadir(AFactura);
    AFactura.Proveedor := APedido.Proveedor;

    CopiarArticulosPedido(APedido.Detalles, AFactura.Detalles);

    // Guardo la factura que acabo de generar
    AFactura.CalcularImporteTotal;
    Self.Guardar(AFactura);

    Result := True;
  finally
    APedido := NIL;
    APedidosController := NIL;
    HideHourglassCursor;
    Application.ProcessMessages;
  end;
end;

function TFacturasProveedorController.AnadirAbono(AFactura: IBizFacturaProveedor): Boolean;
begin
  Result := Anadir(AFactura);
  AFactura.TIPO := CTE_TIPO_ABONO;
end;

procedure TFacturasProveedorController.AsignarID(AFactura: IBizFacturaProveedor; const IDNuevo: Integer);
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada');

  if not Assigned(AFactura.Detalles) then
    raise Exception.Create ('Detalles de factura no asignados');

  if not Assigned(FDetallesController) then
    raise Exception.Create ('Controller detalles no asignado');

  { Los detalles siempre hay que comprobarlos }
  FDetallesController.AsignarID(AFactura.Detalles, IDNuevo, AFactura.EsNuevo);

  if AFactura.EsNuevo then
  begin
    AFactura.Edit;
    AFactura.ID := IDNuevo;
    AFactura.Post;
  end;
end;

function TFacturasProveedorController.Buscar(const ID: Integer): IBizFacturaProveedor;
begin
  Result := (FDataModule as IDataModuleFacturasProveedor).GetItem(ID);
  FiltrarEmpresa(Result);  
end;

{
function TFacturasProveedorController.BuscarTodasPendientesComision(IdAgente:Integer; IdComision: Integer; IdFacturasAsociadas: String): IBizFacturaProveedor;
begin
  ShowHourglassCursor;
  try
    Result := BuscarTodos;
    with Result.DataTable.Where do
    begin
      if NotEmpty then
         AddOperator(opAND);
      //Todas las facturas de un agente determinado
      OpenBraket;
      AddText(fld_FacturasProveedorID_AGENTE + ' = ' + IntToStr(IdAgente));
      CloseBraket;

      //Todas aquellas que no esten asociadas a ninguna comisión o asociadas a la comisión,
      //pero no asociadas en el editor de la comision, esto es porque se puede agregar y quitar
      //facturas y todos los cambios estan el cache y por lo tanto al pedir las facturas a seleccionar
      //debemos tener en cuenta dichso cambios en cache
      AddOperator(opAND);
      OpenBraket;
        OpenBraket;
          //En el caso de ser facturas sin asociar
          OpenBraket;
          AddText(fld_FacturasProveedorID_COMISION_LIQUIDADA + ' IS NULL ');
          CloseBraket;
          //Quitamos aquellas que ya están asociadas
          if length(IdFacturasAsociadas) > 0 then
          begin
            AddOperator(opAND);
            OpenBraket;
            AddText(fld_FacturasProveedorID + ' not in (' + IdFacturasAsociadas + ')');
            CloseBraket;
          end;
        CloseBraket;

        AddOperator(opOR);

        OpenBraket;
          //En caso de ser facturas ya asociadas lo limitamos a la comision actual
          //ya que no debemos poder elegir facturas asociadas a otras comisiones
          OpenBraket;
          AddText(fld_FacturasProveedorID_COMISION_LIQUIDADA + ' = ' + IntToStr(IdComision));
          CloseBraket;
          //En el caso de que halla facturas asociadas
          if length(IdFacturasAsociadas) > 0 then
          begin
            AddOperator(opAND);
            OpenBraket;
            AddText(fld_FacturasProveedorID + ' not in (' + IdFacturasAsociadas + ')');
            CloseBraket;
          end;
        CloseBraket;

      CloseBraket;
    end;
  finally
    HideHourglassCursor;
  end;
//  showmessage(Result.DataTable.Where.Clause);
end;
}

function TFacturasProveedorController.BuscarTodos: IBizFacturaProveedor;
begin
  Result := FDataModule.GetItems;
  FiltrarEmpresa(Result);
end;

constructor TFacturasProveedorController.Create;
begin
  FDataModule := TDataModuleFacturasProveedor.Create(Nil);
  FProveedorController := TProveedoresController.Create;  
  FDetallesController := TDetallesFacturaProveedorController.Create;
  FDetallesController.addObservador(Self);
end;

function TFacturasProveedorController.CreateEditor(const AName: String;
  const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;

function TFacturasProveedorController.DarListaAnosFacturas: TStringList;
begin
  Result := FDataModule.GetAnosItems;
end;

procedure TFacturasProveedorController.DescartarCambios(AFactura: IBizFacturaProveedor);
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada');

  ShowHourglassCursor;
  try
    if (AFactura.State in dsEditModes) then
      AFactura.Cancel;

    AFactura.DataTable.CancelUpdates;
  finally
    HideHourglassCursor;
  end;
end;

destructor TFacturasProveedorController.Destroy;
begin
  FDataModule := Nil;
  FProveedorController := Nil;
  FDetallesController := Nil;
  inherited;
end;

function TFacturasProveedorController.Duplicar(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;
begin
  Result := Self._Vacio;
  ShowHourglassCursor;
  try
    DuplicarRegistros(AFactura.DataTable, Result.DataTable, mdrActual);
    DuplicarRegistros(AFactura.Detalles.DataTable, Result.Detalles.DataTable, mdrTodos);

    // Hay que dejar algunos campos como si fuera una factura nueva
    Result.Edit;
    with Result do
    begin
      ID_EMPRESA := dmUsuarios.IDEmpresaActual;
      USUARIO := dmUsuarios.LoginInfo.Usuario;
      REFERENCIA := ''; //Para que se asigne una nueva
      SITUACION := CTE_PENDIENTE; //Una factura nueva debe estar pendiente
      FECHA_FACTURA := DateOf(Now);
    end;

    Result.Post;
  finally
    HideHourglassCursor;
  end;
end;

function TFacturasProveedorController.ValidarFactura(AFactura: IBizFacturaProveedor): Boolean;
begin
  Result := False;

  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada');

  if (AFactura.DataTable.State in dsEditModes) then
    AFactura.DataTable.Post;

  //Tambien hacemos post de sus tablas hija
  if (AFactura.Detalles.DataTable.State in dsEditModes) then
      AFactura.Detalles.DataTable.Post;

  if (AFactura.ID_PROVEEDOR < 0) or (AFactura.ID_PROVEEDOR = 0) then
  // No comprobar el objeto Proveedor por que puede fallar la validación
  // cuando se generan facturas automáticamente.
{     (not Assigned(AFactura.Proveedor)) or
     (AFactura.Proveedor.IsEmpty) then}
    raise Exception.Create('Debe indicar el Proveedor de esta factura');

  if (EsFechaVacia(AFactura.FECHA_FACTURA)) then
    raise Exception.Create('Debe indicar la fecha de esta factura');

  if (AFactura.Detalles.DataTable.RecordCount = 0) then
    raise Exception.Create('La factura debe tener al menos un concepto en su contenido');

  { Esta validación puede saltar cuando se generan facturas automáticamente
    por albaranes o pedidos y el Proveedor no tiene Tipo de IVA puesto. }
{  if (AFactura.ID_TIPO_IVA = 0) then
    raise Exception.Create('Debe indicar un tipo de IVA para esta factura');}

  //En caso de ser un Abono no podra tener un importe total positivo  
  if (AFactura.TIPO = CTE_TIPO_ABONO) then
    if (AFactura.IMPORTE_TOTAL >= 0) then
      raise Exception.Create('Un abono nunca no puede tener un importe positivo');

  { Asegurarse de valores en campos "automáticos" tanto
    en MODIFICACIÓN como en INSERCIÓN. }
  AFactura.Edit;
  try
    AFactura.USUARIO := dmUsuarios.LoginInfo.Usuario;

    if Assigned(AFactura.Proveedor)
    and (AFactura.ID_Proveedor <> AFactura.Proveedor.ID) then
      AFactura.ID_Proveedor := AFactura.Proveedor.ID;

    Result := True;
  finally
    AFactura.Post;
  end;
end;

procedure TFacturasProveedorController.Ver(AFactura: IBizFacturaProveedor);
var
  AEditor : IEditorFacturaProveedor;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    RecuperarProveedor(AFactura);
    CreateEditor('EditorFacturaProveedor', IEditorFacturaProveedor, AEditor);

    if Assigned(AEditor) then
      with AEditor do
      begin
        Controller := Self; //OJO ORDEN MUY IMPORTANTE
        Factura := AFactura;

        //MODO CONSULTAR
        if not EsModificable(AFactura) then
        begin
           SetDataTableReadOnly(AFactura.DataTable, True);
           ReadOnly := True;
        end;

        ShowModal;

        //MODO CONSULTAR (Se deja la tabla como estaba)
        if ReadOnly then
           SetDataTableReadOnly(AFactura.DataTable, False);

        AEditor.Release;
      end;
  finally
    AEditor := NIL;
    HideHourglassCursor;
  end;
end;

procedure TFacturasProveedorController.VerTodos(AFacturas: IBizFacturaProveedor);
var
  AEditor : IEditorFacturasProveedor;
begin
  AEditor := NIL;
  ShowHourglassCursor;
  try
    CreateEditor('EditorFacturasProveedor', IEditorFacturasProveedor, AEditor);
    with AEditor do
    begin
      Controller := Self; //OJO ORDEN MUY IMPORTANTE
      Facturas := AFacturas;
      MultiSelect := True;
      ShowEmbedded;
    end;
  finally
    AEditor := Nil;
    HideHourglassCursor;
  end;
end;

procedure TFacturasProveedorController._AnadirMarcaEnvioCorreo(AFactura: IBizFacturaProveedor);
var
  ASoloLectura : Boolean;
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada (_AnadirMarcaEnvioCorreo)');

  if AFactura.DataTable.Active then
    AFactura.DataTable.Active := True;

  if AnadirMarcaEnvioCorreo(nme_FacturasProveedor, AFactura.ID) then
  begin
    DesconectarTabla(AFactura.DataTable);
    try
      ASoloLectura := AFactura.DataTable.ReadOnly;
      if ASoloLectura then
        SetDataTableReadOnly(AFactura.DataTable, False);
      try
        AFactura.Edit;
        AFactura.NUM_CORREOS := AFactura.NUM_CORREOS + 1;
        AFactura.Post;
      finally
        if ASoloLectura then
          SetDataTableReadOnly(AFactura.DataTable, True);
      end;
    finally
      ConectarTabla(AFactura.DataTable);
    end;
  end;
end;

function TFacturasProveedorController._Vacio: IBizFacturaProveedor;
begin
  Result := Buscar(ID_NULO);
end;

function TFacturasProveedorController.Eliminar(const ID: Integer): Boolean;
var
  AFactura : IBizFacturaProveedor;
begin
  AFactura := Buscar(ID);

  if not Assigned(AFactura) then
    raise Exception.Create(Format('No se ha encontrado la factura con ID = %d', [ID]));

  Result := Eliminar(AFactura);
  AFactura := NIL;
end;

function TFacturasProveedorController.ElegirFacturas(AFacturas: IBizFacturaProveedor; AMensaje: String;
  AMultiSelect: Boolean): IBizFacturaProveedor;
{var
  AEditor : IEditorElegirFacturasProveedor;}
begin
  Result := NIL;
{  CreateEditor('EditorElegirFacturasProveedor', IEditorElegirFacturasProveedor, AEditor);
  try
    with AEditor do
    begin
      Controller := Self;
      Facturas := AFacturas;
      MultiSelect := AMultiSelect;
      Mensaje := AMensaje;
      if IsPositiveResult(ShowModal) then
        Result := FacturasProveedoreSeleccionados;
	  Release;
    end;
  finally
    AEditor := NIL;
  end;
}  
end;

function TFacturasProveedorController.Eliminar(AFactura: IBizFacturaProveedor; AllItems: Boolean = false): Boolean;
//En el caso de eliminar almenos un elemento del conjunto se devuelve true
var
  bEliminado: Boolean;

begin
  bEliminado := False;

  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada');

  ShowHourglassCursor;
  try
    if not AFactura.DataTable.Active then
      AFactura.DataTable.Active := True;

    if (AFactura.State in dsEditModes) then
      AFactura.Cancel;

    //Siempre eliminaremos el seleccionado
    if EsEliminable(AFactura) then
    begin
      AFactura.Delete;
      bEliminado := True;
    end;

    //En el caso de querer eliminar todos los items del objeto AAlbaran
    if AllItems then
    begin
       with AFactura.DataTable do
       begin
         First;
         while not EOF do
         begin
           if EsEliminable(AFactura) then
           begin
              AFactura.Delete;
              bEliminado := True
           end
           else Next;
         end;
       end;
    end;

    if bEliminado then
    begin
       AFactura.DataTable.ApplyUpdates;
       Result := True;
    end
    else
       Result := False;

  finally
    HideHourglassCursor;
  end;
end;

function TFacturasProveedorController.EnviarEmailFacturas(
  AFacturas: IBizFacturaProveedor): Boolean;
var
  ADialog : IDialogListaFacturasProvEnvioEMail;
  ARespuesta : Integer;
begin
  ADialog := NIL;

  if not Assigned(AFacturas) then
    raise Exception.Create ('Facturas no asignadas (EnviarFacturasPorEMail)');

  if AFacturas.DataTable.Active then
    AFacturas.DataTable.Active := True;

  ShowHourglassCursor;
  try
    CreateEditor('DialogListaFacturasProvEnvioEMail', IDialogListaFacturasProvEnvioEMail, ADialog);

    if Assigned(ADialog) then
    begin
      try
        ADialog.Facturas := AFacturas;
        ARespuesta := ADialog.ShowModal;
        Result := (ARespuesta = mrOK)
      finally
        ADialog.Release;
      end;
    end;
  finally
    ADialog := NIL;
    HideHourglassCursor;
  end;
end;

function TFacturasProveedorController.EnviarFacturaPorEMail(
  AFactura: IBizFacturaProveedor; const AEnviarDirectamente: Boolean;
  const ADireccionEMail, AAsuntoEMail, ATextoEMail: String): Boolean;
var
  AReportController : IFacturasProveedorReportController;
  AFicheroTMP : TFileName;
  AEMail : String;
  AAsunto : String;
  AListaEmail : TStringList;
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada (EnviarFacturaPorEMail)');

  if AFactura.DataTable.Active then
    AFactura.DataTable.Active := True;

  RecuperarProveedor(AFactura);
  AFactura.Proveedor.DataTable.Active := True;

  AFicheroTMP := DarFicheroPDFTemporal(EscapeIllegalChars(AFactura.REFERENCIA));

  if not EsCadenaVacia(ADireccionEMail) then
    AEMail := ADireccionEMail
  else begin
    AListaEmail := TStringList.Create;
    try
      if not EsCadenaVacia(AFactura.Proveedor.EMAIL_ADMINISTRACION) then
        AListaEmail.Add(AFactura.Proveedor.EMAIL_ADMINISTRACION);

      if not ElegirEMail(AListaEmail, AEMail) then
        Exit;
    finally
      FreeANDNIL(AListaEmail);
    end;
  end;

  if not EsCadenaVacia(AAsuntoEMail) then
    AAsunto := AAsuntoEMail
  else
    AAsunto := 'Factura ' + AFactura.REFERENCIA;

  ShowHourglassCursor;
  Application.ProcessMessages;

  AReportController := TFacturasProveedorReportController.Create;
  try
    AReportController.ExportToPDF(AFactura.ID, AFicheroTMP);
    Result := EnviarEMailMAPI(AAsunto, ATextoEMail, AFicheroTMP, '', '', AFactura.Proveedor.NOMBRE, AEMail, AEnviarDirectamente);
    if Result then
       _AnadirMarcaEnvioCorreo(AFactura);
  finally
    SysUtils.DeleteFile(AFicheroTMP);
    AReportController := NIL;
    HideHourglassCursor;
    Application.ProcessMessages;
  end;
end;

function TFacturasProveedorController.EsEliminable(AFactura: IBizFacturaProveedor): Boolean;
begin
  Result := EsModificable(AFactura);
end;

function TFacturasProveedorController.EsModificable(AFactura: IBizFacturaProveedor): Boolean;
begin
  if not Assigned(AFactura) then
     raise Exception.Create ('Factura no asignado: EsModificable');

  Result := (AFactura.SITUACION = CTE_PENDIENTE);
end;

procedure TFacturasProveedorController.RecalcularImportes(
  FFactura: IBizFacturaProveedor);
var
  bEnEdicion : Boolean;
begin
  if not Assigned(FFactura) then
    raise Exception.Create ('Factura no asignada (RecalcularImportes)');

  if FFactura.DataTable.Active then
    FFactura.DataTable.Active := True;

  bEnEdicion := (FFactura.DataTable.State in dsEditModes);
  if not bEnEdicion then
    FFactura.Edit;

  ShowHourglassCursor;
  FFactura.Edit;
  try
    FFactura.IMPORTE_NETO := FDetallesController.DarTotalImporteTotal(FFactura.Detalles);
    FFactura.IMPORTE_PORTE := FDetallesController.DarTotalPorteTotal(FFactura.Detalles);
    if not bEnEdicion then
      FFactura.Post;
  finally
    HideHourglassCursor;
  end;
end;

procedure TFacturasProveedorController.RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable);
var
  AFactura : IBizFacturaProveedor;
  ADetalles : IBizDetallesFacturaProveedor;
begin
  inherited;

  if Supports(ADataTable, IBizDetallesFacturaProveedor, ADetalles) and
     Supports(ADetalles.DataTable.MasterSource.DataTable, IBizFacturaProveedor, AFactura) then
  begin
    RecalcularImportes(AFactura);
  end;
end;

procedure TFacturasProveedorController.RecuperarProveedor(AFactura: IBizFacturaProveedor);
begin
  AFactura._Proveedor := (FProveedorController.Buscar(AFactura.ID_Proveedor)  as IBizProveedor);
end;

function TFacturasProveedorController.Existe(const ID: Integer): Boolean;
var
  AFactura : IBizFacturaProveedor;
begin
  try
    AFactura := Buscar(ID);
    Result := Assigned(AFactura) and (AFactura.ID = ID);
  finally
    AFactura := NIL;
  end;
end;

function TFacturasProveedorController.ExtraerSeleccionados(AFacturasProveedor: IBizFacturaProveedor; Const ViewGrid: IViewGridBase = Nil): IBizFacturaProveedor;
var
  ASeleccionados : IBizFacturaProveedor;
begin
  if Assigned(ViewGrid) then
  begin
    //Guardamos la situación porque el CopyDataTable nos cambia la posicion
    ViewGrid.SaveGridStatus;
    ViewGrid.DesactivarGrid;
  end;

  ASeleccionados := (Self.Buscar(ID_NULO) as IBizFacturaProveedor);
  CopyDataTable(AFacturasProveedor.DataTable, ASeleccionados.DataTable, True);
  Result := ASeleccionados;

  if Assigned(ViewGrid) then
  begin
    ViewGrid.ActivarGrid;
    ViewGrid.RestoreGridStatus;
  end;
end;

procedure TFacturasProveedorController.FiltrarAno(AFactura: IBizFacturaProveedor; AWhereDataTable: String; const Ano: String);
var
  FechaIni: String;
  FechaFin: String;

begin
  AFactura.DataTable.Where.Clear;
  AFactura.DataTable.Where.AddText(AWhereDataTable);

  if (Ano <> 'Todos') then
  begin
    // Filtrar las facturas actuales por empresa
    FechaIni := '01.01.' + Ano;
    FechaFin := '31.12.' + Ano;
    with AFactura.DataTable.Where do
    begin
      if NotEmpty then
         AddOperator(opAND);
      AddCondition(fld_FacturasProveedorFECHA_FACTURA, cMajorOrEqual, FechaIni);
      AddOperator(opAND);
      AddCondition(fld_FacturasProveedorFECHA_FACTURA, cLessOrEqual, FechaFin);
    end;
  end;
end;

procedure TFacturasProveedorController.FiltrarEmpresa(AFactura: IBizFacturaProveedor);
begin
  if AFactura.DataTable.Active then
    AFactura.DataTable.Active := False;

  // Filtrar las facturas actuales por empresa
  with AFactura.DataTable.Where do
  begin
    if NotEmpty then
      AddOperator(opAND);
    AddCondition(fld_FacturasProveedorID_EMPRESA, cEqual, dmUsuarios.IDEmpresaActual);
  end;
end;

procedure TFacturasProveedorController.SetProveedorController(const Value: IProveedoresController);
begin
  FProveedorController := Value;
end;

procedure TFacturasProveedorController.SetDetallesController(const Value: IDetallesFacturaProveedorController);
begin
  FDetallesController := Value;
end;

function TFacturasProveedorController.Guardar(AFactura: IBizFacturaProveedor): Boolean;
var
  IDNuevo : Integer;
begin
  Result := False;

  if not Assigned(AFactura) then
    raise Exception.Create ('Factura no asignada');

  if not Assigned(FDetallesController) then
    raise Exception.Create ('Controller detalles no asignado');

  if ValidarFactura(AFactura) then
  begin
    ShowHourglassCursor;

    // Asegurarnos de que todos los importes están bien.
    RecalcularImportes(AFactura);

    try
      if (AFactura.EsNuevo) then
        IDNuevo := FDataModule.GetNextID(AFactura.DataTable.LogicalName)
      else
        IDNuevo := AFactura.ID;

      AsignarID(AFactura, IDNuevo);

      AFactura.DataTable.ApplyUpdates;

      //Se generan los recibos automáticamente a partir de la forma de pago
      GenerarRecibos(AFactura);

      Result := True;
    finally
      HideHourglassCursor;
    end;
  end;
end;

function TFacturasProveedorController.Nuevo: IBizFacturaProveedor;
var
  AFactura : IBizFacturaProveedor;
begin
  AFactura := FDataModule.NewItem;
  FiltrarEmpresa(AFactura);
  AFactura.DataTable.Active := True;
  AFactura.Insert;
  Result := AFactura;
end;

procedure TFacturasProveedorController.Preview(AFactura: IBizFacturaProveedor; AllItems: Boolean = false);
var
  AReportController : IFacturasProveedorReportController;
  ID_Facturas: TStringList;

begin
  AReportController := TFacturasProveedorReportController.Create;
  try
   ID_Facturas := TStringList.Create;

   //Si deseamos previsualizar todos los items del objeto albaran
   if AllItems then
   begin
     with AFactura.DataTable do
     begin
       First;
       while not EOF do
       begin
         ID_Facturas.Add(IntToStr(AFactura.ID));
         Next;
       end;
     end;
   end
   //Solo previsualizamos el item seleccionado
   else
     ID_Facturas.Add(IntToStr(AFactura.ID));

    AReportController.Preview(ID_Facturas.CommaText);

  finally
    AReportController := NIL;
    ID_Facturas.Free;
  end;
end;

function TFacturasProveedorController.Print(AFactura: IBizFacturaProveedor; AllItems: Boolean = false): Boolean;
var
  AReportController : IFacturasProveedorReportController;
  ID_Facturas: TStringList;

begin
  Result := False;
  AReportController := TFacturasProveedorReportController.Create;
  try
   ID_Facturas := TStringList.Create;

   //Si deseamos previsualizar todos los items del objeto albaran
   if AllItems then
   begin
     with AFactura.DataTable do
     begin
       First;
       while not EOF do
       begin
         ID_Facturas.Add(IntToStr(AFactura.ID));
         Next;
       end;
     end;
   end
   //Solo previsualizamos el item seleccionado
   else
     ID_Facturas.Add(IntToStr(AFactura.ID));

    Result := AReportController.Print(ID_Facturas.CommaText);

  finally
    AReportController := NIL;
    ID_Facturas.Free;
  end;
end;

function TFacturasProveedorController.GenerarAbono(AFactura: IBizFacturaProveedor): IBizFacturaProveedor;
begin
  ShowHourglassCursor;
  try
    Result := Duplicar(AFactura);
    //Añade un concepto con los datos de la factura asociada al abono
    FDetallesController.AnadirDetalleFacturaAsociadaAbono(Result.Detalles, AFactura.REFERENCIA, DateToStr(AFactura.FECHA_FACTURA));
    //Convierte todos los articulos de la factura a negativos por se un abono
    FDetallesController.CambiarSignoDetalles(Result.Detalles);

    // Hay que dejar algunos campos como si fuera una factura nueva
    Result.Edit;
    Result.TIPO := CTE_TIPO_ABONO;
    Result.Post;

  finally
    HideHourglassCursor;
  end;
end;

function TFacturasProveedorController.GenerarEmailFactura(
  AFactura: IBizFacturaProveedor): Boolean;
begin
  if not Assigned(AFactura) then
    raise Exception.Create ('Facturas no asignadas (GenerarEmailFactura)');

  if AFactura.DataTable.Active then
    AFactura.DataTable.Active := True;

  ShowHourglassCursor;
  try
    RecuperarProveedor(AFactura);
    EnviarFacturaPorEMail(AFactura, False, AFactura.Proveedor.EMAIL_ADMINISTRACION);
  finally
    HideHourglassCursor;
  end;
end;

procedure TFacturasProveedorController.GenerarRecibos(AFactura: IBizFacturaProveedor);
var
  AFormasPagoController : IFormasPagoController;
  AFormaPago: IBizFormaPago;
  ARecibosProveedorController: IRecibosProveedorController;
  ARecibos: IBizRecibosProveedor;
  AFechaVencimiento: TDateTime;
  i: Integer;
  ADiaVencimiento: Integer;
  ADiasMas: Integer;
  BSemaforo: Boolean;

begin

  if not Assigned(AFactura) then
     Exit;

  AFormasPagoController := TFormasPagoController.Create;
  AFormaPago := AFormasPagoController.Buscar(AFactura.ID_FORMA_PAGO);
  AFormaPago.DataTable.Active := True;
  if AFormaPago.DataTable.RecordCount <> 1 then
     Exit; //No hay forma de pago en la factura y por lo tanto no se generan recibos
     //raise Exception.Create('No existe la forma de pago de la factura');

  ARecibosProveedorController := TRecibosProveedorController.Create;
  //Eliminamos todos los recibos que tuviera la factura porque sabemos que todos
  //estarán pendientes (solo permitiremos modificar y eliminar facturas pendientes,
  //parcialmente pagadas o pagadas no
  ARecibos := ARecibosProveedorController.BuscarRecibosFactura(AFactura.ID);
  ARecibosProveedorController.EliminarTodo(ARecibos);

  //Vamos a generar todos los recibos necesarios para la factura
  With AFormaPago.Plazos.DataTable do
  begin
    i := 1;
    First;
    while not eof do
    begin
      ARecibos := ARecibosProveedorController.Nuevo;
      ARecibos.Edit;
      ARecibos.ID_FACTURA := AFactura.ID;
      ARecibos.FECHA_EMISION := AFactura.FECHA_FACTURA;      
      ARecibos.REFERENCIA := AFactura.REFERENCIA + ' - ' + IntToStr(i);

      AFechaVencimiento := AFactura.FECHA_FACTURA + AFormaPago.Plazos.NUM_DIAS;
      ADiasMas := 0;
      BSemaforo := False;
      if (AFactura.Proveedor.VENCIMIENTO_FACTURAS_1 <> 0)
      or (AFactura.Proveedor.VENCIMIENTO_FACTURAS_2 <> 0)
      or (AFactura.Proveedor.VENCIMIENTO_FACTURAS_3 <> 0) then
      begin
        ADiaVencimiento := DayOf(AFechaVencimiento);
        while (ADiaVencimiento <> AFactura.Proveedor.VENCIMIENTO_FACTURAS_1)
        and (ADiaVencimiento <> AFactura.Proveedor.VENCIMIENTO_FACTURAS_2)
        and (ADiaVencimiento <> AFactura.Proveedor.VENCIMIENTO_FACTURAS_3) do
        begin
          if ADiaVencimiento = DaysInMonth(AFechaVencimiento) then
          begin
            ADiaVencimiento := 1;

            //Controlamos con una variable semaforo que no nos quedemos en un bucle infinito
            //intentando encontrar el dia de pago establecido para el cliente (es el caso de tener
            //asignado el dia de pago 30 y llegar febrero en el que no se encuentra dicho dia, o
            //tener como dia de pago los días 31 y en el caso de meses de 30 dias no encontrarlo.
            if BSemaforo then
            begin
              ADiasMas := 0;
              Break
            end
            else
              BSemaforo := True;
          end
          else
            Inc(ADiaVencimiento);
          Inc(ADiasMas);
        end;
      end;
      AFechaVencimiento := IncDay(AFechaVencimiento, ADiasMas);
      ARecibos.FECHA_VENCIMIENTO := AFechaVencimiento;

      ARecibos.IMPORTE := AFactura.IMPORTE_TOTAL * (AFormaPago.Plazos.PORCENTAJE / 100);
      ARecibosProveedorController.Guardar(ARecibos);
      Inc(i);
      Next;
    end;
  end;

  //Liberamos
  AFormasPagoController := Nil;
  AFormaPago := Nil;
  ARecibosProveedorController := Nil;
  ARecibos := Nil;
end;

function TFacturasProveedorController.GetProveedorController: IProveedoresController;
begin
  Result := FProveedorController;
end;

function TFacturasProveedorController.GetDetallesController: IDetallesFacturaProveedorController;
begin
  Result := FDetallesController;
end;

end.