LuisLeon_FactuGES/Modulos/Facturas de proveedor/Views/uViewFacturasProveedor.pas

unit uViewFacturasProveedor;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, uViewGrid, uViewPreview, cxStyles, cxCustomData, cxGraphics,
  cxFilter, cxData, cxDataStorage, cxEdit, DB, cxDBData, dxPSGlbl, dxPSUtl,
  dxPSEngn, dxPrnPg, dxBkgnd, dxWrap, dxPrnDev, dxPSCompsProvider,
  dxPSFillPatterns, dxPSEdgePatterns, cxImageComboBox, cxTextEdit, ImgList,
  PngImageList, cxGridCustomTableView, cxGridTableView, cxGridDBTableView,
  dxPSCore, dxPScxCommon, dxPScxGridLnk, ActnList, uDADataTable,
  cxGridLevel, cxClasses, cxControls, cxGridCustomView, cxGrid,
  cxImage, Grids, DBGrids, uBizFacturasProveedor, cxGridCustomPopupMenu,
  cxGridPopupMenu, cxCalendar, cxCurrencyEdit;

type
  IViewFacturasProveedor = interface(IViewGrid)
  ['{F0015E71-D890-4266-B7F4-7BCB38AFA0DE}']
    function GetFacturas: IBizFacturaProveedor;
    procedure SetFacturas(const Value: IBizFacturaProveedor);
    property Facturas: IBizFacturaProveedor read GetFacturas write SetFacturas;

    procedure FiltrarPorFechas(const Fecha1, Fecha2: Variant);
  end;

  TfrViewFacturasProveedor = class(TfrViewGrid, IViewFacturasProveedor)
    PngImageList: TPngImageList;
    cxGridViewNOMBRE: TcxGridDBColumn;
    cxGridViewREFERENCIA: TcxGridDBColumn;
    cxGridViewICONO: TcxGridDBColumn;
    cxGridViewFECHA_FACTURA: TcxGridDBColumn;
    cxGridViewSITUACION: TcxGridDBColumn;
    cxGridViewBASE_IMPONIBLE: TcxGridDBColumn;
    cxGridViewIMPORTE_DESCUENTO: TcxGridDBColumn;
    cxGridViewDESCUENTO: TcxGridDBColumn;
    cxGridViewIMPORTE_IVA: TcxGridDBColumn;
    cxGridViewIMPORTE_TOTAL: TcxGridDBColumn;
    cxGridViewIVA: TcxGridDBColumn;
    cxGridViewNIF_CIF: TcxGridDBColumn;
    cxGridViewCALLE: TcxGridDBColumn;
    cxGridViewPROVINCIA: TcxGridDBColumn;
    cxGridViewCODIGO_POSTAL: TcxGridDBColumn;
    cxGridViewPOBLACION: TcxGridDBColumn;
    cxStylePagada: TcxStyle;
    cxGridPendientes: TcxGridLevel;
    cxGridParcial: TcxGridLevel;
    cxStyleAbono: TcxStyle;
    cxGridViewID: TcxGridDBColumn;
    cxGridPagadas: TcxGridLevel;
    cxGridViewREFERENCIA_COMISION: TcxGridDBColumn;
    cxGridViewREFERENCIA_PROVEEDOR: TcxGridDBColumn;
    cxStylePendientes: TcxStyle;
    cxStyleParciales: TcxStyle;
    procedure cxGridViewICONOCustomDrawCell(Sender: TcxCustomGridTableView;
      ACanvas: TcxCanvas; AViewInfo: TcxGridTableDataCellViewInfo;
      var ADone: Boolean);
    procedure cxGridViewStylesGetContentStyle(Sender: TcxCustomGridTableView;
      ARecord: TcxCustomGridRecord; AItem: TcxCustomGridTableItem;
      out AStyle: TcxStyle);
    procedure cxGridActiveTabChanged(Sender: TcxCustomGrid; ALevel: TcxGridLevel);

  protected
    FNivelFiltrado : TcxFilterCriteriaItemList;
    FFacturas: IBizFacturaProveedor;
    function GetFacturas: IBizFacturaProveedor;
    procedure SetFacturas(const Value: IBizFacturaProveedor);
    procedure FilterChanged(Sender : TObject); override;

  public
    property Facturas: IBizFacturaProveedor read GetFacturas write SetFacturas;
    procedure FiltrarPorFechas(const Fecha1, Fecha2: Variant);    
  end;


implementation

uses
  uDataModuleFacturasProveedor, DateUtils;

{$R *.dfm}

{ TfrViewFacturasProveedor }

