Tecsitel_FactuGES2/Source/Modulos/Presupuestos de cliente/Controller/uDetallesPresupuestoClienteController.pas

unit uDetallesPresupuestoClienteController;

interface

uses
  uDADataTable, uControllerDetallesBase, uControllerDetallesArticulos, uBizDetallesPresupuestoCliente, uIDataModulePresupuestosCliente,
  uBizArticulos, uBizContactos;

type
  IDetallesPresupuestoClienteController = interface(IControllerDetallesArticulos)
  ['{8D1D3559-E695-4962-9999-404B26B50D6C}']
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean = True); overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente); overload;
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
    function VariarPrecios(var APorcentaje: Variant; var ATipoOperacion: Integer): Boolean;
    procedure AplicarAumento(ADataTable: IDAStronglyTypedDataTable; Posicion: TIntegerArray; APorcentaje: Variant);    
  end;

  TDetallesPresupuestoClienteController = class(TControllerDetallesArticulos, IDetallesPresupuestoClienteController)
  private
    FDataModule : IDataModulePresupuestosCliente;
    function CreateEditor(const AName : String; const IID: TGUID; out Intf): Boolean;

  protected
//    procedure AsignarDatos(ADetalles: IDAStronglyTypedDataTable; IDCabecera: Integer); override;
    procedure RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); overload; override;
    procedure RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo); override;

    procedure AsignarController; override;
    //Si sobreescribimos este método podremos tener en cuenta otras columnas para el calculo del importe total de un concepto
    function CalcularImporteTotalConcepto(DataTable: TDADataTable): Double; override;
    procedure ValidarCampos(DataTable: TDADataTable); override;
    procedure DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
    function DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;

  public
    function VariarPrecios(var APorcentaje: Variant; var ATipoOperacion: Integer): Boolean;
    procedure AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean = True); reintroduce; overload;
    procedure ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente); overload;
    procedure AplicarAumento(ADataTable: IDAStronglyTypedDataTable; Posicion: TIntegerArray; APorcentaje: Variant);
    constructor Create; override;
    destructor Destroy; override;
  end;

implementation

uses Controls, SysUtils, Dialogs, uDAInterfaces, uDialogUtils, Variants, uDataModulePresupuestosCliente, uArticulosPresupuestoClienteController,
     uDataTableUtils, uCalculosUtils, uIEditorVariarPrecios, uEditorRegistryUtils;

{ TDetallesPresupuestoClienteController }

procedure TDetallesPresupuestoClienteController.ActualizarDetalles(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente);
var
  AArticulos : IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos(ACliente) as IBizArticulo);
      ActualizarDetalles(ADetalles, AArticulos);
      ShowInfoMessage('Se ha actualizado el descuento para el cliente seleccionado');
    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesPresupuestoClienteController.AnadirArticulos(ADetalles: IDAStronglyTypedDataTable; ACliente: IBizCliente; const ANuevaFila :Boolean);
var
  AArticulos: IBizArticulo;
begin
  if Assigned(ADetalles) then
  begin
    try
      AArticulos := (FArticulosController.BuscarTodos(ACliente) as IBizArticulo);

      //Si nueva fila es false, quiere decir que se sustituye un determinado artículo, por ello la lista a seleccionar no debe ser multiselect
      if ANuevaFila then
      begin
        AArticulos := (FArticulosController as IArticulosPresupuestoClienteController).ElegirArticulos(AArticulos, 'Elija los artículos que desea añadir a este presupuesto de cliente', True);
        Add(ADetalles, AArticulos)
      end
      else
      begin
        AArticulos := (FArticulosController as IArticulosPresupuestoClienteController).ElegirArticulos(AArticulos, 'Elija el artículo que desea añadir a este presupuesto de cliente', False);
        RellenarDetalle(ADetalles, AArticulos);
      end;

    finally
      AArticulos := Nil;
    end;
  end;
end;

procedure TDetallesPresupuestoClienteController.AplicarAumento(ADataTable: IDAStronglyTypedDataTable; Posicion: TIntegerArray;
  APorcentaje: Variant);
var
  i: integer;
  AField: TDAField;
  AsignarDtoPosicion: Integer;

