{
===============================================================================
  Copyright (©) 2006. Rodax Software.
===============================================================================
  Los contenidos de este fichero son propiedad de Rodax Software titular del
  copyright. Este fichero sólo podrá ser copiado, distribuido y utilizado,
  en su totalidad o en parte, con el permiso escrito de Rodax Software, o de
  acuerdo con los términos y condiciones establecidas en el acuerdo/contrato
  bajo el que se suministra.
  -----------------------------------------------------------------------------
  Web:  www.rodax-software.com
===============================================================================
  Fecha primera versión: 22-05-2006
  Versión actual: 1.0.0
  Fecha versión actual: 22-05-2006
===============================================================================
  Modificaciones:

    Fecha         Comentarios
    ---------------------------------------------------------------------------
===============================================================================
}

unit uEditorGruposProveedor;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, StdCtrls, DBCtrls, uDADataTable, ActnList,
  uIEditorGruposProveedor, uCustomEditor, uGUIBase, ExtCtrls,
  ComCtrls, uBizGruposProveedor, uGruposProveedorController, uDAInterfaces;

type
  TfEditorGruposProveedor = class(TCustomEditor, IEditorGruposProveedor)
    ActionList1: TActionList;
    DADataSource: TDADataSource;
    ListaGruposProveedor: TDBLookupListBox;
    editGrupoProveedor: TEdit;
    bAnadir: TButton;
    actAnadir: TAction;
    actEliminar: TAction;
    bEliminar: TButton;
    actAceptar: TAction;
    actCancelar: TAction;
    bAceptar: TButton;
    bCancelar: TButton;
    actCerrar: TAction;
    PageControl1: TPageControl;
    TabSheet1: TTabSheet;
    GroupBox1: TGroupBox;
    Label1: TLabel;
    procedure FormShow(Sender: TObject);
    procedure CustomEditorClose(Sender: TObject; var Action: TCloseAction);

    procedure actAnadirExecute(Sender: TObject);
    procedure actEliminarExecute(Sender: TObject);
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCerrarExecute(Sender: TObject);
    procedure actAnadirUpdate(Sender: TObject);
    procedure actEliminarUpdate(Sender: TObject);
  protected
    FGruposProveedor: IBizGrupoProveedor;
    FController: IGruposProveedorController;
    function GetGruposProveedor: IBizGrupoProveedor;
    procedure SetGruposProveedor(const Value: IBizGrupoProveedor);
    function GetController : IGruposProveedorController;
    procedure SetController (const Value : IGruposProveedorController);
  public
    property GruposProveedor: IBizGrupoProveedor read GetGruposProveedor write SetGruposProveedor;
    property Controller : IGruposProveedorController read GetController write SetController;
  end;


implementation
{$R *.dfm}

{ TfEditorGruposProveedor }

uses
  uDialogUtils;


function TfEditorGruposProveedor.GetController: IGruposProveedorController;
begin
  Result := FController;
end;

function TfEditorGruposProveedor.GetGruposProveedor: IBizGrupoProveedor;
begin
  Result := FGruposProveedor;
end;

procedure TfEditorGruposProveedor.SetController(const Value: IGruposProveedorController);
begin
  FController := Value;
end;

procedure TfEditorGruposProveedor.SetGruposProveedor(const Value: IBizGrupoProveedor);
begin
  FGruposProveedor := Value;
  DADataSource.DataTable := (FGruposProveedor as IBizGrupoProveedor).DataTable;
  DADataSource.DataTable.Open;
end;

procedure TfEditorGruposProveedor.actAnadirExecute(Sender: TObject);
begin
  if not FController.Localizar(GruposProveedor, editGrupoProveedor.Text) then
  begin
    GruposProveedor.Append;
    GruposProveedor.DESCRIPCION := editGrupoProveedor.Text;
    GruposProveedor.Post;
    editGrupoProveedor.Clear;
    ListaGruposProveedor.SetFocus;
  end
  else
    ShowErrorMessage('Ya existe el grupo ' + editGrupoProveedor.Text,
      'Ya existe el grupo de proveedor ''' + editGrupoProveedor.Text + ''' en la lista.');
end;

procedure TfEditorGruposProveedor.actEliminarExecute(Sender: TObject);
begin
  GruposProveedor.Delete;
  ListaGruposProveedor.SetFocus;
end;

procedure TfEditorGruposProveedor.actEliminarUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (FGruposProveedor.DataTable.RecordCount > 0) and
                                  (Length(ListaGruposProveedor.SelectedItem) > 0);

end;

procedure TfEditorGruposProveedor.CustomEditorClose(Sender: TObject; var Action: TCloseAction);
begin
  FGruposProveedor := Nil;
  FController := Nil;
end;

procedure TfEditorGruposProveedor.actAceptarExecute(Sender: TObject);
begin
  try
    GruposProveedor.DataTable.ApplyUpdates;
  except
    on E : Exception do begin
      GruposProveedor.DataTable.CancelUpdates;
      ShowErrorMessage('Error al guardar cambios', 'Se ha producido un error grave', E);
      exit;
    end;
  end;
  actCerrar.Execute;
end;

procedure TfEditorGruposProveedor.actCancelarExecute(Sender: TObject);
begin
  GruposProveedor.DataTable.CancelUpdates;
  actCerrar.Execute;
end;

procedure TfEditorGruposProveedor.actCerrarExecute(Sender: TObject);
begin
  Close;
end;

procedure TfEditorGruposProveedor.actAnadirUpdate(Sender: TObject);
begin
  (Sender as TAction).Enabled := (Length(editGrupoProveedor.Text) > 0)
end;

procedure TfEditorGruposProveedor.FormShow(Sender: TObject);
begin
  if not FGruposProveedor.DataTable.Active then
     FGruposProveedor.DataTable.Active := true;

  editGrupoProveedor.SetFocus;
end;

end.