Tecsitel_FactuGES2/Source/Modulos/Pedidos a proveedor/Model/uBizPedidosProveedorServer.pas

unit uBizPedidosProveedorServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schPedidosProveedorServer_Intf;

const
  BIZ_SERVER_PEDIDOS_PROVEEDOR = 'Server.PedidosProveedor';

type
  TBizPedidosProveedorServer = class(TPedidosProveedorBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schPedidosProveedorClient_Intf, srvReferencias_Impl;

const
  REF_PEDIDOS_PROVEEDOR = 'REF_PEDIDOS_PROVEEDOR';


{ TBizPedidosProveedorServer }

procedure TBizPedidosProveedorServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;
  { Por defecto, no es necesario mantener los deltas una vez
    procesados los cambios. }
  CanRemoveFromDelta := True;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                            { En este caso no debemos quitar los deltas porque
                              el cliente tiene que enterarse de la referencia que
                              ha rellenado el servidor. }
                            CanRemoveFromDelta := False;
                          end;
                        end;
  end;
end;

procedure TBizPedidosProveedorServer.BeforeProcessDelta(
  Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizPedidosProveedorServer.DarReferencia: String;
begin
  with TsrvReferencias.Create(NIL) do
    try
      Result := DarNuevaReferencia(REF_PEDIDOS_PROVEEDOR, ID_EMPRESA)
    finally
      Free;
    end;
end;

function TBizPedidosProveedorServer.IncrementarReferencia: Boolean;
begin
  with TsrvReferencias.Create(NIL) do
    try
      Result := IncrementarValorReferencia(REF_PEDIDOS_PROVEEDOR,
        Self.REFERENCIA, ID_EMPRESA)
    finally
      Free;
    end;
end;

initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_PEDIDOS_PROVEEDOR, TBizPedidosProveedorServer);

end.