AbetoDesign_FactuGES2/Source/Modulos/Albaranes de proveedor/Controller/uAlbaranesProveedorController.pas

unit uAlbaranesProveedorController;

interface


uses
  SysUtils, uDADataTable, uEditorDBItem, Classes,
  uControllerBase, uIDataModuleAlbaranesProveedor, uProveedoresController,
  uDetallesAlbaranProveedorController, uBizAlbaranesProveedor,
  uBizDireccionesContacto, uBizInventario,
  uBizPedidosProveedor;

type
  IAlbaranesProveedorController = interface(IControllerBase)
  ['{E2FA2312-EDBD-4E80-B3D7-A8784F6A4E39}']
    function GetProveedorController: IProveedoresController;
    procedure SetProveedorController(const Value: IProveedoresController);
    property ProveedorController: IProveedoresController read GetProveedorController write SetProveedorController;

    function GetDetallesController: IDetallesAlbaranProveedorController;
    procedure SetDetallesController(const Value: IDetallesAlbaranProveedorController);
    property DetallesController: IDetallesAlbaranProveedorController read GetDetallesController write SetDetallesController;

    function Buscar(const ID: Integer): IBizAlbaranProveedor;
    function BuscarTodos: IBizAlbaranProveedor;
    function BuscarAlbaranesNormales: IBizAlbaranProveedor;
    function BuscarAlbaranesDevolucion: IBizAlbaranProveedor;
    function BuscarSinFacturar : IBizAlbaranProveedor;
    procedure Ver(AAlbaran : IBizAlbaranProveedor);
    procedure VerTodosAlbaranes(AAlbarans: IBizAlbaranProveedor);
    procedure VerTodosAlbaranesDev(AAlbarans: IBizAlbaranProveedor);
    procedure VerDireccionEntrega(AAlbaran : IBizAlbaranProveedor);
    function Nuevo (WithInsert: Boolean = True): IBizAlbaranProveedor;
    function Anadir(AAlbaran : IBizAlbaranProveedor) : Boolean; overload;
    function AnadirAlbaranDev(AAlbaran : IBizAlbaranProveedor) : Boolean;
    function Anadir(AAlbaran : IBizAlbaranProveedor; const IDPedido : Integer; AInventarioRecibido: IBizInventario): Boolean; overload;
    function Anadir(AAlbaranes : IBizAlbaranProveedor; AListaPedidos : IBizPedidoProveedor): Boolean; overload;    

    function Eliminar(const ID : Integer): Boolean; overload;
    function Eliminar(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false): Boolean; overload;
    function Guardar(AAlbaran : IBizAlbaranProveedor): Boolean;
    procedure DescartarCambios(AAlbaran : IBizAlbaranProveedor);
    function Existe(const ID: Integer) : Boolean;
    function Duplicar(AAlbaran: IBizAlbaranProveedor): IBizAlbaranProveedor;

    function ExtraerSeleccionados(AAlbaran: IBizAlbaranProveedor) : IBizAlbaranProveedor;
    function ElegirAlbaranes(AAlbaran: IBizAlbaranProveedor; AMensaje: String; AMultiSelect: Boolean): IBizAlbaranProveedor;

    procedure CopiarDireccionEnvio (const ADireccionEnvio: IBizDireccionesContacto; AAlbaran: IBizAlbaranProveedor);
    procedure QuitarDireccionEnvio(AAlbaran: IBizAlbaranProveedor);
    procedure RecuperarProveedor(AAlbaran: IBizAlbaranProveedor);

    procedure RecalcularImportes(AAlbaran: IBizAlbaranProveedor);
    function EsModificable(AAlbaran: IBizAlbaranProveedor): Boolean;
    function EsEliminable(AAlbaran: IBizAlbaranProveedor): Boolean;

    procedure Preview(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false);
    procedure Print(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false);

    function DarListaAnosAlbaranes: TStringList;
    procedure FiltrarAno(AAlbaran: IBizAlbaranProveedor; ADynWhereDataTable: WideString; const Ano: String);

  end;

  TAlbaranesProveedorController = class(TControllerBase, IAlbaranesProveedorController)
  protected
    FDataModule : IDataModuleAlbaranesProveedor;
    FProveedorController : IProveedoresController;
    FDetallesController : IDetallesAlbaranProveedorController;

    function GetProveedorController: IProveedoresController;
    procedure SetProveedorController(const Value: IProveedoresController);
    procedure RecuperarProveedor(AAlbaran : IBizAlbaranProveedor);
    function GetDetallesController: IDetallesAlbaranProveedorController;
    procedure SetDetallesController(const Value: IDetallesAlbaranProveedorController);

    //Estos son los tres m<>todos a sobre escribir si se desea heredar toda la logica de
    //este controller
    procedure AsignarDataModule; virtual;
    procedure RecuperarObjetos(AAlbaran: IBizAlbaranProveedor); virtual;

    procedure RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable); override;
    function CreateEditor(const AName : String; const IID: TGUID; out Intf): Boolean;
    procedure FiltrarEmpresa(AAlbaran: IBizAlbaranProveedor);
    function _Vacio : IBizAlbaranProveedor;
    function ValidarAlbaran(AAlbaran: IBizAlbaranProveedor): Boolean;

  public
    property ProveedorController: IProveedoresController read GetProveedorController write SetProveedorController;
    property DetallesController: IDetallesAlbaranProveedorController read GetDetallesController write SetDetallesController;

    constructor Create; override;
    destructor Destroy; override;

    function Eliminar(const ID : Integer): Boolean; overload;
    function Eliminar(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false): Boolean; overload;
    function Guardar(AAlbaran : IBizAlbaranProveedor): Boolean;
    procedure DescartarCambios(AAlbaran : IBizAlbaranProveedor); virtual;
    function Existe(const ID: Integer) : Boolean; virtual;
    function Anadir(AAlbaran : IBizAlbaranProveedor) : Boolean; overload;
    function AnadirAlbaranDev(AAlbaran : IBizAlbaranProveedor) : Boolean;
    function Anadir(AAlbaran : IBizAlbaranProveedor; const IDPedido : Integer; AInventarioRecibido: IBizInventario): Boolean; overload;
    function Anadir(AAlbaranes : IBizAlbaranProveedor; AListaPedidos : IBizPedidoProveedor): Boolean; overload;

    function Buscar(const ID: Integer): IBizAlbaranProveedor;
    function BuscarTodos: IBizAlbaranProveedor;
    function BuscarAlbaranesNormales: IBizAlbaranProveedor;
    function BuscarAlbaranesDevolucion: IBizAlbaranProveedor;
    function BuscarSinFacturar : IBizAlbaranProveedor;
    function Nuevo (WithInsert: Boolean = True): IBizAlbaranProveedor;
    procedure Ver(AAlbaran : IBizAlbaranProveedor);
    procedure VerTodosAlbaranes(AAlbarans: IBizAlbaranProveedor);
    procedure VerTodosAlbaranesDev(AAlbarans: IBizAlbaranProveedor);
    procedure VerDireccionEntrega(AAlbaran : IBizAlbaranProveedor);
    function Duplicar(AAlbaran: IBizAlbaranProveedor): IBizAlbaranProveedor;
    procedure CopiarDireccionEnvio (const ADireccionEnvio: IBizDireccionesContacto; AAlbaran: IBizAlbaranProveedor);

    procedure QuitarDireccionEnvio(AAlbaran: IBizAlbaranProveedor);
    function ExtraerSeleccionados(AAlbaran: IBizAlbaranProveedor) : IBizAlbaranProveedor;
    function ElegirAlbaranes(AAlbaran: IBizAlbaranProveedor; AMensaje: String; AMultiSelect: Boolean): IBizAlbaranProveedor;

    procedure RecalcularImportes(AAlbaran: IBizAlbaranProveedor);
    function EsModificable(AAlbaran: IBizAlbaranProveedor): Boolean;
    function EsEliminable(AAlbaran: IBizAlbaranProveedor): Boolean;

    procedure Preview(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false);
    procedure Print(AAlbaran : IBizAlbaranProveedor; AllItems: Boolean = false);

    function DarListaAnosAlbaranes: TStringList;
    procedure FiltrarAno(AAlbaran: IBizAlbaranProveedor; ADynWhereDataTable: WideString; const Ano: String);

  end;

