Tecsitel_FactuGES2/Source/Modulos/Facturas de proveedor/Model/uBizFacturasProveedorServer.pas

unit uBizFacturasProveedorServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schFacturasProveedorServer_Intf;

const
  BIZ_SERVER_FACTURAS_PROVEEDOR = 'Server.FacturasProveedor';


type
  TBizFacturasProveedorServer = class(TFacturasProveedorBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schFacturasProveedorClient_Intf, srvReferencias_Impl;

const
  REF_FACTURAS_PROVEEDOR = 'REF_FACTURAS_PROVEEDOR';
  REF_ABONOS_PROVEEDOR = 'REF_ABONOS_PROVEEDOR';
  CTE_TIPO_ABONO = 'A';
  CTE_TIPO_FACTURA = 'F';


{ TBizFacturasProveedorServer }

procedure TBizFacturasProveedorServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;
  { Por defecto, no es necesario mantener los deltas una vez
    procesados los cambios. }
  CanRemoveFromDelta := True;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                            { En este caso no debemos quitar los deltas porque
                              el cliente tiene que enterarse de la referencia que
                              ha rellenado el servidor. }
                            CanRemoveFromDelta := False;
                          end;
                        end;
  end;
end;

procedure TBizFacturasProveedorServer.BeforeProcessDelta(Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizFacturasProveedorServer.DarReferencia: String;
var
  ATipo : String;
begin
  if TIPO = CTE_TIPO_FACTURA then
    ATipo := REF_FACTURAS_PROVEEDOR
  else
    ATipo := REF_ABONOS_PROVEEDOR;

  with TsrvReferencias.Create(NIL) do
    try
      Result := DarNuevaReferencia(ATipo, ID_EMPRESA)
    finally
      Free;
    end;
end;

function TBizFacturasProveedorServer.IncrementarReferencia: Boolean;
var
  ATipo : String;
begin
  if TIPO = CTE_TIPO_FACTURA then
    ATipo := REF_FACTURAS_PROVEEDOR
  else
    ATipo := REF_ABONOS_PROVEEDOR;

  with TsrvReferencias.Create(NIL) do
    try
      Result := IncrementarValorReferencia(ATipo,
        Self.REFERENCIA, ID_EMPRESA)
    finally
      Free;
    end;
end;

initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_FACTURAS_PROVEEDOR, TBizFacturasProveedorServer);

end.