unit uEditorFacturasProveedor;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, DB, uDADataTable, JvAppStorage,
  JvAppRegistryStorage, JvComponent, JvFormPlacement, ImgList,
  PngImageList, StdActns, ActnList, ComCtrls, TB2ExtItems, TBXExtItems,
  TBX, TB2Item, TB2Dock, TB2Toolbar, ExtCtrls, JvExControls,
  JvNavigationPane, uViewGrid, pngimage, JvComponentBase,
  uEditorGridBase, uBizFacturasProveedor, uIEditorFacturasProveedor,
  uFacturasProveedorController, uCustomView, uViewBase, uViewBarraSeleccion,
  uViewGridBase, JvExComCtrls, JvStatusBar, JSDialog,
  uViewFacturasProveedor;

type

  TfEditorFacturasProveedor = class(TfEditorGridBase, IEditorFacturasProveedor)
    Cambiarlasituacin1: TMenuItem;
    N4: TMenuItem;
    JsNuevaFacturaDialog: TJSDialog;
    JsListaFacturasGeneradas: TJSDialog;
    frViewFacturasProveedor1: TfrViewFacturasProveedor;
    actNuevaFactura: TAction;
    actNuevoAbono: TAction;
    JsNuevoAbonoDialog: TJSDialog;
    TBXSubmenuItem2: TTBXSubmenuItem;
    TBXItem38: TTBXItem;
    TBXItem39: TTBXItem;
    JsPrevisualizarDialog: TJSDialog;
    JsImprimirDialog: TJSDialog;
    JsListaFacturasNoEliminadas: TJSDialog;
    actEnviarEMail: TAction;
    TBXItem40: TTBXItem;
    procedure FormShow(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
    procedure actNuevaFacturaExecute(Sender: TObject);
    procedure actNuevoAbonoExecute(Sender: TObject);
    procedure actEnviarEMailExecute(Sender: TObject);
    procedure actEnviarEMailUpdate(Sender: TObject);
    procedure OnListaAnosChange(Sender: TObject; const Text: string);

  private
    FFacturas: IBizFacturaProveedor;
    FController : IFacturasProveedorController;

  protected
    function GetFacturas: IBizFacturaProveedor;
    procedure SetFacturas(const Value: IBizFacturaProveedor);

    function GetController : IFacturasProveedorController; virtual;
    procedure SetController (const Value : IFacturasProveedorController); virtual;

    procedure NuevoInterno; override;
    procedure EliminarInterno; override;
    procedure ModificarInterno; override;
    procedure DuplicarInterno; override;
    procedure ImprimirInterno; override;
    procedure PrevisualizarInterno; override;
    procedure RefrescarInterno; override;

  public
    procedure PonerTitulos(const ATitulo: string = ''); override;
    property Facturas: IBizFacturaProveedor read GetFacturas write SetFacturas;
    property Controller : IFacturasProveedorController read GetController write SetController;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;


implementation

uses
  cxControls, uDataModuleFacturasProveedor, uDataModuleUsuarios,
  uGridUtils, uDBSelectionListUtils,
  uAlbaranesProveedorController, uBizAlbaranesProveedor,
  uEditorBase, uGenerarFacturasProvAlbProvUtils;

{$R *.dfm}

{
*************************** TfEditorFacturasProveedor ***************************
}
procedure TfEditorFacturasProveedor.actEliminarUpdate(Sender: TObject);
begin
  inherited;
  if (Sender as TAction).Enabled then
     (Sender as TAction).Enabled := (FFacturas.SITUACION = CTE_PENDIENTE);
end;

procedure TfEditorFacturasProveedor.actEnviarEMailExecute(Sender: TObject);
var
  AFacturas : IBizFacturaProveedor;
begin
  inherited;

  if ViewGrid.NumSeleccionados = 1 then
    FController.GenerarEmailFactura(Facturas)
  else begin
    ShowHourglassCursor;
    try
      SeleccionarFilasDesdeGrid(ViewGrid._FocusedView, (Facturas as ISeleccionable).SelectedRecords);
      AFacturas := (Controller as IFacturasProveedorController).ExtraerSeleccionados(Facturas, ViewGrid) as IBizFacturaProveedor;

      if Assigned(AFacturas) then
         if FController.EnviarEmailFacturas(AFacturas) then
            RefrescarInterno;
    finally
      AFacturas := NIL;
      HideHourglassCursor;
    end;
  end;
end;

procedure TfEditorFacturasProveedor.actEnviarEMailUpdate(Sender: TObject);
begin
  inherited;
  if HayDatos and Assigned(ViewGrid) then
    (Sender as TAction).Enabled := ViewGrid.esSeleccionCeldaDatos
      and (ViewGrid.NumSeleccionados > 0)
  else
    (Sender as TAction).Enabled := False;
end;

procedure TfEditorFacturasProveedor.actNuevaFacturaExecute(Sender: TObject);
begin
  actNuevo.Execute;
end;

procedure TfEditorFacturasProveedor.actNuevoAbonoExecute(Sender: TObject);
var
  Respuesta : Integer;
  Opcion : Integer;
//  FPedidosClienteController : IPedidosClienteController;
//  APedido : IBizPedidoCliente;
//  FAlbaranesClienteController : IAlbaranesClienteController;
//  AAlbaranes : IBizAlbaranCliente;
//  AFacturasNuevas : IBizFacturaCliente;
///  i : integer;
begin
  inherited;
  //ABONOS
  if (Facturas.TIPO = CTE_TIPO_FACTURA) then
  begin
      Respuesta := JsNuevoAbonoDialog.Execute;
      //Nos salimos sin hace nada
      if Respuesta = IDCANCEL then
         Exit;
      Opcion := JsNuevoAbonoDialog.CustomButtonResult;
  end
  else
      Opcion := 100;

    case Opcion of
      200   : begin   // Utilizar factura seleccionada
                  FController.Ver(FController.GenerarAbono(Facturas));
                  actRefrescar.Execute;
                  ViewGrid._FocusedView.DataController.GotoFirst;
      end;
      100    : begin   // Abono nuevo vacio
                  if FController.AnadirAbono(Facturas) then
                     FController.Ver(Facturas);
                end;
    end;
end;

constructor TfEditorFacturasProveedor.Create(AOwner: TComponent);
begin
  inherited;
  ViewGrid := frViewFacturasProveedor1; //  CreateView(TfrViewFacturasProveedor) as IViewFacturasProveedor;
end;

destructor TfEditorFacturasProveedor.Destroy;
begin
  FFacturas := NIL;
  inherited;
end;

procedure TfEditorFacturasProveedor.DuplicarInterno;
var
  AFactura : IBizFacturaProveedor;
begin
  inherited;
  AFactura := FController.Duplicar(FFacturas);
  try
    FController.Ver(AFactura);
  finally
    actRefrescar.Execute;
  end;
end;

procedure TfEditorFacturasProveedor.EliminarInterno;
var
  ACadena : String;
  AFacturas: IBizFacturaProveedor;
  AllItems: Boolean;
begin
  AFacturas := Nil;
  AllItems := False;

  if MultiSelect and Assigned(ViewGrid) then
     AllItems :=  (ViewGrid.NumSeleccionados > 1);

  if AllItems then
  begin
    if (Application.MessageBox('¿Desea borrar las facturas/abonos de cliente seleccionados?', 'Atención', MB_YESNO) = IDYES) then
    begin
      SeleccionarFilasDesdeGrid(ViewGrid._FocusedView, (Facturas as ISeleccionable).SelectedRecords);
      AFacturas := (Controller as IFacturasProveedorController).ExtraerSeleccionados(Facturas, ViewGrid) as IBizFacturaProveedor;
    end
  end
  else begin
     if Facturas.TIPO = CTE_TIPO_FACTURA then
        ACadena := '¿Desea borrar esta factura de proveedor?'
     else
        ACadena := '¿Desea borrar este abono a proveedor?';

     if (Application.MessageBox(PChar(ACadena), 'Atención', MB_YESNO) = IDYES) then
        AFacturas := Facturas;
  end;

  if Assigned(AFacturas) then
  begin
    FController.Eliminar(AFacturas, AllItems);
    if AllItems then
    begin
      if (AFacturas.DataTable.RecordCount > 0) then
      begin
        with  AFacturas.DataTable do
        begin
          First;
          while not EOF do
          begin
            JsListaFacturasNoEliminadas.Content.Add('Ref. factura: ' + AFacturas.REFERENCIA + '  ' + AFacturas.NOMBRE);
            Next;
          end;
        end;
        JsListaFacturasNoEliminadas.Execute;
      end;
      actRefrescar.Execute;
    end;
  end;

  ViewGrid.GotoFirst;
end;

procedure TfEditorFacturasProveedor.FormShow(Sender: TObject);
begin
  cbxListaAnos.OnChange := OnListaAnosChange; //OJO SIEMPRE ANTES DEL INHERITED

  inherited;

  if not Assigned(ViewGrid) then
    raise Exception.Create('No hay ninguna vista asignada');

  if not Assigned(Facturas) then
    raise Exception.Create('No hay ninguna facturas asignada');

  Facturas.DataTable.Active := True;
  ViewGrid.GotoFirst;  
end;

function TfEditorFacturasProveedor.GetController: IFacturasProveedorController;
begin
  Result := FController;
end;

function TfEditorFacturasProveedor.GetFacturas: IBizFacturaProveedor;
begin
  Result := FFacturas;
end;

procedure TfEditorFacturasProveedor.ImprimirInterno;
var
  Respuesta : Integer;
  AFacturas: IBizFacturaProveedor;
  AllItems: Boolean;
begin
  AFacturas := Nil;
  AllItems := False;

  if MultiSelect and Assigned(ViewGrid) then
     AllItems :=  (ViewGrid.NumSeleccionados > 1);

  //Si esta agrupado solo podré imprimir la lista de elementos visibles
  if not ViewGrid.esSeleccionCeldaDatos then
     inherited
  else
  begin
    Respuesta := JsImprimirDialog.Execute;
    if Respuesta <> IDCANCEL then
    begin
      case JsImprimirDialog.CustomButtonResult of
        200   : begin   // Lista de elementos visibles
                  inherited;
                end;
        100   : begin   // Elemento Seleccionado
                  if AllItems then
                  begin
                    SeleccionarFilasDesdeGrid(ViewGrid._FocusedView, (Facturas as ISeleccionable).SelectedRecords);
                    AFacturas := (Controller as IFacturasProveedorController).ExtraerSeleccionados(Facturas, ViewGrid) as IBizFacturaProveedor;
                  end
                  else
                    AFacturas := Facturas;

                  if Assigned(AFacturas) then
                     if FController.Print(AFacturas, AllItems) then
                        RefrescarInterno;
                end;
      end;
    end;
  end;
end;

procedure TfEditorFacturasProveedor.ModificarInterno;
begin
  inherited;
  FController.Ver(Facturas);
end;

procedure TfEditorFacturasProveedor.NuevoInterno;
var
  Respuesta : Integer;
//  FPedidosProveedorController : IPedidosProveedorController;
//  APedido : IBizPedidoProveedor;
  //FAlbaranesProveedorController : IAlbaranesProveedorController;
  //AAlbaranes : IBizAlbaranProveedor;
  //AFacturasNuevas : IBizFacturaProveedor;
  //i : integer;
begin
  inherited;

  Respuesta := JsNuevaFacturaDialog.Execute;

  if Respuesta <> IDCANCEL then
  begin
    case JsNuevaFacturaDialog.CustomButtonResult of
      300   : begin   // Utilizar un pedido
{                  FPedidosProveedorController := TPedidosProveedorController.Create;
                  try
                    APedido := FPedidosProveedorController.ElegirPedidos(FPedidosProveedorController.BuscarPendientes,
                        'Elija el pedido de proveedor que desea utilizar para dar de alta la factura.'
                        + #10#13 + 'Tenga en cuenta que sólo se podrán utilizar pedidos que no tengan ningún albarán ya asociado.', False);
                    if Assigned(APedido) then
                    begin
                      if FController.Anadir(Facturas, APedido) then
                        FController.Ver(Facturas);
                    end;
                  finally
                    FPedidosClienteController := NIL;
                  end;}
                end;
      200   : begin   // Utilizar albaranes
                GenerarFacturaProv;
                actRefrescar.Execute;
      end;
      100    : begin   // Factura nuevo vacio
                  if FController.Anadir(Facturas) then
                    FController.Ver(Facturas);
                end;
    end;
  end;
end;

procedure TfEditorFacturasProveedor.OnListaAnosChange(Sender: TObject; const Text: string);
begin
  Controller.FiltrarAno(Facturas, WhereDataTable, Text);
  if Facturas.DataTable.Active then
     RefrescarInterno;
end;

procedure TfEditorFacturasProveedor.PonerTitulos(const ATitulo: string);
var
  FTitulo : String;
begin
  FTitulo := 'Lista de facturas de proveedor - ' + dmUsuarios.EmpresaActual.NOMBRE;
  inherited PonerTitulos(FTitulo);
end;

procedure TfEditorFacturasProveedor.PrevisualizarInterno;
var
  Respuesta : Integer;
  AFacturas: IBizFacturaProveedor;
  AllItems: Boolean;
begin
  AFacturas := Nil;
  AllItems := False;

  if MultiSelect and Assigned(ViewGrid) then
     AllItems :=  (ViewGrid.NumSeleccionados > 1);

  //Si esta agrupado solo podré imprimir la lista de elementos visibles
  if not ViewGrid.esSeleccionCeldaDatos then
     inherited
  else
  begin
    Respuesta := JsPrevisualizarDialog.Execute;
    if Respuesta <> IDCANCEL then
    begin
      case JsPrevisualizarDialog.CustomButtonResult of
        200   : begin   // Lista de elementos visibles
                  inherited;
                end;
        100   : begin   // Elemento Seleccionado
                  if AllItems then
                  begin
                    SeleccionarFilasDesdeGrid(ViewGrid._FocusedView, (Facturas as ISeleccionable).SelectedRecords);
                    AFacturas := (Controller as IFacturasProveedorController).ExtraerSeleccionados(Facturas, ViewGrid) as IBizFacturaProveedor;
                  end
                  else
                    AFacturas := Facturas;

                  if Assigned(AFacturas) then
                     FController.Preview(AFacturas, AllItems);
                end;
      end;
    end;
  end;
end;

procedure TfEditorFacturasProveedor.RefrescarInterno;
begin
  //Volvemos a cargar los años de las facturas
  if Assigned(FController) then
     ListaAnos := FController.DarListaAnosFacturas;

  inherited;
end;

procedure TfEditorFacturasProveedor.SetController(const Value: IFacturasProveedorController);
begin
  FController := Value;

  if Assigned(FController) then
     ListaAnos := FController.DarListaAnosFacturas;  
end;

procedure TfEditorFacturasProveedor.SetFacturas(const Value: IBizFacturaProveedor);
begin
  FFacturas := Value;

  if Assigned(FFacturas) then
  begin
    //Se guarda el where de la sentencia origen, por si el editor tiene filtros que
    //afecten a este where y en un futuro se desea volver al where origen (filtro de año))
    WhereDataTable := FFacturas.DataTable.Where.Clause;

    dsDataTable.DataTable := FFacturas.DataTable;
    if Assigned(ViewGrid) then
      (ViewGrid as IViewFacturasProveedor).Facturas := Facturas;
  end;
end;

end.