Noviseda_FactuGES2/Source/Modulos/Albaranes de proveedor/Controller/uDetallesAlbaranProveedorController.pas

unit uDetallesAlbaranProveedorController;

interface

uses
  uDADataTable, uControllerDetallesArticulos, uBizDetallesAlbaranProveedor, uIDataModuleAlbaranesProveedor,
  uBizArticulos, uBizContactos;

const
  CAMPO_REFERENCIA_FABRICANTE = 'REFERENCIA_FABRICANTE';
  
type
  IDetallesAlbaranProveedorController = interface(IControllerDetallesArticulos)
  ['{6E35D49A-C78D-481D-93E9-859CD27EB79F}']
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor); overload;
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
  end;

  TDetallesAlbaranProveedorController = class(TControllerDetallesArticulos, IDetallesAlbaranProveedorController)
  private
    FDataModule : IDataModuleAlbaranesProveedor;
  protected

    procedure RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); override;
    procedure RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); override;

    procedure AsignarController; override;
    //Si sobreescribimos este método podremos tener en cuenta otras columnas para el calculo del importe total de un concepto
    function CalcularImporteTotalConcepto(DataTable: TDADataTable): Double; override;
    procedure ValidarCampos(DataTable: TDADataTable); override;
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;

  public
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor; const ANuevaFila :Boolean = True; const ACantidad: Integer = 1); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor); overload;
    constructor Create; override;
    destructor Destroy; override;
  end;

implementation

uses uDAInterfaces, Variants, uDialogUtils, uControllerDetallesBase, uDataModuleAlbaranesProveedor, uArticulosAlbaranProveedorController,
     uDataTableUtils, uCalculosUtils, schArticulosClient_Intf;

{ TDetallesAlbaranProveedorController }

procedure TDetallesAlbaranProveedorController.ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor);
var
  AArticulos : IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos(AProveedor) as IBizArticulo);
      ActualizarDetalles(ADetalles, AArticulos);
      EliminarArticulosProveedor(ADetalles);
      ShowInfoMessage('Se han eliminado todos los artículos que no pertenecen al nuevo proveedor seleccionado, y los que pertenecen sus descuentos han sido adaptados al proveedor seleccionado');      
    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesAlbaranProveedorController.AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; AProveedor: IBizProveedor; const ANuevaFila :Boolean; const ACantidad: Integer);
var
  AArticulos: IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodosPorProveedor as IBizArticulo);

      //Si nueva fila es false, quiere decir que se sustituye un determinado artículo, por ello la lista a seleccionar no debe ser multiselect
      if ANuevaFila then
      begin
        AArticulos := (FArticulosController as IArticulosAlbaranProveedorController).ElegirArticulos(AArticulos, 'Elija los artículos que desea añadir a este albarán de proveedor', True, AProveedor);
        Add(ADetalles, AArticulos, ACantidad)
      end
      else
      begin
        AArticulos := (FArticulosController as IArticulosAlbaranProveedorController).ElegirArticulos(AArticulos, 'Elija el artículo que desea añadir a este albarán de proveedor', False, AProveedor);
        RellenarDetalle(ADetalles, AArticulos, ACantidad);
      end;

    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesAlbaranProveedorController.AsignarController;
begin
  FArticulosController := TArticulosAlbaranProveedorController.Create;
end;

function TDetallesAlbaranProveedorController.CalcularImporteTotalConcepto(DataTable: TDADataTable): Double;
begin
  Result := CalcularLineaConcepto(DataTable);
end;

constructor TDetallesAlbaranProveedorController.Create;
begin
  inherited;
  FDataModule := TDataModuleAlbaranesProveedor.Create(Nil);
end;

function TDetallesAlbaranProveedorController.DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
begin
  Result := DarTotalPorte(ADetalles);
end;

procedure TDetallesAlbaranProveedorController.DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
begin
  DesglosarPorte(ImportePorte, ADetalles);
  ActualizarTotales(ADetalles);  
end;

destructor TDetallesAlbaranProveedorController.Destroy;
begin
  FDataModule := Nil;
  inherited;
end;


procedure TDetallesAlbaranProveedorController.RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
var
  AField: TDAField;

begin
  if Assigned(AArticulos) then
    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := AArticulos.DESCUENTO
  else
    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := 0;

  //Sobreescribimos el id del articulo por el campo ID_ARTICULO que nos hemos tenido que crear para
  //almacenar el codigo de artículo ya que ID esta destinado a ID_ARTICULO||ID_PROVEEDOR, para identificar de forma
  //unica los articulos desglosados por proveedor.
  //Validamos la existencia de todos los campos necesarios
  AField := AArticulos.DataTable.FindField(CAMPO_ID_ARTICULOS);
  if Assigned(AField) then
  begin
//     if not ADetalles.DataTable.Editing then
//        ADetalles.DataTable.Edit;
     ADetalles.DataTable.FieldByName(CAMPO_ID_ARTICULOS).AsVariant := AField.AsVariant;
  end;

  AField := AArticulos.DataTable.FindField(fld_ArticulosREFERENCIA_FABR);
  if Assigned(AField) then
  begin
//     if not ADetalles.DataTable.Editing then
//        ADetalles.DataTable.Edit;
     ADetalles.DataTable.FieldByName(CAMPO_REFERENCIA_FABRICANTE).AsVariant := AField.AsVariant;
  end;
end;

procedure TDetallesAlbaranProveedorController.RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
begin
  if Assigned(AArticulos) then
  begin
     ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := AArticulos.PRECIO_COSTE;
     ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_PORTE).AsVariant := AArticulos.PRECIO_PORTE;
  end
  else
  begin
     ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := Null;
     ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_PORTE).AsVariant := Null;
  end;
end;

procedure TDetallesAlbaranProveedorController.ValidarCampos(DataTable: TDADataTable);
begin
  inherited;
  ValidarCamposLineaConcepto(DataTable);
end;

end.