AbetoDesign_FactuGES2/Source/Modulos/Remesas de cliente/Model/uBizRemesasClienteServer.pas

unit uBizRemesasClienteServer;

interface

uses
  uDAInterfaces, uDADelta, uDABusinessProcessor,
  schRemesasClienteServer_Intf;

const
  BIZ_SERVER_REMESAS_CLIENTE = 'Server.RemesasCliente';

type
  TBizRemesasClienteServer = class(TRemesasClienteBusinessProcessorRules)
  private
    FReferenciaAutomatica : Boolean;
    function DarReferencia : String;
    function IncrementarReferencia : Boolean;
  protected
    procedure BeforeProcessDelta(Sender: TDABusinessProcessor;
      const aDelta: IDADelta); override;
    procedure AfterProcessChange(Sender: TDABusinessProcessor;
      aChange: TDADeltaChange; Processed: Boolean;
      var CanRemoveFromDelta: Boolean); override;
  end;

implementation

uses
  Variants, uDAClasses, uReferenciasUtils, uBusinessUtils, uROClasses,  uDataModuleServer,
  schRemesasClienteClient_Intf, FactuGES_Intf, uROServer, SysUtils;

const
  REF_REMESAS_CLIENTE = 'REF_REMESAS_CLIENTE';
  
{ TBizRemesasClienteServer }

procedure TBizRemesasClienteServer.AfterProcessChange(
  Sender: TDABusinessProcessor; aChange: TDADeltaChange; Processed: Boolean;
  var CanRemoveFromDelta: Boolean);
begin
  inherited;
  { Por defecto, mantenemos los deltas por si alguna tabla hija los necesita }
  CanRemoveFromDelta := False;

  case aChange.ChangeType of
    ctInsert, ctUpdate: begin
                          if FReferenciaAutomatica then
                          begin
                            IncrementarReferencia;
                            FReferenciaAutomatica := False;
                          end;
                        end;
  end;
end;

procedure TBizRemesasClienteServer.BeforeProcessDelta(
  Sender: TDABusinessProcessor; const aDelta: IDADelta);
begin
  FReferenciaAutomatica := False;

  case Sender.CurrentChange.ChangeType of
    ctInsert, ctUpdate: begin
      //Si la referencia no ha sido asignada le asignamos una nosotros
      if REFERENCIAIsNull or (Length(REFERENCIA) = 0) then
      begin
        FReferenciaAutomatica := True;
        REFERENCIA := DarReferencia;
      end;
    end;
  end;
end;

function TBizRemesasClienteServer.DarReferencia: String;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
begin
  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.DarNuevaReferencia(REF_REMESAS_CLIENTE, ID_EMPRESA, -1)
end;

function TBizRemesasClienteServer.IncrementarReferencia: Boolean;
var
  AReferenciasService : IsrvReferencias;
  Intf : IInterface;
  AClientID : TGUID;
begin
  CreateGUID(AClientID);

  GetClassFactory('srvReferencias').CreateInstance(AClientID, Intf);
  AReferenciasService := Intf as IsrvReferencias;
  Result := AReferenciasService.IncrementarValorReferencia(REF_REMESAS_CLIENTE, Self.REFERENCIA, ID_EMPRESA, -1)
end;


initialization
  RegisterBusinessProcessorRules(BIZ_SERVER_REMESAS_CLIENTE, TBizRemesasClienteServer);

end.