unit uDataModulePedidosCliente;

interface

uses
  DB, Classes, SysUtils, uDADesigntimeCall, 
  uRORemoteService, uROClient, uROBinMessage, uDAScriptingProvider,
  uDACDSDataTable, uROWinInetHttpChannel, uDADataTable, uDABINAdapter,

  uROTypes, uDataModuleBase,
  uIDataModulePedidosCliente, uIDataModulePedidosClienteReport,
  uBizPedidosCliente, uBizDetallesPedidoCliente, uDARemoteDataAdapter,
  uDADataStreamer, uDABin2DataStreamer, uDAInterfaces, uDAMemDataTable,
  uIntegerListUtils;

type
  TDataModulePedidosCliente = class(TDataModuleBase, IDataModulePedidosCliente,
                                      IDataModulePedidosClienteReport)
    RORemoteService: TRORemoteService;
    Bin2DataStreamer: TDABin2DataStreamer;
    rda_PedidosCliente: TDARemoteDataAdapter;
    tbl_ListaAnosPedidos: TDAMemDataTable;
    ds_ListaAnosPedidos: TDADataSource;
    tbl_PedidoCliente_ArticulosPendientesPedirAProv: TDAMemDataTable;
    ds_PedidoCliente_ArticulosPendientesPedirAProv: TDADataSource;
    tbl_PedidosCliente: TDAMemDataTable;
    ds_PedidosCliente: TDADataSource;
    tbl_PedidosCliente_Articulos_Pendientes: TDAMemDataTable;
    ds_PedidosCliente_Articulos_Pendientes: TDADataSource;
    tbl_PedidosCliente_Detalles: TDAMemDataTable;
    ds_PedidosCliente_Detalles: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);

  private
    function _GetDetalles : IBizDetallesPedidoCliente;

  protected
    procedure AsignarClaseNegocio(var APedido: TDAMemDataTable); virtual;

  public
    function GetItems : IBizPedidoCliente; virtual;
    function GetItem(const ID : Integer) : IBizPedidoCliente;
    function NewItem : IBizPedidoCliente;
    function GetArticulosPendientesPedirAProv(const IDPedido: Integer): IBizPedidoClienteArticulosPendientesPedirAProv;
    function GetArticulosPendientes(const IDPedido: Integer): IBizPedidoClienteArticulosPend;


    // Report
    function GetReport(const ListaID: TIntegerList;
      const ImprimirPrecio: Boolean = True;
      const ImprimirRefProveedor: Boolean = True): Binary;
    function GetRptPDFPedido(const AID: Integer;
      const ImprimirPrecio: Boolean = True;
      const ImprimirRefProveedor: Boolean = True): Binary;

    function GetAnosItems : TStringList;      
  end;

implementation

{$R *.DFM}

uses
  cxControls, FactuGES_Intf, uDataModuleConexion,
  uDataTableUtils, schPedidosClienteClient_Intf, uBizContactos;

{ TdmPedidosCliente }

procedure TDataModulePedidosCliente.AsignarClaseNegocio(var APedido: TDAMemDataTable);
begin
  APedido.BusinessRulesID := BIZ_CLIENT_PEDIDO_CLIENTE;
end;

procedure TDataModulePedidosCliente.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModulePedidosCliente.GetReport(const ListaID: TIntegerList;
  const ImprimirPrecio: Boolean = True;
  const ImprimirRefProveedor: Boolean = True): Binary;
var
  AParam : TIntegerArray;
begin
  AParam := ListaID.ToIntegerArray;
  try
    Result := (RORemoteService as IsrvPedidosCliente).GenerarInforme(AParam,
      ImprimirPrecio, ImprimirRefProveedor);
  finally
    FreeANDNil(AParam);
  end;
end;

function TDataModulePedidosCliente.GetRptPDFPedido(
  const AID: Integer; const ImprimirPrecio: Boolean = True;
  const ImprimirRefProveedor: Boolean = True): Binary;
var
  AParam : TIntegerArray;
begin
  AParam := TIntegerArray.Create;
  try
    AParam.Add(AID);
    Result := (RORemoteService as IsrvPedidosCliente).GenerarInformeEnPDF(AParam,
      ImprimirPrecio, ImprimirRefProveedor);
  finally
    FreeANDNil(AParam);
  end;
end;

function TDataModulePedidosCliente.NewItem: IBizPedidoCliente;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModulePedidosCliente._GetDetalles: IBizDetallesPedidoCliente;
var
  ADetalles : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    ADetalles := CloneDataTable(tbl_PedidosCliente_Detalles);
    with ADetalles do
    begin
      BusinessRulesID := BIZ_CLIENT_DETALLES_PEDIDO_CLIENTE;
      DetailOptions := DetailOptions - [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (ADetalles as IBizDetallesPedidoCliente);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetAnosItems: TStringList;
var
  AListaAnos: TStringList;
begin
  AListaAnos := TStringList.Create;
  ShowHourglassCursor;
  try
    with tbl_ListaAnosPedidos do
    begin
      Open;
      First;
      while not eof do
      begin
        AListaAnos.Add(Format('%s=%s', [Fields[0].AsString, Fields[0].AsString]));
        Next;
      end;
      Close;
    end;
    Result := AListaAnos;
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetArticulosPendientes(const IDPedido: Integer): IBizPedidoClienteArticulosPend;
var
  AArticulos : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    AArticulos := CloneDataTable(tbl_PedidosCliente_Articulos_Pendientes);
    AArticulos.BusinessRulesID := BIZ_CLIENT_ARTICULOS_PEND_PEDIDO_CLIENTE;
    AArticulos.ParamByName('ID').AsInteger := IDPedido;
    Result := (AArticulos as IBizPedidoClienteArticulosPend);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetArticulosPendientesPedirAProv(const IDPedido: Integer): IBizPedidoClienteArticulosPendientesPedirAProv;
var
  AArticulos : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    AArticulos := CloneDataTable(tbl_PedidoCliente_ArticulosPendientesPedirAProv);
    AArticulos.BusinessRulesID := BIZ_CLIENT_PEDIDO_CLIENTE_ARTICULOS_PENDIENTES_PEDIR_A_PROV;
    AArticulos.ParamByName('ID').AsInteger := IDPedido;
    Result := (AArticulos as IBizPedidoClienteArticulosPendientesPedirAProv);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetItem(const ID: Integer): IBizPedidoCliente;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := Self.GetItems;

    with Result.DataTable.DynamicWhere do
    begin
      // (ID = :ID)
      Condicion := NewBinaryExpression(NewField('', fld_PedidosClienteID), NewConstant(ID, datInteger), dboEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

function TDataModulePedidosCliente.GetItems: IBizPedidoCliente;
var
  APedido : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    APedido := CloneDataTable(tbl_PedidosCliente);
    AsignarClaseNegocio(APedido);
    
    // EL CAMPO REFERENCIA TIENE QUE SER AUTOREFRESH!!!!!
    APedido.FieldByName(fld_PedidosClienteREFERENCIA).ServerAutoRefresh := TRUE;

    with TBizPedidoCliente(APedido.BusinessEventsObj) do
      Detalles := _GetDetalles;

    Result := (APedido as IBizPedidoCliente);
  finally
    HideHourglassCursor;
  end;
end;

end.