implementation
{$INCLUDE ..\..\FactuGES.inc}

uses
  uROTypes, Controls, cxControls, DB, uEditorRegistryUtils, uEditorPreview, DateUtils,
  uIEditorAlbaranesProveedor, uIEditorAlbaranesDevProveedor, uDataModuleAlbaranesProveedor,
  uBizDetallesAlbaranProveedor, uBizContactos, uDataTableUtils, uDataModuleUsuarios,
  schAlbaranesProveedorClient_Intf, uDAInterfaces, uDateUtils, uIEditorAlbaranProveedor,
  uIEditorElegirAlbaranesProveedor, uIEditorDireccionEntregaAlbaranProveedor,
  schContactosClient_Intf, Forms,  schPedidosProveedorClient_Intf, uFactuGES_App,
  uPedidosProveedorController, uBizDetallesPedidoProveedor,
  uArticulosController, uBizArticulos, uControllerDetallesBase,
  schArticulosClient_Intf, uControllerDetallesArticulos, Variants, uDialogUtils,
  uIEditorAlbaranDevProveedor, uAlbaranesProveedorReportController,
  schInventarioClient_Intf;


{ M<>todos auxiliares }
procedure CopiarPedidoAAlbaran(APedido: IBizPedidoProveedor;
  AAlbaran : IBizAlbaranProveedor);
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (CopiarPedidoAAlbaran)');

  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignado (CopiarPedidoAAlbaran)');

  if not APedido.DataTable.Active then
    APedido.DataTable.Active := True;

  // El albar<61>n tiene que venir ya abierto y posicionado donde hay que copiar
  AAlbaran.ID_PROVEEDOR := APedido.ID_PROVEEDOR;
  AAlbaran.ID_PEDIDO := APedido.ID;
  AAlbaran.CALLE := APedido.CALLE;
  AAlbaran.CODIGO_POSTAL := APedido.CODIGO_POSTAL;
  AAlbaran.POBLACION := APedido.POBLACION;
  AAlbaran.PROVINCIA := APedido.PROVINCIA;
  AAlbaran.PERSONA_CONTACTO := APedido.PERSONA_CONTACTO;
  AAlbaran.TELEFONO := APedido.TELEFONO;
  AAlbaran.BASE_IMPONIBLE := APedido.BASE_IMPONIBLE;
  AAlbaran.IMPORTE_NETO := APedido.IMPORTE_NETO;
  AAlbaran.IMPORTE_PORTE := APedido.IMPORTE_PORTE;
  AAlbaran.IMPORTE_DESCUENTO := APedido.IMPORTE_DESCUENTO;
  AAlbaran.IMPORTE_IVA := APedido.IMPORTE_IVA;
  AAlbaran.IMPORTE_TOTAL := APedido.IMPORTE_TOTAL;
  AAlbaran.DESCUENTO := APedido.DESCUENTO;
  AAlbaran.IVA := APedido.IVA;
  AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorOBSERVACIONES).AsVariant := APedido.DataTable.FieldByName(fld_PedidosProveedorOBSERVACIONES).AsVariant;
  AAlbaran.ID_FORMA_PAGO := APedido.ID_FORMA_PAGO;
  AAlbaran.ID_ALMACEN := APedido.ID_ALMACEN;
end;

procedure CopiarArticulosPedido(ID_PEDIDO: Integer; AOrigen: IBizDetallesPedidoProveedor; ADestino : IBizDetallesAlbaranProveedor; AArticulosPendientes: IBizDetallesPedidoProveedorPend);
var
  i : integer;
  ADetallesController : IDetallesAlbaranProveedorController;
  ACantidad: Variant;
  ArticulosAnadidosAux: TStringList;
  ACadena: String;

begin
  if not Assigned(AOrigen) then
    raise Exception.Create ('Origen no asignado (CopiarArticulosPedido)');

  if not Assigned(ADestino) then
    raise Exception.Create ('Destino no asignado (CopiarArticulosPedido)');

  if not AOrigen.DataTable.Active then
    AOrigen.DataTable.Active := True;

  if not ADestino.DataTable.Active then
    ADestino.DataTable.Active := True;

  ADetallesController := TDetallesAlbaranProveedorController.Create;
  ArticulosAnadidosAux:= TStringList.Create;
  try
    //OJO IMPORTANTE
    //Siempre que vayamos a trabajar con los detalles debemos hacer un beginupdate de los mismos y un endupdate para
    //obligarle siempre a recalcular los detalles una sola vez
    ADetallesController.BeginUpdate(ADestino);

    AOrigen.DataTable.First;
    for i := 0 to AOrigen.DataTable.RecordCount - 1 do
    begin
      ACadena := '';
      //Comprobamos el articulo del pedido no haya sido recibido ya en otro albaran.
      AArticulosPendientes.DataTable.First;
      if AArticulosPendientes.DataTable.Locate(fld_PedidosProveedor_DetallesID_ARTICULO, AOrigen.ID_ARTICULO, []) then
      begin
        //Esto es para el caso de meter edl mismo articulo varias veces en el pedido cambiando la descripci<63>n, si esto ocurre,
        //Metemos en la primera aparici<63>n la suma de las unidades a recibir y en las siguiente apariciones se pone CERO
        if (ArticulosAnadidosAux.IndexOf(IntToStr(AOrigen.ID_ARTICULO)) = -1) then
        begin
           ACantidad := AArticulosPendientes.CANTIDAD;
           ArticulosAnadidosAux.Add(IntToStr(AOrigen.ID_ARTICULO));
        end
        else begin
           ACantidad := 0;
           ACadena := #10 + #13 + ' - Art<72>culo con ref. ' + AOrigen.REFERENCIA + ' repetido en otra linea y descripci<63>n diferente';
        end;
      end
      else
      begin
         ACantidad := 0; //AOrigen.CANTIDAD;
         ACadena := ' - Recibido en un albar<61>n anterior'
      end;


      ADetallesController.Add(ADestino, TIPO_DETALLE_CONCEPTO);
      ADestino.Edit;
      ADestino.REFERENCIA := AOrigen.REFERENCIA;
      if AOrigen.ID_ARTICULO > 0 then
         ADestino.ID_ARTICULO := AOrigen.ID_ARTICULO;
      ADestino.CONCEPTO := AOrigen.CONCEPTO + ACadena;
      ADestino.CANTIDAD := ACantidad;
      ADestino.IMPORTE_UNIDAD := AOrigen.IMPORTE_UNIDAD;
      ADestino.IMPORTE_TOTAL := AOrigen.IMPORTE_TOTAL;
      ADestino.DESCUENTO := AOrigen.DESCUENTO;
      ADestino.IMPORTE_PORTE := AOrigen.IMPORTE_PORTE;
      ADestino.VISIBLE := AOrigen.VISIBLE;
      ADestino.REFERENCIA_PROVEEDOR := AOrigen.REFERENCIA_PROVEEDOR;
      ADestino.ID_PEDIDO := ID_PEDIDO;
      ADestino.Post;
      AOrigen.Next;
    end;
  finally
    ArticulosAnadidosAux.Destroy;
    ADetallesController.EndUpdate(ADestino);
    ADetallesController := NIL;
  end;
