AbetoDesign_FactuGES2/Source/Modulos/Articulos/Data/uDataModuleArticulos.pas

unit uDataModuleArticulos;

interface

uses
  SysUtils, Classes, DB, uDADataTable, uDABINAdapter,
  uDAScriptingProvider, uROWinInetHttpChannel, uROTypes,
  uRORemoteService, uROClient, uROBinMessage,
  uDADesigntimeCall,
  uIDataModuleArticulos, uBizArticulos, uDataModuleBase, uDARemoteDataAdapter,
  uDADataStreamer, uDABin2DataStreamer, uDAInterfaces, uDAMemDataTable,
  uBizArticulosProveedores, uBizArticulosIdiomas;

type
  TDataModuleArticulos = class(TDataModuleBase, IDataModuleArticulos)
    RORemoteService: TRORemoteService;
    Bin2DataStreamer: TDABin2DataStreamer;
    rda_Articulos: TDARemoteDataAdapter;
    tbl_Articulos: TDAMemDataTable;
    ds_Articulos: TDADataSource;
    tbl_ArticulosParaCliente: TDAMemDataTable;
    ds_ArticulosParaCliente: TDADataSource;
    tbl_Articulos_Proveedores: TDAMemDataTable;
    ds_Articulos_Proveedores: TDADataSource;
    tbl_ArticulosParaCompra: TDAMemDataTable;
    ds_ArticulosParaCompra: TDADataSource;
    tbl_Articulos_Idiomas: TDAMemDataTable;
    ds_Articulos_Idiomas: TDADataSource;
    tbl_ListaTarifasArticulos: TDAMemDataTable;
    ds_ListaTarifasArticulos: TDADataSource;
    procedure DAClientDataModuleCreate(Sender: TObject);
  private
    function _GetProveedores : IBizArticulosProveedores;
    function _GetIdiomas : IBizArticulosIdiomas;

  protected
    procedure AsignarClaseNegocio(AArticulo: TDADataTable); virtual;

  public
    function GetItems (const Tipo: TEnumArticulos): IBizArticulo; overload;
    function GetItems (IDCliente: Integer) : IBizArticulo; overload;
    function GetItem(const ID : Integer; AClienteID: Integer = -1) : IBizArticulo;
    function NewItem : IBizArticulo;
    function GetTarifasItems : TStringList;
  end;

implementation

{$R *.DFM}

uses
  FactuGES_Intf, uDataModuleConexion, uDataTableUtils, cxControls,
  schArticulosClient_Intf;

{ TdmArticulos }

procedure TDataModuleArticulos.AsignarClaseNegocio(AArticulo: TDADataTable);
begin
  AArticulo.BusinessRulesID := BIZ_CLIENT_ARTICULO;
end;

procedure TDataModuleArticulos.DAClientDataModuleCreate(Sender: TObject);
begin
  RORemoteService.Channel := dmConexion.Channel;
  RORemoteService.Message := dmConexion.Message;
end;

function TDataModuleArticulos.NewItem: IBizArticulo;
begin
  Result := GetItem(ID_NULO)
end;

function TDataModuleArticulos._GetIdiomas: IBizArticulosIdiomas;
var
  AIdiomas : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    AIdiomas := CloneDataTable(tbl_Articulos_Idiomas);
    with AIdiomas do
    begin
      BusinessRulesID := BIZ_CLIENT_ARTICULOS_IDIOMAS;
      DetailOptions := DetailOptions - [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (AIdiomas as IBizArticulosIdiomas);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleArticulos._GetProveedores: IBizArticulosProveedores;
var
  AProveedores : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    AProveedores := CloneDataTable(tbl_Articulos_Proveedores);
    with AProveedores do
    begin
      BusinessRulesID := BIZ_CLIENT_ARTICULOS_PROVEEDORES;
      DetailOptions := DetailOptions - [dtDisableLogOfCascadeDeletes, dtDisableLogOfCascadeUpdates];
    end;
    Result := (AProveedores as IBizArticulosProveedores);
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleArticulos.GetItem(const ID: Integer; AClienteID: Integer = -1): IBizArticulo;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    if (AClienteID = -1) then
      Result := Self.GetItems(txArticulo)
    else
      Result := Self.GetItems(AClienteID);

    with Result.DataTable.DynamicWhere do
    begin
      // (ID = :ID)
      Condicion := NewBinaryExpression(NewField('', fld_ArticulosID), NewConstant(ID, datInteger), dboEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleArticulos.GetItems(IDCliente: Integer): IBizArticulo;
var
  AArticulo : TDAMemDataTable;
begin

  ShowHourglassCursor;
  try
    AArticulo := CloneDataTable(tbl_ArticulosParaCliente);
    AsignarClaseNegocio(AArticulo);

    AArticulo.ParamByName('ID_CLIENTE').AsInteger := IdCliente;

    Result := (AArticulo as IBizArticulo);

  finally
    HideHourglassCursor;
  end;

end;

function TDataModuleArticulos.GetTarifasItems: TStringList;
var
  AListaTarifas: TStringList;
begin
  AListaTarifas := TStringList.Create;
  ShowHourglassCursor;
  try
    with tbl_ListaTarifasArticulos do
    begin
      Open;
      First;
      while not eof do
      begin
        AListaTarifas.Add(Format('%s=%s', [Fields[0].AsString, Fields[0].AsString]));
        Next;
      end;
      Close;
    end;
    Result := AListaTarifas;
  finally
    HideHourglassCursor;
  end;
end;

function TDataModuleArticulos.GetItems (const Tipo: TEnumArticulos): IBizArticulo;
var
  AArticulo : TDAMemDataTable;
begin
  ShowHourglassCursor;
  try
    case Tipo of
      txArticulo: AArticulo := CloneDataTable(tbl_Articulos);
      txProveedor:  AArticulo := CloneDataTable(tbl_ArticulosParaCompra); //En el caso de tener varios proveedores para un mismo art<72>culo
//      txProveedor:  AArticulo := CloneDataTable(tbl_Articulos); //En el caso de tener solo un proveedor por articulo
    end;

    AsignarClaseNegocio(AArticulo);

    case Tipo of
      txArticulo: begin
        TBizArticulo(AArticulo.BusinessEventsObj).Proveedores := _GetProveedores;
        TBizArticulo(AArticulo.BusinessEventsObj).Idiomas := _GetIdiomas;
      end;
    end;

    Result := (AArticulo as IBizArticulo);

  finally
    HideHourglassCursor;
  end;


end;


end.