LuisLeon_FactuGES2/Source/Modulos/Facturas proforma/Controller/uDetallesFacturaProformaController.pas

unit uDetallesFacturaProformaController;

interface

uses
  Classes, uDADataTable, uControllerDetallesArticulos, uBizDetallesFacturaProforma, uIDataModuleFacturasProforma,
  uBizContactos, uBizArticulos;

type
  IDetallesFacturaProformaController = interface(IControllerDetallesArticulos)
  ['{5DBAE3ED-D54F-4C62-AEBF-2BED29D91DD2}']
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente);
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
  end;

  TDetallesFacturaProformaController = class(TControllerDetallesArticulos, IDetallesFacturaProformaController)
  private
    FDataModule : IDataModuleFacturasProforma;
  protected
//    procedure AsignarDatos(ADetalles: IDAStronglyTypedDataTable; IDCabecera: Integer); override;
    procedure RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); overload; override;
    procedure RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); override;

    procedure AsignarController; override;
    //Si sobreescribimos este método podremos tener en cuenta otras columnas para el calculo del importe total de un concepto
    function CalcularImporteTotalConcepto(DataTable: TDADataTable): Double; override;
    procedure ValidarCampos(DataTable: TDADataTable); override;
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;

  public
    function DarListaTiposDetalle: TStringList; override;

    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente); overload;

    constructor Create; override;
    destructor Destroy; override;
  end;

implementation

{ TDetallesFacturaProformaController }

uses Variants, uDataModuleFacturasProforma, uArticulosFacturaProformaController,
  uControllerDetallesBase, Dialogs, uDialogUtils, SysUtils, uCalculosUtils;

procedure TDetallesFacturaProformaController.ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente);
var
  AArticulos : IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos(ACliente) as IBizArticulo);
      ActualizarDetalles(ADetalles, AArticulos);
      ShowInfoMessage('Se ha actualizado el descuento para el cliente seleccionado');
    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesFacturaProformaController.AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean; const ACantidad: Integer);
var
  AArticulos: IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos(ACliente) as IBizArticulo);

      //Si nueva fila es false, quiere decir que se sustituye un determinado artículo, por ello la lista a seleccionar no debe ser multiselect
      if ANuevaFila then
      begin
        AArticulos := (FArticulosController as IArticulosFacturaProformaController).ElegirArticulos(AArticulos, 'Elija los artículos que desea añadir a esta factura de cliente', True);
        Add(ADetalles, AArticulos, ACantidad)
      end
      else
      begin
        AArticulos := (FArticulosController as IArticulosFacturaProformaController).ElegirArticulos(AArticulos, 'Elija el artículo que desea añadir a esta factura de cliente', False);
        RellenarDetalle(ADetalles, AArticulos, ACantidad);
      end;

    finally
      AArticulos := Nil;
    end;
  end;
end;


procedure TDetallesFacturaProformaController.AsignarController;
begin
  FArticulosController := TArticulosFacturaProformaController.Create;
end;

function TDetallesFacturaProformaController.CalcularImporteTotalConcepto(DataTable: TDADataTable): Double;
begin
  Result := CalcularLineaConcepto(DataTable);
end;

constructor TDetallesFacturaProformaController.Create;
begin
  inherited;
  FDataModule := TDataModuleFacturasProforma.Create(Nil);
end;

function TDetallesFacturaProformaController.DarListaTiposDetalle: TStringList;
begin
  Result := TStringList.Create;
  Result.Values[TIPO_DETALLE_CONCEPTO] := TIPO_DETALLE_CONCEPTO;
  Result.Values[TIPO_DETALLE_TITULO] := TIPO_DETALLE_TITULO;
//  Result.Values[TIPO_DETALLE_TITULO_OPCIONAL] := TIPO_DETALLE_TITULO_OPCIONAL;
  Result.Values[TIPO_DETALLE_SUBTOTAL] := TIPO_DETALLE_SUBTOTAL;
//  Result.Values[TIPO_DETALLE_DESCUENTO] := TIPO_DETALLE_DESCUENTO;
//  Result.Values[TIPO_DETALLE_SALTO] := TIPO_DETALLE_SALTO;
end;

function TDetallesFacturaProformaController.DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
begin
  Result := DarTotalPorte(ADetalles);
end;

procedure TDetallesFacturaProformaController.DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
begin
  DesglosarPorte(ImportePorte, ADetalles);
  ActualizarTotales(ADetalles);  
end;

destructor TDetallesFacturaProformaController.Destroy;
begin
  FDataModule := Nil;
  inherited;
end;

procedure TDetallesFacturaProformaController.RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
begin
  if Assigned(AArticulos) then
    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := AArticulos.DESCUENTO
  else
    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := 0;
end;

procedure TDetallesFacturaProformaController.ValidarCampos(DataTable: TDADataTable);
begin
  inherited;
  ValidarCamposLineaConcepto(DataTable);
end;

procedure TDetallesFacturaProformaController.RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
begin
//Como en tecsitel no hay descuento por linea de detalle, solo recuperamos nuevamente el valor del articulo cuando el detalle no tenga niguno
//de esta forma evitamos que al cambiar de cliente se quiten los importes que se hubiesen establecido para los articulos.
  if ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).IsNull then
     if Assigned(AArticulos) then
//       ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := AArticulos.PRECIO_PVP_TOTAL
       ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := AArticulos.PRECIO_COSTE
     else
       ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := Null;
end;

end.