Tecsitel_FactuGES2/Source/Modulos/Presupuestos de cliente/Reports/uRptPresupuestosCliente_Server.pas

unit uRptPresupuestosCliente_Server;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frxClass, frxDBSet, uDAScriptingProvider,
  uDADataTable, uDACDSDataTable, DB, uDAClasses, uDABINAdapter, uROTypes,
  uDAInterfaces, uDAMemDataTable, uDADataStreamer, uDABin2DataStreamer,
  frxGradient, frxChBox, frxCross, frxOLE, frxBarcode, frxRich, uDAEngine,
  IBSQL, IBDatabase, IBCustomDataSet, IBQuery, frxExportPDF, FactuGES_Intf;

type
  TRptPresupuestosCliente = class(TDataModule)
    DADSCabecera: TDADataSource;
    DADSDetalles: TDADataSource;
    frxBarCodeObject1: TfrxBarCodeObject;
    frxOLEObject1: TfrxOLEObject;
    frxCrossObject1: TfrxCrossObject;
    frxCheckBoxObject1: TfrxCheckBoxObject;
    frxGradientObject1: TfrxGradientObject;
    frxDBCabecera: TfrxDBDataset;
    frxDBDetalles: TfrxDBDataset;
    tbl_Cabecera: TDAMemDataTable;
    tbl_Detalles: TDAMemDataTable;
    frxReport: TfrxReport;
    IBDatabase1: TIBDatabase;
    IBTransaction1: TIBTransaction;
    DataSource1: TDataSource;
    DataSource2: TDataSource;
    capitulos: TIBQuery;
    DataSource3: TDataSource;
    detalles: TIBQuery;
    DataSource4: TDataSource;
    resumen: TIBQuery;
    resumenID: TIntegerField;
    resumenID_PRESUPUESTO: TIntegerField;
    resumenPOSICION: TIntegerField;
    resumenTIPO_DETALLE: TIBStringField;
    resumenCONCEPTO: TIBStringField;
    resumenIMPORTE_TOTAL: TIBBCDField;
    resumenVISIBLE: TSmallintField;
    frxDBCapitulos: TfrxDBDataset;
    frxDBResumen: TfrxDBDataset;
    DABin2DataStreamer1: TDABin2DataStreamer;
    cabecera: TIBQuery;
    cabeceraID: TIntegerField;
    cabeceraID_EMPRESA: TIntegerField;
    cabeceraFECHA_PRESUPUESTO: TDateField;
    cabeceraREFERENCIA: TIBStringField;
    cabeceraPORTADA: TMemoField;
    cabeceraMEMORIA: TMemoField;
    cabeceraOBSERVACIONES: TMemoField;
    cabeceraIMPORTE_NETO: TIBBCDField;
    cabeceraIMPORTE_PORTE: TIBBCDField;
    cabeceraDESCUENTO: TFloatField;
    cabeceraIMPORTE_DESCUENTO: TIBBCDField;
    cabeceraBASE_IMPONIBLE: TIBBCDField;
    cabeceraIVA: TFloatField;
    cabeceraID_CLIENTE: TIntegerField;
    cabeceraREFERENCIA_CLIENTE: TIBStringField;
    cabeceraCLIENTE_FINAL: TIBStringField;
    cabeceraNIF_CIF: TIBStringField;
    cabeceraNOMBRE: TIBStringField;
    cabeceraIMPORTE_IVA: TIBBCDField;
    cabeceraIMPORTE_TOTAL: TIBBCDField;
    cabeceraPERSONA_CONTACTO: TIBStringField;
    cabeceraCALLE: TIBStringField;
    cabeceraPOBLACION: TIBStringField;
    cabeceraPROVINCIA: TIBStringField;
    cabeceraCODIGO_POSTAL: TIBStringField;
    DADSCapitulos: TDADataSource;
    tbl_Capitulos: TDAMemDataTable;
    DADSResumen: TDADataSource;
    tbl_Resumen: TDAMemDataTable;
    DAMemDataTable1: TDAMemDataTable;
    DAMemDataTable2: TDAMemDataTable;
    frxPDFExport1: TfrxPDFExport;
    DADSInformeListadoPresupuestos: TDADataSource;
    tbl_InformeListadoPresupuestos: TDAMemDataTable;
    frxDBInformeListadoPresupuestos: TfrxDBDataset;
    frxDBInformeListadoPresupuestosResumen: TfrxDBDataset;
    DADSInformeListadoPresupuestosResumen: TDADataSource;
    tbl_InformeListadoPresupuestosResumen: TDAMemDataTable;
    schReport: TDASchema;
    DataDictionary: TDADataDictionary;
    procedure DataModuleCreate(Sender: TObject);
  private
    FConnection: IDAConnection;
    FIdEmpresa: Integer;
    FFechaInicio: Variant;
    FFechaFin: Variant;
    FListaIDClientes: TIntegerArray;
    FImporteMinimo: Currency;

    procedure _GenerarPresupuesto(const AID : Integer);

    procedure PrepararTablaInforme(ATabla: TDAMemDataTable);
    procedure PrepararTablaResumenInforme(ATabla: IDADataset);
    function _GenerarInforme(const TipoInforme: String): Binary;

  public
    function GenerarPresupuesto(const ListaID : TIntegerArray): Binary;
    function GenerarPresupuestoEnPDF(const ListaID : TIntegerArray): Binary;
    function GenerarInformeListadoPresupuestos(const IdEmpresa: Integer; const FechaInicio: Variant; const FechaFin: Variant; const ListaIDClientes: TIntegerArray; const Desglosado: Boolean; const ImporteMinimo: Currency): Binary;
  end;