end;


procedure CopiarArticulosAAlbaran(APedido: IBizPedidoProveedor; AAlbaran: IBizAlbaranProveedor;
    AInventarioRecibido: IBizInventario);
var
  i : integer;
  ADetalles : IBizDetallesAlbaranProveedor;
  ADetallesController : IDetallesAlbaranProveedorController;
  AArticulosController : IArticulosController;
  AArticulo : IBizArticulo;
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (CopiarArticulosAAlbaran)');

  if not Assigned(APedido) then
    raise Exception.Create ('Pedido no asignado (CopiarArticulosAAlbaran)');

  //Si esta asignado el inventario recibido es por una entrada de articulos de un pedido a almac<61>n
  if Assigned(AInventarioRecibido) then
  begin
    if not AInventarioRecibido.DataTable.Active then
      AInventarioRecibido.DataTable.Active := True;

    // El albar<61>n tiene que venir ya abierto y posicionado donde hay que copiar

    ADetalles := AAlbaran.Detalles;
    ADetallesController := TDetallesAlbaranProveedorController.Create;
    AArticulosController := TArticulosController.Create;
    try
      AInventarioRecibido.DataTable.First;
      for i := 0 to AInventarioRecibido.DataTable.RecordCount - 1 do
      begin
        AArticulo := AArticulosController.Buscar(AInventarioRecibido.ID_ARTICULO);
        if not Assigned(AArticulo) then
          raise Exception.Create(Format('No se ha encontrado el art<72>culo con ID %d (CopiarArticulosAAlbaran)', [AInventarioRecibido.ID_ARTICULO]));

        if (AInventarioRecibido.CANTIDAD <> 0) then
        begin
          ADetallesController.Add(ADetalles, TIPO_DETALLE_CONCEPTO);
//Se cambia porque puede haber articulos del pedido que no tengan referencia de proveedor
//          ADetallesController.AnadirArticulo(ADetalles, AInventarioRecibido.REFERENCIA, tCliente);
          ADetallesController.AnadirArticulo(ADetalles, AInventarioRecibido.ID_ARTICULO);
          ADetalles.Edit;

          APedido.Detalles.First;
//Se cambia porque puede haber articulos del pedido que no tengan referencia de proveedor
//          if not APedido.Detalles.DataTable.Locate(fld_ArticulosREFERENCIA, ADetalles.REFERENCIA, []) then
          if not APedido.Detalles.Locate(fld_INVENTARIOID_ARTICULO, VarArrayOf([ADetalles.DataTable.FieldByName('ID_ARTICULO').AsVariant]), []) then
             raise Exception.Create(Format('No se ha encontrado el art<72>culo del pedido con REFERENCIA %s (CopiarArticulosAAlbaran)', [ADetalles.REFERENCIA]));
          ADetalles.IMPORTE_UNIDAD := APedido.Detalles.IMPORTE_UNIDAD;
          ADetalles.DESCUENTO := APedido.Detalles.DESCUENTO;
          ADetalles.IMPORTE_PORTE := APedido.Detalles.IMPORTE_PORTE;

          ADetalles.CANTIDAD := AInventarioRecibido.CANTIDAD;
          ADetalles.Post;
        end;

        AInventarioRecibido.Next;
      end;

    finally
      ADetallesController := NIL;
      AArticulosController := NIL;
    end;
  end
  else begin
    // AInventarioRecibido = NIL

    // El albar<61>n tiene que venir ya abierto y posicionado donde hay que copiar

    ADetalles := AAlbaran.Detalles;
    ADetallesController := TDetallesAlbaranProveedorController.Create;
    AArticulosController := TArticulosController.Create;
    try
      APedido.Detalles.DataTable.First;
      for i := 0 to APedido.Detalles.DataTable.RecordCount - 1 do
      begin
        AArticulo := AArticulosController.Buscar(APedido.Detalles.ID_ARTICULO);
        if not Assigned(AArticulo) then
          raise Exception.Create(Format('No se ha encontrado el art<72>culo con ID %d (CopiarArticulosAAlbaran)', [APedido.Detalles.ID_ARTICULO]));

          if (APedido.Detalles.CANTIDAD <> 0) then
          begin
            ADetallesController.Add(ADetalles, TIPO_DETALLE_CONCEPTO);
            ADetallesController.AnadirArticulo(ADetalles, APedido.Detalles.REFERENCIA, tCliente);
            ADetalles.Edit;
            ADetalles.IMPORTE_UNIDAD := APedido.Detalles.IMPORTE_UNIDAD;
            ADetalles.DESCUENTO := APedido.Detalles.DESCUENTO;
            ADetalles.IMPORTE_PORTE := APedido.Detalles.IMPORTE_PORTE;
            ADetalles.CANTIDAD := APedido.Detalles.CANTIDAD;
            ADetalles.Post;
          end;
        APedido.Detalles.Next;
      end;
    finally
      ADetallesController := NIL;
      AArticulosController := NIL;
    end;
  end;

  ADetallesController.ActualizarTotales(ADetalles);
end;


{ TAlbaranesProveedorController }

function TAlbaranesProveedorController.Anadir(AAlbaran: IBizAlbaranProveedor) : Boolean;
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (Anadir)');

  if not AAlbaran.DataTable.Active then
    AAlbaran.DataTable.Active := True;

  AAlbaran.Insert;
  Result := True;
end;


