AbetoDesign_FactuGES2/Source/Modulos/Albaranes de proveedor/Data/uDataModuleAlbaranesProveedor.pas

unit uDataModuleAlbaranesProveedor;

interface

uses
  DB, Classes, SysUtils, uDADesigntimeCall, 
  uRORemoteService, uROClient, uROBinMessage, uDAScriptingProvider,
  uDACDSDataTable, uROWinInetHttpChannel, uDADataTable, uDABINAdapter,
  uDAClientDataModule, uROTypes, uIDataModuleAlbaranesProveedorReport, uDataModuleBase,
  uIDataModuleAlbaranesProveedor, uBizAlbaranesProveedor, uBizDetallesAlbaranProveedor,
  uDARemoteDataAdapter, uDADataStreamer, uDABin2DataStreamer, uDAInterfaces,
  uDAMemDataTable;

type
  TDataModuleAlbaranesProveedor = class(TDataModuleBase, IDataModuleAlbaranesProveedor, IDataModuleAlbaranesProveedorReport)
    RORemoteService: TRORemoteService;
    Bin2DataStreamer: TDABin2DataStreamer;
    rda_AlbaranesProveedor: TDARemoteDataAdapter;
    tbl_AlbaranesProveedor: TDAMemDataTable;
    ds_AlbaranesProveedor: TDADataSource;
    tbl_AlbaranesProveedor_Detalles: TDAMemDataTable;
    ds_AlbaranesProveedor_Detalles: TDADataSource;
    tbl_ListaAnosAlbaranes: TDAMemDataTable;
    ds_ListaAnosAlbaranes: TDADataSource;
    tbl_AlbaranesProveedorConArticuloBuscado: TDAMemDataTable;
    ds_AlbaranesProveedorConArticuloBuscado: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);

  private
    function _GetDetalles : IBizDetallesAlbaranProveedor;

  protected
    procedure AsignarClaseNegocio(var APedido: TDAMemDataTable); virtual;

  public
    function GetAnosItems : TStringList;  
    function GetItems : IBizAlbaranProveedor; virtual;
    function GetItem(const ID : Integer) : IBizAlbaranProveedor;
    function NewItem : IBizAlbaranProveedor;
    function GetAlbaranesConArticulo(const Concepto: String; const isEqual: Boolean = false): IBizAlbaranProveedor;

    // Report
    function GetReport(const AID: String): Binary;
  end;

implementation

{$R *.DFM}

uses
  cxControls, FactuGES_Intf, uDataModuleConexion,
  uDataTableUtils, schAlbaranesProveedorClient_Intf, uBizContactos;

{ TdmAlbaranesProveedor }

procedure TDataModuleAlbaranesProveedor.AsignarClaseNegocio(var APedido: TDAMemDataTable);
begin
  APedido.BusinessRulesID := BIZ_CLIENT_ALBARAN_PROVEEDOR;
end;

procedure TDataModuleAlbaranesProveedor.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModuleAlbaranesProveedor.GetReport(const AID: String): Binary;
begin
  Result := (RORemoteService as IsrvAlbaranesProveedor).GenerateReport(AID)
end;

function TDataModuleAlbaranesProveedor.NewItem: IBizAlbaranProveedor;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModuleAlbaranesProveedor._GetDetalles: IBizDetallesAlbaranProveedor;
var
  ADetalles : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    ADetalles := CloneDataTable(tbl_AlbaranesProveedor_Detalles);
    with ADetalles do
    begin
      BusinessRulesID := BIZ_CLIENT_DETALLES_ALBARAN_PROVEEDOR;
      DetailOptions := DetailOptions - [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (ADetalles as IBizDetallesAlbaranProveedor);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleAlbaranesProveedor.GetAlbaranesConArticulo(const Concepto: String; const isEqual: Boolean): IBizAlbaranProveedor;
var
  AAlbaranes : TDAMemDataTable;
  Condicion, Filtro: TDAWhereExpression;
  ACadena: String;
  Campos     : array[0..0] of string;
  I          : Integer;
begin
  ShowHourglassCursor;
  try
    // Convertimos el texto a MAY<41>SCULAS para compararlo con campos tambi<62>n en MAY<41>SCULAS
    ACadena := '%' + UpperCase(Concepto) + '%';

    Campos[0] := fld_AlbaranesProveedorCONCEPTO_BUSQUEDA;

    AAlbaranes := CloneDataTable(tbl_AlbaranesProveedorConArticuloBuscado);
    AAlbaranes.BusinessRulesID := BIZ_CLIENT_ALBARAN_PROVEEDOR;

    with AAlbaranes.DynamicWhere do
    begin

       Filtro := nil;
      for I := Low(Campos) to High(Campos) do
      begin
          Condicion := NewBinaryExpression(
            NewField('', Campos[I]),
            NewConstant(ACadena, datString),
            dboLike
          );

        if Filtro = nil then
          Filtro := Condicion
        else
          Filtro := NewBinaryExpression(Filtro, Condicion, dboOr);
      end;

    // Aplicar filtro
      if IsEmpty then
        Expression := Filtro
      else
        Expression := NewBinaryExpression(Expression, Filtro, dboAnd);
    end;

    Result := (AAlbaranes as IBizAlbaranProveedor);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleAlbaranesProveedor.GetAnosItems: TStringList;
var
  AListaAnos: TStringList;
begin
  AListaAnos := TStringList.Create;
  ShowHourglassCursor;
  try
    with tbl_ListaAnosAlbaranes do
    begin
      Open;
      First;
      while not eof do
      begin
        AListaAnos.Add(Format('%s=%s', [Fields[0].AsString, Fields[0].AsString]));
        Next;
      end;
      Close;
    end;
    Result := AListaAnos;
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleAlbaranesProveedor.GetItem(const ID: Integer): IBizAlbaranProveedor;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := Self.GetItems;

    with Result.DataTable.DynamicWhere do
    begin
      // (ID = :ID)
      Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorID), NewConstant(ID, datInteger), dboEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleAlbaranesProveedor.GetItems: IBizAlbaranProveedor;
var
  AAlbaran : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    AAlbaran := CloneDataTable(tbl_AlbaranesProveedor);
    AsignarClaseNegocio(AAlbaran);

    // EL CAMPO REFERENCIA TIENE QUE SER AUTOREFRESH!!!!!
    AAlbaran.FieldByName(fld_AlbaranesProveedorREFERENCIA).ServerAutoRefresh := TRUE;

    with TBizAlbaranProveedor(AAlbaran.BusinessEventsObj) do
    begin
      Detalles := _GetDetalles;
    end;

    Result := (AAlbaran as IBizAlbaranProveedor);
  finally
    HideHourglassCursor;
  end;
end;

end.