unit uBizComisionesServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schComisionesServer_Intf;

const
  BIZ_SERVER_COMISIONES = 'Server.Comisiones';

type
  TBizComisionesServer = class(TComisionesBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;

  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor; const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean; var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schComisionesClient_Intf, FactuGES_Intf, uROServer, SysUtils;

const
  REF_COMISIONES = 'REF_COMISIONES';  

{ TBizComisionesServer }

procedure TBizComisionesServer.AfterProcessChange(Sender: TDABusinessProcessor;
  aChange: TDADeltaChange; Processed: Boolean; var CanRemoveFromDelta: Boolean);
begin
  // No hay que quitar los deltas para que los datos del contacto se
  // mantengan por si alguna tabla detalle lo necesita
  // (por ejemplo, DireccionesContacto)
  CanRemoveFromDelta := False;

  // Actualizamos el contador de referencias.
  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                          end;
                        end;
  end;
end;

procedure TBizComisionesServer.BeforeProcessDelta(Sender: TDABusinessProcessor;
  const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizComisionesServer.DarReferencia: String;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
begin
  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.DarNuevaReferencia(REF_COMISIONES, ID_EMPRESA, -1)
end;

function TBizComisionesServer.IncrementarReferencia: Boolean;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
begin
  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.IncrementarValorReferencia(REF_COMISIONES, Self.REFERENCIA, ID_EMPRESA, -1)
end;


initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_COMISIONES, TBizComisionesServer);

end.