{
===============================================================================
  Copyright (©) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 22-05-2006
  Versión actual: 1.0.0
  Fecha versión actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorFabricantes;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorFabricantes, uCustomEditor, uGUIBase, ExtCtrls,
  ComCtrls, uBizFabricantes, uFabricantesController, uDAInterfaces;

type
  TfEditorFabricantes = class(TCustomEditor, IEditorFabricantes)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaFabricantes: TDBLookupListBox;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    Label1: TLabel;
    Label2: TLabel;
    Bevel1: TBevel;
    eCategoria: TLabel;
    editFabricante: TEdit;
    bAnadir: TButton;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FFabricantes: IBizFabricante;
    FController: IFabricantesController;
    function GetFabricantes: IBizFabricante;
    procedure SetFabricantes(const Value: IBizFabricante);
    function GetController : IFabricantesController;
    procedure SetController (const Value : IFabricantesController);
  public
    property Fabricantes: IBizFabricante read GetFabricantes write SetFabricantes;
    property Controller : IFabricantesController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorFabricantes }

uses
  uDialogUtils;

function TfEditorFabricantes.GetController: IFabricantesController;
begin
  Result := FController;
end;

function TfEditorFabricantes.GetFabricantes: IBizFabricante;
begin
  Result := FFabricantes;
end;

procedure TfEditorFabricantes.SetController(const Value: IFabricantesController);
begin
  FController := Value;
end;

procedure TfEditorFabricantes.SetFabricantes(const Value: IBizFabricante);
begin
  FFabricantes := Value;
  DADataSource.DataTable := (FFabricantes as IBizFabricante).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorFabricantes.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(Fabricantes, editFabricante.Text) then
  begin
    Fabricantes.Append;
    Fabricantes.DESCRIPCION := editFabricante.Text;
    Fabricantes.Post;
    editFabricante.Clear;
    ListaFabricantes.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe la unidad ' + editFabricante.Text,
      'Ya existe la unidad ''' + editFabricante.Text + ''' en la lista.');
end;

procedure TfEditorFabricantes.actEliminarExecute(Sender: TObject);
begin
  Fabricantes.Delete;
  ListaFabricantes.SetFocus;
end;

procedure TfEditorFabricantes.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FFabricantes.DataTable.RecordCount > 0) and
                                  (Length(ListaFabricantes.SelectedItem) > 0);

end;

procedure TfEditorFabricantes.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FFabricantes := Nil;
  FController := Nil;
end;

procedure TfEditorFabricantes.actAceptarExecute(Sender: TObject);
begin
  try
    Fabricantes.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      Fabricantes.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorFabricantes.actCancelarExecute(Sender: TObject);
begin
  Fabricantes.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorFabricantes.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorFabricantes.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editFabricante.Text) > 0)
end;

procedure TfEditorFabricantes.FormShow(Sender: TObject);
begin
  if not FFabricantes.DataTable.Active then
     FFabricantes.DataTable.Active := true;

  FFabricantes.DataTable.Sort(['DESCRIPCION'], [sdAscending]);
  EditFabricante.SetFocus;
end;

end.
