Tecsitel_FactuGES2/Source/Modulos/Albaranes de proveedor/Model/uBizAlbaranProveedorServer.PAS

unit uBizAlbaranProveedorServer;

interface

uses
  schFacturasClienteServer_Intf, uDAInterfaces, uDADelta,
  uDADataTable, uDABusinessProcessor;

const
  BIZ_SERVER_ALBARAN_PROVEEDOR = 'Server.AlbaranProveedor';

type
  TBizAlbaranProveedorServer = class(TFacturasClienteBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Dialogs, SysUtils, Variants, uDataModuleServer, uDAClasses, 
  schAlbaranesProveedorClient_Intf, uBusinessUtils, uROClasses,
  srvReferencias_Impl;

const
  REF_ALBARANES_PROVEEDOR = 'REF_ALBARANES_PROVEEDOR';
  REF_ALBARANES_DEV_PROVEEDOR = 'REF_ALBARANES_DEV_PROVEEDOR';


{ TBizFacturasClienteServer }

procedure TBizAlbaranProveedorServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;
  { Por defecto, no es necesario mantener los deltas una vez
    procesados los cambios. }
  CanRemoveFromDelta := True;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                            { En este caso no debemos quitar los deltas porque
                              el cliente tiene que enterarse de la referencia que
                              ha rellenado el servidor. }
                            CanRemoveFromDelta := False;
                          end;
                        end;
  end;
end;

procedure TBizAlbaranProveedorServer.BeforeProcessDelta(Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizAlbaranProveedorServer.DarReferencia: String;
var
  ACodigoReferencia : String;
begin
  if (IMPORTE_TOTAL < 0) then
    ACodigoReferencia := REF_ALBARANES_DEV_PROVEEDOR
  else
    ACodigoReferencia := REF_ALBARANES_PROVEEDOR;

  with TsrvReferencias.Create(NIL) do
    try
      Result := DarNuevaReferencia(ACodigoReferencia, ID_EMPRESA)
    finally
      Free;
    end;
end;

function TBizAlbaranProveedorServer.IncrementarReferencia: Boolean;
var
  ACodigoReferencia : String;
begin
  if (IMPORTE_TOTAL < 0) then
    ACodigoReferencia := REF_ALBARANES_DEV_PROVEEDOR
  else
    ACodigoReferencia := REF_ALBARANES_PROVEEDOR;

  with TsrvReferencias.Create(NIL) do
    try
      Result := IncrementarValorReferencia(ACodigoReferencia,
        Self.REFERENCIA, ID_EMPRESA)
    finally
      Free;
    end;
end;

initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_ALBARAN_PROVEEDOR, TBizAlbaranProveedorServer);

end.