begin
  if APorcentaje > 0 then
  begin
    AsignarDtoPosicion := 0;
    AField := ADataTable.DataTable.FindField(CAMPO_POSICION);
    if not Assigned(AField) then
       raise Exception.Create('Campo ' + CAMPO_POSICION + ' no encontrado (AsignarDescuento)');

    BeginUpdate(ADataTable);
    try
      with ADataTable do
      begin
        for i := 0 to High(POSICION) do
        begin
          DataTable.First;
          AsignarDtoPosicion := POSICION[i];
          if DataTable.Locate(CAMPO_POSICION, AsignarDtoPosicion, []) then
          begin
             if (DataTable.FieldByName(CAMPO_TIPO).AsString = TIPO_DETALLE_CONCEPTO) then
             begin
               DataTable.Edit;
               DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := (DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant * (APorcentaje/100)) + DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant;
               DataTable.Post;
             end;
          end;
        end;
        Renumerar(DataTable, AsignarDtoPosicion);
      end;
    finally
      EndUpdate(ADataTable);
    end;
  end;
end;

procedure TDetallesPresupuestoClienteController.AsignarController;
begin
  FArticulosController := TArticulosPresupuestoClienteController.Create;
end;

{
procedure TDetallesPresupuestoClienteController.AsignarDatos(ADetalles: IDAStronglyTypedDataTable; IDCabecera: Integer);
begin
  inherited;

  with (ADetalles as IBizDetallesPresupuestoCliente) do
  begin
    Edit;
    ID := FDataModule.GetNextID(DataTable.LogicalName);
    ID_PEDIDO := IDCabecera;
    Post
  end;
end;
}

function TDetallesPresupuestoClienteController.CalcularImporteTotalConcepto(DataTable: TDADataTable): Double;
begin
  Result := CalcularLineaConcepto(DataTable);
end;

constructor TDetallesPresupuestoClienteController.Create;
begin
  inherited;
  FDataModule := TDataModulePresupuestosCliente.Create(Nil);
end;

function TDetallesPresupuestoClienteController.CreateEditor(const AName: String; const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;

function TDetallesPresupuestoClienteController.DarTotalPorteTotal(ADetalles: IDAStronglyTypedDataTable): Double;
begin
  Result := DarTotalPorte(ADetalles);
end;

procedure TDetallesPresupuestoClienteController.DesglosarPorteDetalles(ImportePorte: Currency; ADetalles: IDAStronglyTypedDataTable);
begin
  DesglosarPorte(ImportePorte, ADetalles);
  ActualizarTotales(ADetalles);
end;

destructor TDetallesPresupuestoClienteController.Destroy;
begin
  FDataModule := Nil;
  inherited;
end;

procedure TDetallesPresupuestoClienteController.RellenarOtros(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
begin
//En Tecsitel no se tiene en cuenta el descuento de cliente para el precio PVP
//  if Assigned(AArticulos) then
//    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := AArticulos.DESCUENTO
//  else
//    ADetalles.DataTable.FieldByName(CAMPO_DESCUENTO).AsFloat := 0;
end;

procedure TDetallesPresupuestoClienteController.ValidarCampos(DataTable: TDADataTable);
begin
  inherited;
  ValidarCamposLineaConcepto(DataTable);
end;

function TDetallesPresupuestoClienteController.VariarPrecios(var APorcentaje: Variant; var ATipoOperacion: Integer): Boolean;
var
  AEditor: IEditorVariarPrecios;

begin
  Result := False;

  CreateEditor('EditorVariarPrecios', IEditorVariarPrecios, AEditor);
  if Assigned(AEditor) then
       try
         if (AEditor.ShowModal = mrOk) then
         begin
            APorcentaje := AEditor.Porcentaje;
            ATipoOperacion := AEditor.TipoOperacion;
            Result := True;
         end;
       finally
         AEditor.Release;
         AEditor := NIL;
       end;
end;

procedure TDetallesPresupuestoClienteController.RellenarImportes(ADetalles: IDAStronglyTypedDataTable; AArticulos: IBizArticulo);
begin
//Como en tecsitel no hay descuento por linea de detalle, solo recuperamos nuevamente el valor del articulo cuando el detalle no tenga niguno
//de esta forma evitamos que al cambiar de cliente se quiten los importes que se hubiesen establecido para los articulos.
  if ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).IsNull then
     if Assigned(AArticulos) then
       ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := AArticulos.PRECIO_PVP_TOTAL
     else
       ADetalles.DataTable.FieldByName(CAMPO_IMPORTE_UNIDAD).AsVariant := Null;
end;

end.