function TAlbaranesProveedorController.Anadir(AAlbaran: IBizAlbaranProveedor; const IDPedido: Integer; AInventarioRecibido: IBizInventario): Boolean;
var
  APedidosController : TPedidosProveedorController;
  APedido : IBizPedidoProveedor;
begin
  Result := False;
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (Anadir)');

  if (IDPedido < 0) or (IDPedido = 0) then
    raise Exception.Create (Format('ID de pedido (%d) incorrecto (Anadir)', [IDPedido]));

  if not AAlbaran.DataTable.Active then
    AAlbaran.DataTable.Active := True;

  ShowHourglassCursor;
  Application.ProcessMessages;

  APedido := NIL;
  APedidosController := TPedidosProveedorController.Create;
  try
    APedido := APedidosController.Buscar(IDPedido);
    if not Assigned(APedido) then
      raise Exception.Create (Format('No se ha encontrado un pedido de proveedor con ID %d (Anadir)', [IDPedido]));

    APedido.DataTable.Active := True;

    if not Assigned(AInventarioRecibido) then
    begin
      if (APedido.ID_ALMACEN > 0) then
        raise Exception.Create ('Inventario recibido no asignado (Anadir)')
    end
    else begin
      if not AInventarioRecibido.DataTable.Active then
        AInventarioRecibido.DataTable.Active := True;
    end;

    Self.Anadir(AAlbaran);
    CopiarPedidoAAlbaran(APedido, AAlbaran);
    CopiarArticulosAAlbaran(APedido, AAlbaran, AInventarioRecibido);
    RecalcularImportes(AAlbaran);
    Result := True;
  finally
    APedido := NIL;
    APedidosController := NIL;
    HideHourglassCursor;
    Application.ProcessMessages;
  end;
end;

function TAlbaranesProveedorController.Anadir(AAlbaranes: IBizAlbaranProveedor;
  AListaPedidos: IBizPedidoProveedor): Boolean;
var
  AAlbaranActual : IBizAlbaranProveedor;
  APedidosController : IPedidosProveedorController;
  AArticulosPendientes : IBizDetallesPedidoProveedorPend;
  I: Integer;
  bEnEdicion : Boolean;
begin
  Result := False;

  // ATENCI<43>N!!! AAlbaranes tiene que estar vacio para no pisar albaranes
  // ya generados.
  if not Assigned(AAlbaranes) then
    raise Exception.Create ('Albaran no asignado (Anadir)');

  if not Assigned(AListaPedidos) then
    raise Exception.Create ('Pedidos no asignados (Anadir)');

  if not AAlbaranes.DataTable.Active then
    AAlbaranes.DataTable.Active := True;

  if not AListaPedidos.DataTable.Active then
    AListaPedidos.DataTable.Active := True;

  ShowHourglassCursor;
  Application.ProcessMessages;

  APedidosController := TPedidosProveedorController.Create;
  try
    // Ordenar por fecha de pedido
    AListaPedidos.DataTable.Sort([fld_PedidosProveedorFECHA_PEDIDO], [uDADataTable.sdAscending]);
    AListaPedidos.First;
    for I := 0 to AListaPedidos.DataTable.RecordCount - 1 do
    begin
      AListaPedidos._Proveedor := NIL;
      AAlbaranActual := NIL;

      // Busco si hay algun albar<61>n ya hecho de ese Proveedor
      AAlbaranes.DataTable.First;
      if AAlbaranes.DataTable.Locate(fld_AlbaranesProveedorID_Proveedor, AListaPedidos.ID_Proveedor, []) then
      begin
        AAlbaranActual := AAlbaranes;
        RecuperarProveedor(AAlbaranActual);
        AAlbaranActual.Proveedor.DataTable.Active := True;

        bEnEdicion := (AAlbaranActual.DataTable.State in dsEditModes);
        if not bEnEdicion then
           AAlbaranActual.Edit;
//Si ya tenemos un albar<61>n quiere decir que dicho albar<61>n va ha recibir mas de un pedido
//por lo que la relaci<63>n con el pedido se traslada a los articulos detalles, es decir un albar<61>n que recibe varios pedidos
//el idPedido de la cabeceza ser<65> null.
        AAlbaranActual.ID_PEDIDOIsNull := True;
//Cuando elijo varios pedidos ponemos como almac<61>n destino siempre el que tenga asociado el primer pedido del albaran
//        AAlbaranActual.ID_ALMACEN := AL PASADO POR PARAMETRO
        AAlbaranActual.Post;
        if bEnEdicion then
           AAlbaranActual.Edit;
      end
      else begin
        // No hay albaran de ese Proveedor. Creo una nueva
        Anadir(AAlbaranes);
        APedidosController.RecuperarProveedor(AListaPedidos);
        AAlbaranes.Proveedor := AListaPedidos.Proveedor;

        //Siempre asignaremos por defecto el ID_PEDIDO del primer pedido de la lista, si hay m<>s pedidos en el albar<61>n luego los pondremos a null,
        //con ID_ALMACEN pasar<61> lo mismo
        bEnEdicion := (AAlbaranes.DataTable.State in dsEditModes);
        if not bEnEdicion then
           AAlbaranes.Edit;
        AAlbaranes.ID_PEDIDO := AListaPedidos.ID;
        AAlbaranes.ID_ALMACEN := AListaPedidos.ID_ALMACEN;
        AAlbaranes.Post;
        if bEnEdicion then
           AAlbaranes.Edit;

        //Si el albaran es de tipo devoluci<63>n hacemos la factura de tipo abono
{        if (AListaAlbaranes.TIPO = CTE_TIPO_ALBARAN_DEV) then
        begin
          bEnEdicion := (AFacturas.DataTable.State in dsEditModes);
          if not bEnEdicion then
             AFacturas.Edit;
          AFacturas.TIPO := CTE_TIPO_ABONO;
          AFacturas.Post;
          if bEnEdicion then
             AFacturas.Edit;
        end;
}
        AAlbaranActual := AAlbaranes;
      end;

      // Ya tengo el albar<61>n. Le a<>ado los conceptos del pedido
      //Recogemos los articulos pendientes de recibir de pedido, para solo recibir lo restante si ya estubiera recibido parcialmente.
      //SOLO SE TENDRA EN CUENTA LOS INVENTARIABLES
      AArticulosPendientes := APedidosController.ArticulosPendientesDeRecibir(AListaPedidos.ID);


      AAlbaranActual.Detalles.DataTable.Last;
      // A<>ado el t<>tulo
      Self.DetallesController.Add(AAlbaranActual.Detalles, TIPO_DETALLE_TITULO);
      with AAlbaranActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Pedido ' + AListaPedidos.REFERENCIA + ' del ' + DateToStr(AListaPedidos.FECHA_PEDIDO);
        Post;
      end;

      // A<>ado el contenido del pedido
      CopiarArticulosPedido(AListaPedidos.ID, AListaPedidos.Detalles, AAlbaranActual.Detalles, AArticulosPendientes);

