Tecsitel_FactuGES2/Source/Modulos/Remesas de proveedor/Model/uBizRemesasProveedorServer.pas

unit uBizRemesasProveedorServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schRemesasProveedorServer_Intf;

const
  BIZ_SERVER_REMESAS_Proveedor = 'Server.RemesasProveedor';


type
  TBizRemesasProveedorServer = class(TRemesasProveedorBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schRemesasProveedorClient_Intf, srvReferencias_Impl;

const
  REF_REMESAS_PROVEEDOR = 'REF_REMESAS_PROVEEDOR';

{ TBizRemesasProveedorServer }

procedure TBizRemesasProveedorServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;

  { Por defecto, mantenemos los deltas por si alguna tabla hija los necesita }
  CanRemoveFromDelta := False;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                          end;
                        end;
  end;
end;

procedure TBizRemesasProveedorServer.BeforeProcessDelta(
  Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizRemesasProveedorServer.DarReferencia: String;
begin
  with TsrvReferencias.Create(NIL) do
    try
      Result := DarNuevaReferencia(REF_REMESAS_PROVEEDOR, ID_EMPRESA)
    finally
      Free;
    end;
end;

function TBizRemesasProveedorServer.IncrementarReferencia: Boolean;
begin
  with TsrvReferencias.Create(NIL) do
    try
      Result := IncrementarValorReferencia(REF_REMESAS_PROVEEDOR,
        Self.REFERENCIA, ID_EMPRESA)
    finally
      Free;
    end;
end;

initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_REMESAS_Proveedor, TBizRemesasProveedorServer);

end.