{
===============================================================================
  Copyright (©) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 22-05-2006
  Versión actual: 1.0.0
  Fecha versión actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorGruposEmpleado;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorGruposEmpleado, uCustomEditor, uGUIBase, ExtCtrls,
  ComCtrls, uBizGruposEmpleado, uGruposEmpleadoController;

type
  TfEditorGruposEmpleado = class(TCustomEditor, IEditorGruposEmpleado)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaGruposEmpleado: TDBLookupListBox;
    editGrupoEmpleado: TEdit;
    bAnadir: TButton;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    GroupBox1: TGroupBox;
    Label1: TLabel;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FGruposEmpleado: IBizGrupoEmpleado;
    FController: IGruposEmpleadoController;
    function GetGruposEmpleado: IBizGrupoEmpleado;
    procedure SetGruposEmpleado(const Value: IBizGrupoEmpleado);
    function GetController : IGruposEmpleadoController;
    procedure SetController (const Value : IGruposEmpleadoController);
  public
    property GruposEmpleado: IBizGrupoEmpleado read GetGruposEmpleado write SetGruposEmpleado;
    property Controller : IGruposEmpleadoController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorGruposEmpleado }

uses
  uDialogUtils;


function TfEditorGruposEmpleado.GetController: IGruposEmpleadoController;
begin
  Result := FController;
end;

function TfEditorGruposEmpleado.GetGruposEmpleado: IBizGrupoEmpleado;
begin
  Result := FGruposEmpleado;
end;

procedure TfEditorGruposEmpleado.SetController(const Value: IGruposEmpleadoController);
begin
  FController := Value;
end;

procedure TfEditorGruposEmpleado.SetGruposEmpleado(const Value: IBizGrupoEmpleado);
begin
  FGruposEmpleado := Value;
  DADataSource.DataTable := (FGruposEmpleado as IBizGrupoEmpleado).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorGruposEmpleado.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(GruposEmpleado, editGrupoEmpleado.Text) then
  begin
    GruposEmpleado.Append;
    GruposEmpleado.DESCRIPCION := editGrupoEmpleado.Text;
    GruposEmpleado.Post;
    editGrupoEmpleado.Clear;
    ListaGruposEmpleado.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe el grupo ' + editGrupoEmpleado.Text,
      'Ya existe la categoría de empleado ''' + editGrupoEmpleado.Text + ''' en la lista.');
end;

procedure TfEditorGruposEmpleado.actEliminarExecute(Sender: TObject);
begin
  GruposEmpleado.Delete;
  ListaGruposEmpleado.SetFocus;
end;

procedure TfEditorGruposEmpleado.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FGruposEmpleado.DataTable.RecordCount > 0) and
                                  (Length(ListaGruposEmpleado.SelectedItem) > 0);

end;

procedure TfEditorGruposEmpleado.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FGruposEmpleado := Nil;
  FController := Nil;
end;

procedure TfEditorGruposEmpleado.actAceptarExecute(Sender: TObject);
begin
  try
    GruposEmpleado.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      GruposEmpleado.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorGruposEmpleado.actCancelarExecute(Sender: TObject);
begin
  GruposEmpleado.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorGruposEmpleado.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorGruposEmpleado.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editGrupoEmpleado.Text) > 0)
end;

procedure TfEditorGruposEmpleado.FormShow(Sender: TObject);
begin
  if not FGruposEmpleado.DataTable.Active then
     FGruposEmpleado.DataTable.Active := true;

  editGrupoEmpleado.SetFocus;
end;

end.