{En los albaranes a proveedor el porte es a nivel del art<EFBFBD>culo
      Self.DetallesController.Add(AFacturaActual.Detalles, TIPO_DETALLE_CONCEPTO);
      with AFacturaActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Porte del albar<61>n';
        CANTIDAD := 1;
        IMPORTE_UNIDAD := AListaAlbaranes.IMPORTE_PORTE;
        Post;
      end;
}

      // A<>ado el resumen
      Self.DetallesController.Add(AAlbaranActual.Detalles, TIPO_DETALLE_SUBTOTAL);
      with AAlbaranActual.Detalles do
      begin
        Edit;
        CONCEPTO := 'Total del pedido ' + AListaPedidos.REFERENCIA;
        Post;
      end;

      // A<>ado una l<>nea en blanco
      Self.DetallesController.Add(AAlbaranActual.Detalles, TIPO_DETALLE_CONCEPTO);
      with AAlbaranActual.Detalles do
      begin
        Edit;
        CONCEPTO := '';
        Post;
      end;

      // Guardo el albaran que acabo de generar o editar
      AAlbaranActual.CalcularImporteTotal;
      Self.Guardar(AAlbaranActual);
      // No se asocia el albaran al pedido ya que un pedido puede estar representado por varios albaranes
{      AListaPedidos.Edit;
      AListaPedidos.ID_FACTURA := AFacturaActual.ID;
      AListaPedidos.Post;
      APedidosController.Guardar(AListaPedidos);
}
      AListaPedidos.Next;
    end;
    Result := True;
  finally
    APedidosController := NIL;
    HideHourglassCursor
  end;
end;

function TAlbaranesProveedorController.AnadirAlbaranDev(AAlbaran: IBizAlbaranProveedor): Boolean;
begin
  Result := Anadir(AAlbaran);
  AAlbaran.TIPO := CTE_TIPO_ALBARAN_DEV;
end;

procedure TAlbaranesProveedorController.AsignarDataModule;
begin
  FDataModule := TDataModuleAlbaranesProveedor.Create(Nil);
end;

function TAlbaranesProveedorController.Buscar(const ID: Integer): IBizAlbaranProveedor;
begin
  Result := FDataModule.GetItem(ID);
  FiltrarEmpresa(Result);
end;

function TAlbaranesProveedorController.BuscarAlbaranesDevolucion: IBizAlbaranProveedor;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := BuscarTodos;

    with Result.DataTable.DynamicWhere do
    begin
      // (IMPORTE_TOTAL < 0)
      Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorIMPORTE_TOTAL), NewConstant(0, datCurrency), dboLess);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;
  finally
    HideHourglassCursor;
  end;
end;

function TAlbaranesProveedorController.BuscarAlbaranesNormales: IBizAlbaranProveedor;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := BuscarTodos;

    with Result.DataTable.DynamicWhere do
    begin
      // (IMPORTE_TOTAL >= 0)
      Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorIMPORTE_TOTAL), NewConstant(0, datCurrency), dboGreaterOrEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

function TAlbaranesProveedorController.BuscarTodos: IBizAlbaranProveedor;
begin
  Result := FDataModule.GetItems;
  FiltrarEmpresa(Result);
end;

function TAlbaranesProveedorController.BuscarSinFacturar: IBizAlbaranProveedor;
var
  Condicion: TDAWhereExpression;
begin
  ShowHourglassCursor;
  try
    Result := BuscarAlbaranesNormales;

    with Result.DataTable.DynamicWhere do
    begin
      // (ID_FACTURA = NULL)
      Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorID_FACTURA), NewNull(), dboEqual);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
    end;

  finally
    HideHourglassCursor;
  end;
end;

procedure TAlbaranesProveedorController.CopiarDireccionEnvio(
  const ADireccionEnvio: IBizDireccionesContacto; AAlbaran: IBizAlbaranProveedor);
var
  bEnEdicion : Boolean;
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albaran no asignado (CopiarDireccionEnvio)');

  if not Assigned(ADireccionEnvio) then
    raise Exception.Create ('No se ha indicado la direcci<63>n (CopiarDireccionEnvio)');

  if AAlbaran.DataTable.Active then
    AAlbaran.DataTable.Active := True;

  if ADireccionEnvio.DataTable.Active then
    ADireccionEnvio.DataTable.Active := True;


  bEnEdicion := (AAlbaran.DataTable.State in dsEditModes);
  if not bEnEdicion then
    AAlbaran.Edit;

  ShowHourglassCursor;
  AAlbaran.Edit;
  try
    AAlbaran.CALLE := ADireccionEnvio.CALLE;
    AAlbaran.POBLACION := ADireccionEnvio.POBLACION;
    AAlbaran.CODIGO_POSTAL := ADireccionEnvio.CODIGO_POSTAL;
    AAlbaran.PROVINCIA := ADireccionEnvio.PROVINCIA;
//    AAlbaran.PAIS := ADireccionEnvio.PAIS;
    AAlbaran.TELEFONO := ADireccionEnvio.TELEFONO;
    AAlbaran.PERSONA_CONTACTO := ADireccionEnvio.PERSONA_CONTACTO;

    if not bEnEdicion then
      AAlbaran.Post;
  finally
    HideHourglassCursor;
  end;
end;

constructor TAlbaranesProveedorController.Create;
begin
  inherited;
  AsignarDataModule;
  
  FProveedorController := TProveedoresController.Create;
  FDetallesController := TDetallesAlbaranProveedorController.Create;
  FDetallesController.addObservador(Self);
end;

function TAlbaranesProveedorController.CreateEditor(const AName: String;
  const IID: TGUID; out Intf): Boolean;
begin
  Result := Supports(EditorRegistry.CreateEditor(AName), IID, Intf);
end;

function TAlbaranesProveedorController.DarListaAnosAlbaranes: TStringList;
begin
  Result := FDataModule.GetAnosItems;
end;

procedure TAlbaranesProveedorController.DescartarCambios(AAlbaran: IBizAlbaranProveedor);
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado');

  ShowHourglassCursor;
  try
    if (AAlbaran.State in dsEditModes) then
      AAlbaran.Cancel;

    AAlbaran.DataTable.CancelUpdates;
  finally
    HideHourglassCursor;
  end;
end;

destructor TAlbaranesProveedorController.Destroy;
begin
  FDataModule := Nil;
  FProveedorController := Nil;
  FDetallesController := Nil;
  inherited;
end;

function TAlbaranesProveedorController.Duplicar(AAlbaran: IBizAlbaranProveedor): IBizAlbaranProveedor;
begin
  Result := Self._Vacio;
  ShowHourglassCursor;
  try
    DuplicarRegistros(AAlbaran.DataTable, Result.DataTable, mdrActual);
    DuplicarRegistros(AAlbaran.Detalles.DataTable, Result.Detalles.DataTable, mdrTodos);

    // Hay que dejar algunos campos como si fuera un presupuesto nuevo
    Result.Edit;
    with Result do
    begin
      ID_EMPRESA := AppFactuGES.EmpresaActiva.ID;
      ID_TIENDA := AppFactuGES.TiendaActiva.ID;
      USUARIO := AppFactuGES.UsuarioActivo.UserName;
      FECHA_ALBARAN := DateOf(Now);
      INCIDENCIAS_ACTIVAS := 0;
      REFERENCIA := '';
      ID_PEDIDO := 0;
      ID_FACTURA := 0;
    end;
    Result.Post;
  finally
    HideHourglassCursor;
  end;
