AbetoDesign_FactuGES2/Source/Modulos/Delegaciones/Views/uEditorDelegaciones.pas

{
===============================================================================
  Copyright (<EFBFBD>) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero s<EFBFBD>lo podr<EFBFBD> ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los t<EFBFBD>rminos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versi<EFBFBD>n: 22-05-2006
  Versi<EFBFBD>n actual: 1.0.0
  Fecha versi<EFBFBD>n actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorDelegaciones;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorDelegaciones, uCustomEditor, uGUIBase, ExtCtrls,
  ComCtrls, uBizDelegaciones, uDelegacionesController, uDAInterfaces;

type
  TfEditorDelegaciones = class(TCustomEditor, IEditorDelegaciones)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaDelegaciones: TDBLookupListBox;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    Label1: TLabel;
    Label2: TLabel;
    Bevel1: TBevel;
    eCategoria: TLabel;
    editDelegacion: TEdit;
    bAnadir: TButton;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FDelegaciones: IBizDelegacion;
    FController: IDelegacionesController;
    function GetDelegaciones: IBizDelegacion;
    procedure SetDelegaciones(const Value: IBizDelegacion);
    function GetController : IDelegacionesController;
    procedure SetController (const Value : IDelegacionesController);
  public
    property Delegaciones: IBizDelegacion read GetDelegaciones write SetDelegaciones;
    property Controller : IDelegacionesController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorDelegaciones }

uses
  uDialogUtils;

function TfEditorDelegaciones.GetController: IDelegacionesController;
begin
  Result := FController;
end;

function TfEditorDelegaciones.GetDelegaciones: IBizDelegacion;
begin
  Result := FDelegaciones;
end;

procedure TfEditorDelegaciones.SetController(const Value: IDelegacionesController);
begin
  FController := Value;
end;

procedure TfEditorDelegaciones.SetDelegaciones(const Value: IBizDelegacion);
begin
  FDelegaciones := Value;
  DADataSource.DataTable := (FDelegaciones as IBizDelegacion).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorDelegaciones.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(Delegaciones, editDelegacion.Text) then
  begin
    Delegaciones.Append;
    Delegaciones.DESCRIPCION := editDelegacion.Text;
    Delegaciones.Post;
    editDelegacion.Clear;
    ListaDelegaciones.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe la unidad ' + editDelegacion.Text,
      'Ya existe la unidad ''' + editDelegacion.Text + ''' en la lista.');
end;

procedure TfEditorDelegaciones.actEliminarExecute(Sender: TObject);
begin
  Delegaciones.Delete;
  ListaDelegaciones.SetFocus;
end;

procedure TfEditorDelegaciones.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FDelegaciones.DataTable.RecordCount > 0) and
                                  (Length(ListaDelegaciones.SelectedItem) > 0);

end;

procedure TfEditorDelegaciones.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FDelegaciones := Nil;
  FController := Nil;
end;

procedure TfEditorDelegaciones.actAceptarExecute(Sender: TObject);
begin
  try
    Delegaciones.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      Delegaciones.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorDelegaciones.actCancelarExecute(Sender: TObject);
begin
  Delegaciones.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorDelegaciones.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorDelegaciones.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editDelegacion.Text) > 0)
end;

procedure TfEditorDelegaciones.FormShow(Sender: TObject);
begin
  if not FDelegaciones.DataTable.Active then
     FDelegaciones.DataTable.Active := true;

  FDelegaciones.DataTable.Sort(['DESCRIPCION'], [sdAscending]);
  EditDelegacion.SetFocus;
end;

end.