{
===============================================================================
  Copyright (©) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 22-05-2006
  Versión actual: 1.0.0
  Fecha versión actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorGruposCliente;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorGruposCliente, uCustomEditor, uGUIBase, ExtCtrls,
  ComCtrls, uBizGruposCliente, uGruposClienteController, uDAInterfaces;

type
  TfEditorGruposCliente = class(TCustomEditor, IEditorGruposCliente)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaGruposCliente: TDBLookupListBox;
    editGrupoCliente: TEdit;
    bAnadir: TButton;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    GroupBox1: TGroupBox;
    Label1: TLabel;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FGruposCliente: IBizGrupoCliente;
    FController: IGruposClienteController;
    function GetGruposCliente: IBizGrupoCliente;
    procedure SetGruposCliente(const Value: IBizGrupoCliente);
    function GetController : IGruposClienteController;
    procedure SetController (const Value : IGruposClienteController);
  public
    property GruposCliente: IBizGrupoCliente read GetGruposCliente write SetGruposCliente;
    property Controller : IGruposClienteController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorGruposCliente }

uses
  uDialogUtils;


function TfEditorGruposCliente.GetController: IGruposClienteController;
begin
  Result := FController;
end;

function TfEditorGruposCliente.GetGruposCliente: IBizGrupoCliente;
begin
  Result := FGruposCliente;
end;

procedure TfEditorGruposCliente.SetController(const Value: IGruposClienteController);
begin
  FController := Value;
end;

procedure TfEditorGruposCliente.SetGruposCliente(const Value: IBizGrupoCliente);
begin
  FGruposCliente := Value;
  DADataSource.DataTable := (FGruposCliente as IBizGrupoCliente).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorGruposCliente.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(GruposCliente, editGrupoCliente.Text) then
  begin
    GruposCliente.Append;
    GruposCliente.DESCRIPCION := editGrupoCliente.Text;
    GruposCliente.Post;
    editGrupoCliente.Clear;
    ListaGruposCliente.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe el grupo ' + editGrupoCliente.Text,
      'Ya existe el grupo de cliente ''' + editGrupoCliente.Text + ''' en la lista.');
end;

procedure TfEditorGruposCliente.actEliminarExecute(Sender: TObject);
begin
  GruposCliente.Delete;
  ListaGruposCliente.SetFocus;
end;

procedure TfEditorGruposCliente.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FGruposCliente.DataTable.RecordCount > 0) and
                                  (Length(ListaGruposCliente.SelectedItem) > 0);

end;

procedure TfEditorGruposCliente.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FGruposCliente := Nil;
  FController := Nil;
end;

procedure TfEditorGruposCliente.actAceptarExecute(Sender: TObject);
begin
  try
    GruposCliente.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      GruposCliente.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorGruposCliente.actCancelarExecute(Sender: TObject);
begin
  GruposCliente.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorGruposCliente.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorGruposCliente.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editGrupoCliente.Text) > 0)
end;

procedure TfEditorGruposCliente.FormShow(Sender: TObject);
begin
  if not FGruposCliente.DataTable.Active then
     FGruposCliente.DataTable.Active := true;

  editGrupoCliente.SetFocus;
end;

end.