end;

function TAlbaranesProveedorController.ValidarAlbaran(AAlbaran: IBizAlbaranProveedor): Boolean;
begin
  Result := False;

  if not Assigned(AAlbaran) then
     raise Exception.Create ('Albar<61>n no asignado');

  if (AAlbaran.DataTable.State in dsEditModes) then
      AAlbaran.DataTable.Post;

  //Tambien hacemos post de sus tablas hija
  if (AAlbaran.Detalles.DataTable.State in dsEditModes) then
      AAlbaran.Detalles.DataTable.Post;

  if (AAlbaran.ID_PROVEEDOR < 0) or (AAlbaran.ID_PROVEEDOR = 0) then
  // Si hay altas autom<6F>ticas no hay objeto Proveedor pero s<> hay ID_PROVEEDOR
{     (not Assigned(AAlbaran.Proveedor)) or
     (AAlbaran.Proveedor.IsEmpty) then}
    raise Exception.Create('Debe indicar el proveedor de este albar<61>n');

  if (EsFechaVacia(AAlbaran.FECHA_ALBARAN)) then
    raise Exception.Create('Debe indicar la fecha de este albar<61>n');

  if (Length(AAlbaran.CALLE) = 0) and (AAlbaran.ID_ALMACEN = 0) then
    {$IFDEF ALMACEN}
    raise Exception.Create('Debe indicar una direcci<63>n de entrega o almac<61>n para este albar<61>n');
    {$ELSE}
    raise Exception.Create('Debe indicar una direcci<63>n de entrega');
    {$ENDIF}

  //Tambien hacemos post de sus tablas hija
  if (AAlbaran.Detalles.DataTable.RecordCount = 0) then
    raise Exception.Create('El albar<61>n de de tener al menos un concepto en su contenido');

  //En caso de ser un Albar<61>n no podra tener un importe total negativo
  if (AAlbaran.TIPO = CTE_TIPO_ALBARAN) then
    if (AAlbaran.IMPORTE_TOTAL < 0) then
      raise Exception.Create('Un albar<61>n no puede tener un importe total negativo');

  {$IFDEF ALMACEN}
    //En caso de ser una orden de devoluci<63>n no podra tener un importe total positivo
    if (AAlbaran.TIPO = CTE_TIPO_ALBARAN_DEV) then
    begin
      if (AAlbaran.IMPORTE_TOTAL >= 0) then
        raise Exception.Create('Una orden de devoluci<63>n no puede tener un importe total positivo');

      //Una orden de devoluci<63>n debe tener relleno el almac<61>n de salida de material
      if (AAlbaran.ID_ALMACEN < 0) or (AAlbaran.ID_ALMACEN = 0) then
        raise Exception.Create('Debe indicar el almac<61>n de salida de esta orden de devoluci<63>n');
    end;
  {$ENDIF}

  { Asegurarse de valores en campos "autom<6F>ticos" tanto
    en MODIFICACI<EFBFBD>N como en INSERCI<EFBFBD>N. }
  AAlbaran.Edit;
  try
    AAlbaran.USUARIO := AppFactuGES.UsuarioActivo.UserName;

    if Assigned(AAlbaran.Proveedor)
    and (AAlbaran.ID_PROVEEDOR <> AAlbaran.Proveedor.ID) then
      AAlbaran.ID_PROVEEDOR := AAlbaran.Proveedor.ID;

    Result := True;
  finally
    AAlbaran.Post;
  end;
end;

procedure TAlbaranesProveedorController.Ver(AAlbaran: IBizAlbaranProveedor);
var
  AEditor : IEditorAlbaranProveedor;
begin
  AEditor := NIL;

  RecuperarObjetos(AAlbaran);

  if (AAlbaran.TIPO = CTE_TIPO_ALBARAN) then
      CreateEditor('EditorAlbaranProveedor', IEditorAlbaranProveedor, AEditor)
  else
      CreateEditor('EditorAlbaranDevProveedor', IEditorAlbaranDevProveedor, AEditor);

  if Assigned(AEditor) then
    try
      AEditor.Controller := Self; //OJO ORDEN MUY IMPORTANTE
      AEditor.Albaran := AAlbaran;

      //MODO CONSULTAR
      if not EsModificable(AAlbaran) then
      begin
         SetDataTableReadOnly(AAlbaran.DataTable, True);
         AEditor.ReadOnly := True;
      end;

      AEditor.ShowModal;

      //MODO CONSULTAR (Se deja la tabla como estaba)
      if AEditor.ReadOnly then
         SetDataTableReadOnly(AAlbaran.DataTable, False);
    finally
      AEditor.Release;
      AEditor := NIL;
    end;
end;

procedure TAlbaranesProveedorController.VerDireccionEntrega(AAlbaran: IBizAlbaranProveedor);
var
  AEditor : IEditorDireccionEntregaAlbaranProveedor;
begin
  AEditor := NIL;

  //RecuperarObjetos(AAlbaran); <- No descomentar. No hace falta
  CreateEditor('EditorDireccionEntregaAlbaranProveedor', IEditorDireccionEntregaAlbaranProveedor, AEditor);
  if Assigned(AEditor) then
    try
      AEditor.Albaran := AAlbaran;
      AEditor.ShowModal;
    finally
      AEditor.Release;
      AEditor := NIL;
    end;
end;

procedure TAlbaranesProveedorController.VerTodosAlbaranes(AAlbarans: IBizAlbaranProveedor);
var
  AEditor : IEditorAlbaranesProveedor;
begin
  AEditor := NIL;

  CreateEditor('EditorAlbaranesProveedor', IEditorAlbaranesProveedor, AEditor);
  if Assigned(AEditor) then
    with AEditor do
    begin
      Controller := Self; //OJO ORDEN MUY IMPORTANTE
      Albaranes := AAlbarans;
      MultiSelect := True;
      ShowEmbedded;
    end;
end;

procedure TAlbaranesProveedorController.VerTodosAlbaranesDev(AAlbarans: IBizAlbaranProveedor);
var
  AEditor : IEditorAlbaranesDevProveedor;
begin
  AEditor := NIL;

  CreateEditor('EditorAlbaranesDevProveedor', IEditorAlbaranesDevProveedor, AEditor);
  if Assigned(AEditor) then
    with AEditor do
    begin
      Controller := Self; //OJO ORDEN MUY IMPORTANTE
      Albaranes := AAlbarans;
      MultiSelect := True;
      ShowEmbedded;
    end;
end;

function TAlbaranesProveedorController._Vacio: IBizAlbaranProveedor;
begin
  Result := Buscar(ID_NULO);
end;

