LuisLeon_FactuGES/Modulos/Pedidos de cliente/Controller/uDetallesPedidoClienteController.pas

unit uDetallesPedidoClienteController;

interface

uses
  uControllerDetallesBase, uBizDetallesPedidoCliente, uIDataModulePedidosCliente;

type
  IDetallesPedidoClienteController = interface(IControllerDetallesBase)
  ['{8D1D3559-E695-4962-9999-404B26B50D6C}']
    procedure AssignarIDDetalles(Modificar:Boolean; ADetalles: IBizDetallesPedidoCliente; IDCabecera: Integer; ADataModule : IDataModulePedidosCliente);
  end;

  TDetallesPedidoClienteController = class(TControllerDetallesBase, IDetallesPedidoClienteController)
    procedure AssignarIDDetalles(Modificar:Boolean; ADetalles: IBizDetallesPedidoCliente; IDCabecera: Integer; ADataModule : IDataModulePedidosCliente);
  end;

implementation

{ TDetallesPedidoClienteController }

procedure TDetallesPedidoClienteController.AssignarIDDetalles(
  Modificar: Boolean; ADetalles: IBizDetallesPedidoCliente;
  IDCabecera: Integer; ADataModule: IDataModulePedidosCliente);

begin
  with ADetalles do
  begin
    DataTable.DisableControls;
    try
      begin
        if not DataTable.Active then
          DataTable.Active := True;

        { ¡¡¡¡ OJO !!!!
          Para asignar el ID en los detalles hay
          que tener en cuenta una cosa:
          Si se cambia el ID, ese detalle ya no
          pertenece a esa cabecera porque ya no se
          cumple la condición de la relacion:
            Master.ID = Detail.ID_PRESUPUESTO.

          Por esa razón no sirve hacer un recorrido
          desde el principio hasta el final porque
          las detalles van desapareciendo según asignamos
          el valor al campo ID y nos mueve aleatoriamente
          la posición del registro actual.

          Es mejor hacer un bucle sencillo hasta que
          "se gasten" todos los detalles. Cuando el
          RecordCount llegue a 0 quiere decir que hemos
          tratado todos los detalles.

          El bucle cambia en el caso de ser llamada esta funcion desde modificar
          un presupuesto ya que en ese caso si que hay que hacer un recorrido
          total de las tuplas de detalle.
        }

        if not Modificar then
        begin
          while RecordCount > 0 do
          begin
            DataTable.First;
            Edit;
            ID := ADataModule.GetNextID(DataTable.LogicalName);
            ID_PEDIDO := IDCabecera;
            Post
          end
        end
        else
        begin
          DataTable.First;
          while not DataTable.EOF do
          begin
            if ID < 0 then
            begin
              Edit;
              ID := ADataModule.GetNextID(DataTable.LogicalName);
              ID_PEDIDO := IDCabecera;
              Post
            end;
            DataTable.Next
          end;
        end;
      end;
    finally
      DataTable.EnableControls;
    end;
  end;
end;

end.