procedure TfrViewFacturasProveedor.cxGridActiveTabChanged(Sender: TcxCustomGrid;
  ALevel: TcxGridLevel);
begin
  inherited;
  FreeAndNil(FNivelFiltrado);
  FilterChanged(Self);
end;

procedure TfrViewFacturasProveedor.cxGridViewICONOCustomDrawCell(
  Sender: TcxCustomGridTableView; ACanvas: TcxCanvas;
  AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
var
  R : TRect;
begin
  inherited;
  R := AViewInfo.ContentBounds;
  ACanvas.FillRect(R);
  if (Pos('-', AViewInfo.GridRecord.DisplayTexts[cxGridViewIMPORTE_TOTAL.Index]) > 0) then
    ACanvas.DrawImage(PngImageList, R.Left, R.Top, 3)
  else
    ACanvas.DrawImage(PngImageList, R.Left, R.Top, 2);
  ADone := True;
end;

procedure TfrViewFacturasProveedor.cxGridViewStylesGetContentStyle(
  Sender: TcxCustomGridTableView; ARecord: TcxCustomGridRecord;
  AItem: TcxCustomGridTableItem; out AStyle: TcxStyle);
var
  IndiceCol: Integer;
  ASituacion: string;
begin
  inherited;

  if Assigned(ARecord) then
  begin

    IndiceCol := cxGridViewSITUACION.Index;
    ASituacion := UPPERCASE(VarToStr(ARecord.DisplayTexts[IndiceCol]));
    if (ASituacion = CTE_PAGADA) then
      AStyle := cxStylePagada
    else if (ASituacion = CTE_PENDIENTE) then
      AStyle := cxStylePendientes
    else if (ASituacion = CTE_PARCIAMENTE_PAGADA) then
      AStyle := cxStyleParciales;

    IndiceCol := cxGridViewIMPORTE_TOTAL.Index;
    if (Pos('-', ARecord.DisplayTexts[IndiceCol]) > 0) then
      AStyle := cxStyleAbono;
  end;
end;

procedure TfrViewFacturasProveedor.FilterChanged(Sender: TObject);
var
  AItemList: TcxFilterCriteriaItemList;
  AItemList2: TcxFilterCriteriaItemList;
begin
  inherited;

  cxGridView.DataController.Filter.BeginUpdate;

  AItemList := cxGridView.DataController.Filter.Root;
  AItemList2 := AItemList.AddItemList(fboAnd);
  FNivelFiltrado := AItemList2;

  case cxGrid.ActiveLevel.Index of
    1   : AItemList2.AddItem(cxGridViewSITUACION, foEqual, CTE_PENDIENTE, CTE_PENDIENTE);
    2   : AItemList2.AddItem(cxGridViewSITUACION, foEqual, CTE_PARCIAMENTE_PAGADA, CTE_PARCIAMENTE_PAGADA);
    3   : AItemList2.AddItem(cxGridViewSITUACION, foEqual, CTE_PAGADA, CTE_PAGADA);
  end;
  AItemList := AItemList2;

  if cxGridView.DataController.Filter.IsEmpty
  then cxGridView.DataController.Filter.Active := False
  else cxGridView.DataController.Filter.Active := True;

  cxGridView.DataController.Filter.EndUpdate;
  cxGrid.ActiveLevel.GridView := cxGridView;
end;

procedure TfrViewFacturasProveedor.FiltrarPorFechas(const Fecha1, Fecha2: Variant);
var
  Columna: TcxGridDBColumn;
begin
  with cxGridView.DataController.Filter do
  begin
    BeginUpdate;
    try
      Options := [fcoCaseInsensitive, fcoSoftCompare];
      Root.Clear;
      if  not VarIsNull(Fecha1)
      and not VarIsNull(Fecha2) then
      begin
        Columna := (cxGridView as TcxGridDBTableView).GetColumnByFieldName('FECHA_FACTURA');
        Root.AddItem(Columna, foBetween, varArrayOf([Fecha1, Fecha2]), VarToStr(Fecha1) + ' and ' + VarToStr(Fecha2));
        Active := True;
      end
      else
        Active := False;
    finally
      EndUpdate;
    end;
  end;
end;

function TfrViewFacturasProveedor.GetFacturas: IBizFacturaProveedor;
begin
  Result := FFacturas;
end;

procedure TfrViewFacturasProveedor.SetFacturas(const Value: IBizFacturaProveedor);
begin
  FFacturas := Value;
  if Assigned(FFacturas) then
    dsDataSource.DataTable := FFacturas.DataTable;
end;

end.