function TAlbaranesProveedorController.Eliminar(const ID: Integer): Boolean;
var
  AAlbaran : IBizAlbaranProveedor;
begin
  AAlbaran := Buscar(ID);

  if not Assigned(AAlbaran) then
    raise Exception.Create(Format('No se ha encontrado el albar<61>n con ID = %d', [ID]));

  Result := Eliminar(AAlbaran);
  AAlbaran := NIL;
end;

function TAlbaranesProveedorController.ElegirAlbaranes(AAlbaran: IBizAlbaranProveedor; AMensaje: String; AMultiSelect: Boolean): IBizAlbaranProveedor;
var
  AEditor : IEditorElegirAlbaranesProveedor;
begin
  Result := NIL;

  CreateEditor('EditorElegirAlbaranesProveedor', IEditorElegirAlbaranesProveedor, AEditor);
  if Assigned(AEditor) then
    try
      AEditor.Controller := Self;
      AEditor.Albaranes := AAlbaran;
      AEditor.MultiSelect := AMultiSelect;
      AEditor.Mensaje := AMensaje;
      if IsPositiveResult(AEditor.ShowModal) then
        Result := AEditor.AlbaranesProveedorSeleccionados;
    finally
      AEditor.Release;
      AEditor := NIL;
    end;
end;

function TAlbaranesProveedorController.Eliminar(AAlbaran: IBizAlbaranProveedor; AllItems: Boolean = false): Boolean;
//En el caso de eliminar almenos un elemento del conjunto se devuelve true
var
  bEliminado: Boolean;

begin
  bEliminado := False;

  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignada');

  ShowHourglassCursor;
  try
    if (AAlbaran.State in dsEditModes) then
      AAlbaran.Cancel;

    //Siempre eliminaremos el seleccionado
    if EsEliminable(AAlbaran) then
    begin
      AAlbaran.Delete;
      bEliminado := True;
    end;

    //En el caso de querer eliminar todos los items del objeto AAlbaran
    if AllItems then
    begin
       with AAlbaran.DataTable do
       begin
         First;
         while not EOF do
         begin
           if EsEliminable(AAlbaran) then
           begin
              AAlbaran.Delete;
              bEliminado := True
           end
           else Next;
         end;
       end;
    end;

    if bEliminado then
    begin
       AAlbaran.DataTable.ApplyUpdates;
       Result := True;
    end
    else
       Result := False;

  finally
    HideHourglassCursor;
  end;
end;
function TAlbaranesProveedorController.EsEliminable(AAlbaran: IBizAlbaranProveedor): Boolean;
begin
  if not Assigned(AAlbaran) then
     raise Exception.Create ('Albar<61>n no asignado: EsModificable');

  Result := EsModificable(AAlbaran);
end;

function TAlbaranesProveedorController.EsModificable(AAlbaran: IBizAlbaranProveedor): Boolean;
begin
  if not Assigned(AAlbaran) then
     raise Exception.Create ('Albar<61>n no asignado: EsModificable');

  Result := not (AAlbaran.ID_FACTURA > 0);
end;

procedure TAlbaranesProveedorController.RecalcularImportes(AAlbaran: IBizAlbaranProveedor);
var
  bEnEdicion : Boolean;
  ADetallePosAct : Integer;
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (RecalcularImportes)');

  if AAlbaran.DataTable.Active then
    AAlbaran.DataTable.Active := True;

  { Hay que guardar la posici<EFBFBD>n en la que estamos en los detalles por que
    la asignaci<EFBFBD>n de valores a los campos IMPORTE_NETO e IMPORTE_PORTE
    (ver m<EFBFBD>s adelante) colocan el puntero en la tabla detalle al principio.
    No he encontrado la raz<EFBFBD>n por la que mueve el puntero. }

  ADetallePosAct := AAlbaran.Detalles.POSICION;

  bEnEdicion := (AAlbaran.DataTable.State in dsEditModes);
  if not bEnEdicion then
    AAlbaran.Edit;

  ShowHourglassCursor;
  AAlbaran.Edit;
  try
    AAlbaran.IMPORTE_NETO := FDetallesController.DarTotalImporteTotal(AAlbaran.Detalles);
    AAlbaran.IMPORTE_PORTE := FDetallesController.DarTotalPorteTotal(AAlbaran.Detalles);
    if not bEnEdicion then
      AAlbaran.Post;
  finally
    HideHourglassCursor;
    // Restaurar la posici<63>n que ten<65>amos en los detalles.
    FDetallesController.LocalizarPosicion(AAlbaran.Detalles, ADetallePosAct);
  end;
end;

procedure TAlbaranesProveedorController.RecibirAviso(ASujeto: ISujeto; ADataTable: IDAStronglyTypedDataTable);
var
  AAlbaran : IBizAlbaranProveedor;
  ADetalles : IBizDetallesAlbaranProveedor;
begin
  inherited;

  if Supports(ADataTable, IBizDetallesAlbaranProveedor, ADetalles) and
     Supports(ADetalles.DataTable.MasterSource.DataTable, IBizAlbaranProveedor, AAlbaran) then
  begin
    RecalcularImportes(AAlbaran);
  end;
end;

procedure TAlbaranesProveedorController.RecuperarObjetos(AAlbaran: IBizAlbaranProveedor);
begin
  RecuperarProveedor(AAlbaran);
end;

procedure TAlbaranesProveedorController.RecuperarProveedor(AAlbaran: IBizAlbaranProveedor);
begin
  AAlbaran._Proveedor := (FProveedorController.Buscar(AAlbaran.ID_PROVEEDOR)  as IBizProveedor);
end;

function TAlbaranesProveedorController.Existe(const ID: Integer): Boolean;
var
  AAlbaran : IBizAlbaranProveedor;
begin
  try
    AAlbaran := Buscar(ID);
    Result := Assigned(AAlbaran) and (AAlbaran.ID = ID);
  finally
    AAlbaran := NIL;
  end;
end;

function TAlbaranesProveedorController.ExtraerSeleccionados(AAlbaran: IBizAlbaranProveedor): IBizAlbaranProveedor;
var
  ASeleccionados : IBizAlbaranProveedor;
begin
  ASeleccionados := (Self.Buscar(ID_NULO) as IBizAlbaranProveedor);
  CopyDataTableDA5(AAlbaran.DataTable, ASeleccionados.DataTable, True);
  Result := ASeleccionados;
end;

procedure TAlbaranesProveedorController.FiltrarAno(AAlbaran: IBizAlbaranProveedor; ADynWhereDataTable: WideString; const Ano: String);
var
  Condicion: TDAWhereExpression;
  FechaIni: String;
  FechaFin: String;