implementation

{$R *.dfm}

uses
  uSistemaFunc, StrUtils, uDataModuleServer, schPresupuestosClienteClient_Intf;

const
  rptInforme = 'InfPresupuestoCliente.fr3';
  rptInformeListadoPresupuestosDesglosado = 'InformeListadoPresupuestosDesglosado.fr3';
  rptInformeListadoPresupuestos = 'InformeListadoPresupuestos.fr3';

  { Dataset names for schReport }
  ds_InformeListadoPresupuestosResumen = 'InformeListadoPresupuestosResumen';


procedure TRptPresupuestosCliente.DataModuleCreate(Sender: TObject);
begin
  schReport.ConnectionManager := dmServer.ConnectionManager;
  FConnection := dmServer.DarNuevaConexion;
  frxReport.EngineOptions.NewSilentMode := simReThrow;

  frxDBCabecera.DataSource := DADSCabecera;
  frxDBCapitulos.DataSource := DADSCapitulos;
  frxDBDetalles.DataSource := DADSDetalles;
  frxDBResumen.DataSource := DADSResumen;

  with tbl_Detalles do
  begin
    MasterSource := DADSCapitulos;
    MasterFields := 'ID';
    DetailFields := 'ID_CAPITULO';
  end;
end;

function TRptPresupuestosCliente.GenerarPresupuestoEnPDF(const ListaID: TIntegerArray): Binary;
var
  i: Integer;
begin
  Result := Binary.Create;
  try
    //Vamos generando todos y cada uno de los presupuestos recibidos
    for i := 0 to ListaID.Count - 1 do
        _GenerarPresupuesto(ListaID.Items[i]);

    frxPDFExport1.Stream := Result;
    frxReport.Export(frxPDFExport1)
  finally
  end;
end;

procedure TRptPresupuestosCliente.PrepararTablaInforme(ATabla: TDAMemDataTable);
var
  Condicion: TDAWhereExpression;
  i: Integer;

