Tecsitel_FactuGES2/Source/Modulos/Albaranes de cliente/Model/uBizAlbaranClienteServer.pas

unit uBizAlbaranClienteServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schAlbaranesClienteServer_Intf;

const
  BIZ_SERVER_ALBARAN_CLIENTE = 'Server.AlbaranCliente';

  CTE_TIPO_ALBARAN = 'A';
  CTE_TIPO_ALBARAN_DEV = 'D';

type
  TBizAlbaranClienteServer = class(TAlbaranesClienteBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schAlbaranesClienteClient_Intf, FactuGES_Intf, uROServer, SysUtils, JclStrings;

const
  REF_ALBARANES_CLIENTE = 'REF_ALBARANES_CLIENTE';
  REF_ALBARANES_DEV_CLIENTE = 'REF_ALBARANES_DEV_CLIENTE';

{ TBizAlbaranClienteServer }

procedure TBizAlbaranClienteServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;
  { Por defecto, mantenemos los deltas por si alguna tabla hija los necesita }
  CanRemoveFromDelta := False;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                          end;
                        end;
  end;
end;

procedure TBizAlbaranClienteServer.BeforeProcessDelta(Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  inherited;

  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizAlbaranClienteServer.DarReferencia: String;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
  ACodigoReferencia : String;
begin
  if (TIPO = CTE_TIPO_ALBARAN_DEV) then
    ACodigoReferencia := REF_ALBARANES_DEV_CLIENTE
  else
    ACodigoReferencia := REF_ALBARANES_CLIENTE;

  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.DarNuevaReferencia(ACodigoReferencia, ID_EMPRESA)
end;

function TBizAlbaranClienteServer.IncrementarReferencia: Boolean;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
  ACodigoReferencia : String;
begin
  if (TIPO = CTE_TIPO_ALBARAN_DEV) then
    ACodigoReferencia := REF_ALBARANES_DEV_CLIENTE
  else
    ACodigoReferencia := REF_ALBARANES_CLIENTE;

  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.IncrementarValorReferencia(ACodigoReferencia, Self.REFERENCIA, ID_EMPRESA)
end;


initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_ALBARAN_CLIENTE, TBizAlbaranClienteServer);

end.