begin
  AAlbaran.DataTable.DynamicWhere.Clear;
  AAlbaran.DataTable.DynamicWhere.Xml := ADynWhereDataTable;

  if (Ano <> 'Todos') then
  begin
    // Filtrar las facturas actuales por empresa
    FechaIni := '01/01/' + Ano;
    FechaFin := '31/12/' + Ano;
    with AAlbaran.DataTable.DynamicWhere do
    begin
      // (FECHA_INICIO between FECHA_FIN)
      Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorFECHA_ALBARAN), NewConstant(FechaIni, datString), dboGreaterOrEqual);
      Condicion := NewBinaryExpression(NewBinaryExpression(NewField('', fld_AlbaranesProveedorFECHA_ALBARAN), NewConstant(FechaFin, datString), dboLessOrEqual), Condicion, dboAnd);

      if IsEmpty then
         Expression := Condicion
      else
         Expression := NewBinaryExpression(Condicion, Expression, dboAnd);
    end;
  end;

end;

procedure TAlbaranesProveedorController.FiltrarEmpresa(AAlbaran: IBizAlbaranProveedor);
var
  Condicion: TDAWhereExpression;
begin
  if AAlbaran.DataTable.Active then
     AAlbaran.DataTable.Active := False;

  // Filtrar los presupuestos actuales por empresa
  with AAlbaran.DataTable.DynamicWhere do
  begin
    // (ID_EMPRESA >= ID)
    Condicion := NewBinaryExpression(NewField('', fld_AlbaranesProveedorID_EMPRESA), NewConstant(AppFactuGES.EmpresaActiva.ID, datInteger), dboEqual);

    if IsEmpty then
       Expression := Condicion
    else
       Expression := NewBinaryExpression(Expression, Condicion, dboAnd);
  end;
end;

procedure TAlbaranesProveedorController.SetProveedorController(const Value: IProveedoresController);
begin
  FProveedorController := Value;
end;

procedure TAlbaranesProveedorController.SetDetallesController(const Value: IDetallesAlbaranProveedorController);
begin
  FDetallesController := Value;
end;

function TAlbaranesProveedorController.Guardar(AAlbaran: IBizAlbaranProveedor): Boolean;
var
  IDNuevo: Integer;
  ABookmark : TBookmark;

begin
  Result := False;

  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignada');

  if not Assigned(FDetallesController) then
    raise Exception.Create ('Controller detalles no asignado');

  //ESTO DA UN PETE DE COJONES NO GUARDA CABECERA
  //Preparamos todo para recuparar la posici<63>n de los detalles para despues de guardar no vaya al principio de los detalles
//OJO en este caso si activamos la desactivaci<63>n de tabla no guarda los importes del pedido
//  AAlbaran.DataTable.DisableControls;
//  AAlbaran.DataTable.DisableEventHandlers;
//  ABookmark := AAlbaran.Detalles.DataTable.GetBookMark;

  if ValidarAlbaran(AAlbaran) then
  begin
    ShowHourglassCursor;

    // Asegurarnos de que todos los importes est<73>n bien.
    RecalcularImportes(AAlbaran);

    try
      AAlbaran.DataTable.ApplyUpdates;
      Result := True;
    finally
      //Recuparamos la posici<63>n de los detalles para despues de guardar no vaya al principio de los detalles
//OJO en este caso si activamos la desactivaci<63>n de tabla no guarda los importes del pedido
//      AAlbaran.DataTable.EnableEventHandlers;
//      AAlbaran.DataTable.EnableControls;
//      AAlbaran.Detalles.DataTable.GotoBookmark(ABookmark);
//      AAlbaran.Detalles.DataTable.FreeBookmark(ABookmark);
    
      HideHourglassCursor;
    end;
  end;
end;

function TAlbaranesProveedorController.Nuevo (WithInsert: Boolean = True): IBizAlbaranProveedor;
var
  AAlbaran : IBizAlbaranProveedor;
begin
  AAlbaran := FDataModule.NewItem;
  FiltrarEmpresa(AAlbaran);
  AAlbaran.DataTable.Active := True;
  if WithInsert then
     AAlbaran.Insert;
  Result := AAlbaran;
end;

procedure TAlbaranesProveedorController.Preview(AAlbaran: IBizAlbaranProveedor; AllItems: Boolean = false);
var
  AReportController : IAlbaranesProveedorReportController;
  ID_Albaranes: TStringList;

begin
  AReportController := TAlbaranesProveedorReportController.Create;
  try
   ID_Albaranes := TStringList.Create;

   //Si deseamos previsualizar todos los items del objeto albaran
   if AllItems then
   begin
     with AAlbaran.DataTable do
     begin
       First;
       while not EOF do
       begin
         ID_Albaranes.Add(IntToStr(AAlbaran.ID));
         Next;
       end;
     end;
   end
   //Solo previsualizamos el item seleccionado
   else
     ID_Albaranes.Add(IntToStr(AAlbaran.ID));

    AReportController.Preview(ID_Albaranes.CommaText);

  finally
    AReportController := NIL;
    ID_Albaranes.Free;
  end;
end;

procedure TAlbaranesProveedorController.Print(AAlbaran: IBizAlbaranProveedor; AllItems: Boolean = false);
var
  AReportController : IAlbaranesProveedorReportController;
  ID_Albaranes: TStringList;

begin
  AReportController := TAlbaranesProveedorReportController.Create;
  try
   ID_Albaranes := TStringList.Create;

   //Si deseamos previsualizar todos los items del objeto albaran
   if AllItems then
   begin
     with AAlbaran.DataTable do
     begin
       First;
       while not EOF do
       begin
         ID_Albaranes.Add(IntToStr(AAlbaran.ID));
         Next;
       end;
     end;
   end
   //Solo previsualizamos el item seleccionado
   else
     ID_Albaranes.Add(IntToStr(AAlbaran.ID));

    AReportController.Print(ID_Albaranes.CommaText);

  finally
    AReportController := NIL;
    ID_Albaranes.Free;
  end;
end;

procedure TAlbaranesProveedorController.QuitarDireccionEnvio(
  AAlbaran: IBizAlbaranProveedor);
var
  bEnEdicion : Boolean;
begin
  if not Assigned(AAlbaran) then
    raise Exception.Create ('Albar<61>n no asignado (QuitarDireccionEnvio)');

  if AAlbaran.DataTable.Active then
    AAlbaran.DataTable.Active := True;

  bEnEdicion := (AAlbaran.DataTable.State in dsEditModes);
  if not bEnEdicion then
    AAlbaran.Edit;

  ShowHourglassCursor;
  AAlbaran.Edit;
  try
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorCALLE).Clear;
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorPOBLACION).Clear;
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorCODIGO_POSTAL).Clear;
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorPROVINCIA).Clear;
//    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorPAIS).Clear;    
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorTELEFONO).Clear;
    AAlbaran.DataTable.FieldByName(fld_AlbaranesProveedorPERSONA_CONTACTO).Clear;

    if not bEnEdicion then
      AAlbaran.Post;
  finally
    HideHourglassCursor;
  end;    
end;

function TAlbaranesProveedorController.GetProveedorController: IProveedoresController;
begin
  Result := FProveedorController;
end;

function TAlbaranesProveedorController.GetDetallesController: IDetallesAlbaranProveedorController;
begin
  Result := FDetallesController;
end;

end.