begin
  // Filtrar el informe por empresa
  with ATabla.DynamicWhere do
  begin
    // (ID_EMPRESA >= ID)
    Condicion := NewBinaryExpression(NewField('', fld_PresupuestosClienteID_EMPRESA), NewConstant(FIdEmpresa, datInteger), dboEqual);
    if IsEmpty then
       Expression := Condicion
    else
       Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
  end;

  // Filtrar el informe por fechas
  if  not VarIsNull(FFechaInicio)
  and not VarIsNull(FFechaFin) then
  begin
    with ATabla.DynamicWhere do
    begin
      // (FECHA_INICIO between FECHA_FIN)
      Condicion := NewBinaryExpression(NewField('', fld_PresupuestosClienteFECHA_PRESUPUESTO), NewConstant(FFechaInicio, datDateTime), dboGreaterOrEqual);
      Condicion := NewBinaryExpression(NewBinaryExpression(NewField('', fld_PresupuestosClienteFECHA_PRESUPUESTO), NewConstant(FFechaFin, datDateTime), dboLessOrEqual), Condicion, dboAnd);
      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;
  end;

  // Filtrar el informe por proveedor
  if  Assigned(FListaIDClientes) then
  begin
    with ATabla.DynamicWhere do
    begin
      for i := 0 to FListaIDClientes.Count - 1 do
      begin

        // (ID_PROVEEDOR = ID)
        Condicion := NewBinaryExpression(NewField('', fld_PresupuestosClienteID_CLIENTE), NewConstant(FListaIDClientes.Items[i], datInteger), dboEqual);
        if IsEmpty then
           Expression := Condicion
        else
           Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
        end;
    end;
  end;

  // Filtrar el informe por importe minimo
  if  (FImporteMinimo > 0) then
  begin
    with ATabla.DynamicWhere do
    begin
      // (IMPORTE_TOTAL > ImporteMinimo)
      Condicion := NewBinaryExpression(NewField('', fld_PresupuestosClienteIMPORTE_TOTAL), NewConstant(FImporteMinimo, datCurrency), dboGreaterOrEqual);
      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;
  end;
end;

procedure TRptPresupuestosCliente.PrepararTablaResumenInforme(ATabla: IDADataset);
var
  i: Integer;
  AWhereStr : String;

begin
  // Filtrar el informe por empresa
  AWhereStr := ' (' + fld_PresupuestosClienteID_EMPRESA + ' = ' + IntToStr(FIdEmpresa) + ') ';

  // Filtrar el informe por fechas
  if  not VarIsNull(FFechaInicio)
  and not VarIsNull(FFechaFin) then
  begin
    if Length(AWhereStr) > 0 then
       AWhereStr := AWhereStr + 'AND';
    AWhereStr := AWhereStr + ' (' + fld_PresupuestosClienteFECHA_PRESUPUESTO + ' between ''' + ReplaceStr(VarToStr(FFechaInicio),'/','.') + ''' and ''' + ReplaceStr(VarToStr(FFechaFin),'/','.') + ''') ';
  end;

  // Filtrar el informe por cliente
  if  Assigned(FListaIDClientes) then
  begin
    for i := 0 to FListaIDClientes.Count - 1 do
    begin
      if Length(AWhereStr) > 0 then
         AWhereStr := AWhereStr + 'AND';
      AWhereStr := AWhereStr + ' (' + fld_PresupuestosClienteID_CLIENTE + ' = ' + IntToStr(FListaIDClientes.Items[i]) + ') ';
    end;
  end;

  // Filtrar el informe por importe minimo
  if  (FImporteMinimo > 0) then
  begin
    if Length(AWhereStr) > 0 then
       AWhereStr := AWhereStr + 'AND';
    AWhereStr := AWhereStr + ' (' + fld_PresupuestosClienteIMPORTE_TOTAL + ' >= ' + CurrToStr(FImporteMinimo) + ') ';
  end;

  ATabla.Where.AddText(AWhereStr);
end;

function TRptPresupuestosCliente.GenerarInformeListadoPresupuestos(
  const IdEmpresa: Integer; const FechaInicio, FechaFin: Variant;
  const ListaIDClientes: TIntegerArray; const Desglosado: Boolean;
  const ImporteMinimo: Currency): Binary;
var
  ATipoInforme: String;
  AStream: TMemoryStream;
  dsMaster: IDADataset;

begin
  FConnection.BeginTransaction; //<--- Creo que no va a hacer falta. "PUES SI ES NECESARIO"

  AStream := TMemoryStream.Create;
  try
    //Inicializamos parametros
    FIdEmpresa := IdEmpresa;
    FFechaInicio := FechaInicio;
    FFechaFin := FechaFin;
    FImporteMinimo := ImporteMinimo;

    if Assigned(FListaIDClientes) then
       FListaIDClientes.Free;
    FListaIDClientes := ListaIDClientes;

    if tbl_InformeListadoPresupuestos.Active then
       tbl_InformeListadoPresupuestos.Active := False;
    PrepararTablaInforme(tbl_InformeListadoPresupuestos);

    //Se prepara la tabla del listado resumen del informe
    if tbl_InformeListadoPresupuestosResumen.Active then
       tbl_InformeListadoPresupuestosResumen.Active := False;
    dsMaster := schReport.NewDataset(FConnection, ds_InformeListadoPresupuestosResumen, [], [], False);
    PrepararTablaResumenInforme(dsMaster);
    //Esto se hace para rellenar la tabla del datamodule que usa el informe.
    dsMaster.Open;
    AStream.Clear;
    DABin2DataStreamer1.WriteDataset(AStream, dsMaster, [woRows, woSchema], -1);
    DABin2DataStreamer1.ReadDataset(AStream, tbl_InformeListadoPresupuestosResumen, TRUE, '', TRUE, TRUE);

    //DESGLOSADO POR CLIENTE EN ESTE INFORME NO SE DESGLOSAR<41> POR CLIENTE
    if Desglosado then
       ATipoInforme := rptInformeListadoPresupuestosDesglosado
    else
       ATipoInforme := rptInformeListadoPresupuestos;

    //Finalmente se abren las tablas del informe
    tbl_InformeListadoPresupuestos.Active := True;
    tbl_InformeListadoPresupuestosResumen.Active := True;

    Result := _GenerarInforme(ATipoInforme);

  finally
    AStream.Free;
    dsMaster := Nil;
    FConnection.RollbackTransaction; //<--- Creo que no va a hacer falta. "PUES SI ES NECESARIO"
  end;
end;

function TRptPresupuestosCliente.GenerarPresupuesto(const ListaID: TIntegerArray): Binary;
var
  i: Integer;
begin
  Result := Binary.Create;
  try
    //Vamos generando todos y cada uno de los presupuestos recibidos
    for i := 0 to ListaID.Count - 1 do
        _GenerarPresupuesto(ListaID.Items[i]);

    frxReport.PreviewPages.SaveToStream(Result);
  finally
  end;
end;

function TRptPresupuestosCliente._GenerarInforme(const TipoInforme: String): Binary;
var
  AInforme: Variant;

begin
  Result := Binary.Create;
  AInforme := DarRutaFichero(DarRutaInformes, TipoInforme, IntToStr(FIdEmpresa));
  if VarIsNull(AInforme) then
     raise Exception.Create (('Error Servidor: _GenerarInforme, no encuentra informe ' + TipoInforme));

  frxReport.LoadFromFile(AInforme, True);
  frxReport.Variables.Variables['FechaInicio'] := FFechaInicio;
  frxReport.Variables.Variables['FechaFin'] := FFechaFin;

  frxReport.PrepareReport(False);
  frxReport.PreviewPages.SaveToStream(Result);
end;

procedure TRptPresupuestosCliente._GenerarPresupuesto(const AID: Integer);
var
  AInforme: Variant;
begin
  FConnection.BeginTransaction; //<--- Creo que no va a hacer falta. "PUES SI ES NECESARIO"
  try
    tbl_Cabecera.Active := False;
    tbl_Capitulos.Active := False;
    tbl_Detalles.Active := False;
    tbl_Resumen.Active := False;

    tbl_Cabecera.ParamByName('ID').AsInteger := AID;
    tbl_Capitulos.ParamByName('ID_PRESUPUESTO').AsInteger := AID;
    tbl_Detalles.ParamByName('ID_PRESUPUESTO').AsInteger := AID;
    tbl_Resumen.ParamByName('ID_PRESUPUESTO').AsInteger := AID;

    tbl_Cabecera.Active := True;
    tbl_Capitulos.Active := True;
    tbl_Detalles.Active := True;
    tbl_Resumen.Active := True;

    AInforme := DarRutaFichero(DarRutaInformes, rptInforme, tbl_Cabecera.FieldByName('ID_EMPRESA').AsString);
    if VarIsNull(AInforme) then
       raise Exception.Create (('Error Servidor: _GenerarPresupuesto, no encuentra informe ' + rptInforme));

    frxReport.LoadFromFile(AInforme, True);
    frxReport.PrepareReport(False);
  finally
    FConnection.RollbackTransaction; //<--- Creo que no va a hacer falta. "PUES SI ES NECESARIO"
  end;
end;

end.